Question

我正在开发一个项目，它一度可以从ftp服务器获取文件列表。此时，它返回文件的arrayref，或者如果传递了可选的正则表达式引用（即qr），则使用grep过滤列表。此外，如果qr有一个捕获组，它会将捕获的部分视为版本号，而是返回一个hashref，其中键是版本，值是文件名（如果是数组则返回）没有捕获组）。代码看起来像（稍微简化）

sub filter_files {
  my ($files, $pattern) = @_;
  my @files = @$files;
  unless ($pattern) {
    return \@files;
  }

  @files = grep { $_ =~ $pattern } @files;
  carp "Could not find any matching files" unless @files;

  my %versions = 
    map { 
      if ($_ =~ $pattern and defined $1) { 
        ( $1 => $_ )
      } else {
        ()
      }
    } 
    @files;

  if (scalar keys %versions) {
    return \%versions;
  } else {
    return \@files;
  }
}

此实现尝试创建哈希并在成功时返回它。我的问题是，我可以检测到qr是否有捕获组，并且只是尝试创建哈希值吗？

Answer 1

您可以使用以下内容：

sub capturing_groups{
    my $re = shift;
    "" =~ /|$re/;
    return $#+;
}

say capturing_groups qr/fo(.)b(..)/;

输出：

Answer 2

请参阅nparen in Regexp::Parser。

use strictures;
use Carp qw(carp);
use Regexp::Parser qw();
my $parser = Regexp::Parser->new;

sub filter_files {
    my ($files, $pattern) = @_;
    my @files = @$files;
    return \@files unless $pattern;

    carp sprintf('Could not inspect regex "%s": %s (%d)',
        $pattern, $parser->errmsg, $parser->errnum)
        unless $parser->regex($pattern);

    my %versions;
    @files = map {
        if (my ($capture) = $_ =~ $pattern) {
            $parser->nparen
                ? push @{ $versions{$capture} }, $_
                : $_
        } else {
            ()
        }
    } @files;
    carp 'Could not find any matching files' unless @files;

    return (scalar keys %versions)
        ? \%versions
        : \@files;
}

避免检查模式的另一种可能性是简单地依赖$capture的值。如果没有捕获成功匹配，它将是1（Perl真值）。您可以将其与偶然捕获的1区分开来，因为那个缺少IV标记。

Answer 3

您可以使用YAPE::Regex来解析正则表达式以查看是否存在捕获：

use warnings;
use strict;
use YAPE::Regex;

filter_files(qr/foo.*/);
filter_files(qr/(foo).*/);

sub filter_files {
    my ($pattern) = @_;
    print "$pattern ";
    if (has_capture($pattern)) {
        print "yes capture\n";
    }
    else {
        print "no capture\n";
    }
}

sub has_capture {
    my ($pattern) = @_;
    my $cap = 0;
    my $p = YAPE::Regex->new($pattern);
    while ($p->next()) {
        if (scalar @{ $p->{CAPTURE} }) {
            $cap = 1;
            last;
        }
    }
    return $cap;
}

__END__

(?-xism:foo.*) no capture
(?-xism:(foo).*) yes capture

计算qr正则表达式中的捕获组？

3 个答案: