Question

你好问题的答疑人！

我正在尝试找到一种方法来准确验证Windows 7计算机当前是否正在使用活动许可证并已激活。我相信我可以启动'cmd.exe'命令来运行cscript（slmgr）并解析该信息，但这似乎是一种效率低下的方法。

我遇到了一个名为SLGetGenuineInformation（http://msdn.microsoft.com/en-us/library/windows/desktop/bb648650%28v=vs.85%29.aspx）的非托管Windows API，但是我不熟悉如何在VB.NET中调用它或者变量类型应该是什么。我相信VB6带有某种APIViewer，Visual STudio 2010似乎并没有包含它。

所有相关的Google搜索都会显示为不相关的结果。

有关如何继续或实现此目标的任何建议，建议或指导？

Answer 1

请查看此示例vb.net控制台应用，该应用使用SLIsGenuineLocal功能。

Imports System.Collections.Generic
Imports System.Text
Imports System.Runtime.InteropServices
Imports SLID = System.Guid
Module Module1

    Public Enum SL_GENUINE_STATE
        SL_GEN_STATE_IS_GENUINE = 0
        SL_GEN_STATE_INVALID_LICENSE = 1
        SL_GEN_STATE_TAMPERED = 2
        SL_GEN_STATE_LAST = 3
    End Enum

    <DllImportAttribute("Slwga.dll", EntryPoint:="SLIsGenuineLocal", CharSet:=CharSet.None, ExactSpelling:=False, SetLastError:=False, PreserveSig:=True, CallingConvention:=CallingConvention.Winapi, _
     BestFitMapping:=False, ThrowOnUnmappableChar:=False)> _
    <PreserveSigAttribute()> _
    Friend Function SLIsGenuineLocal(ByRef slid As SLID, <[In](), Out()> ByRef genuineState As SL_GENUINE_STATE, ByVal val3 As IntPtr) As UInteger
    End Function


    Public Function IsGenuineWindows() As Boolean
        Dim _IsGenuineWindows As Boolean = False
        Dim ApplicationID As New Guid("55c92734-d682-4d71-983e-d6ec3f16059f")
        'Application ID GUID http://technet.microsoft.com/en-us/library/dd772270.aspx
        Dim windowsSlid As SLID = CType(ApplicationID, Guid)
        Try
            Dim genuineState As SL_GENUINE_STATE = SL_GENUINE_STATE.SL_GEN_STATE_LAST
            Dim ResultInt As UInteger = SLIsGenuineLocal(windowsSlid, genuineState, IntPtr.Zero)
            If ResultInt = 0 Then
                _IsGenuineWindows = (genuineState = SL_GENUINE_STATE.SL_GEN_STATE_IS_GENUINE)
            Else
                Console.WriteLine("Error getting information {0}", ResultInt.ToString())

            End If
        Catch ex As Exception
            Console.WriteLine(ex.Message)
        End Try
        Return _IsGenuineWindows
    End Function

    Sub Main()
        If Environment.OSVersion.Version.Major >= 6 Then
            'Version 6 can be Windows Vista, Windows Server 2008, or Windows 7
            If IsGenuineWindows() Then
                Console.WriteLine("Original Windows")
            Else
                Console.WriteLine("Not Original Windows")
            End If
        Else
            Console.WriteLine("OS Not supoprted")
        End If
        Console.ReadLine()
    End Sub

End Module

Answer 2

如果有帮助，那就是VC ++示例

#include <slpublic.h>
#pragma comment(lib,"Slwga.lib")

bool IsWindowsGenuine()
{
    GUID uid;
    RPC_WSTR rpc=(RPC_WSTR)_T("55c92734-d682-4d71-983e-d6ec3f16059f");
    UuidFromString(rpc,&uid);
    SL_GENUINE_STATE state;
    SLIsGenuineLocal(&uid,&state,NULL);
    if(state==SL_GENUINE_STATE::SL_GEN_STATE_IS_GENUINE)
        return true;
    return false;
}

这是VB Sript做到的：

trComputer = "."
Set objWMIService = GetObject("winmgmts:" _
& "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")
Set colWPA = objWMIService.ExecQuery _
("Select * from Win32_WindowsProductActivation")
For Each objWPA in colWPA
Wscript.Echo "Activation Required: " & objWPA.ActivationRequired
Wscript.Echo "Description: " & objWPA.Description
Wscript.Echo "Product ID: " & objWPA.ProductID
Wscript.Echo "Remaining Evaluation Period: " & _
objWPA.RemainingEvaluationPeriod
Wscript.Echo "Remaining Grace Period: " & objWPA.RemainingGracePeriod
Wscript.Echo "Server Name: " & objWPA.ServerName
Next

来源：How to check if a Windows version is Genuine or not?

如果你想直接从OS寄存器中读取它，你可以阅读使用VB在这里工作whit寄存器：http://www.codeproject.com/KB/vb/registry_with_vb.aspx

VB.NET - 检查Windows许可证状态或正版Windows

2 个答案: