Question

Win32 API中的Window-Procedure必须是static \ global函数，因为它不能使用类对象（this）参数。当然可以使用hWnd-＆gt;对象字典之类的解决方法等。

我想知道 D 是否有办法优雅地解决它，比如为每个对象创建一个微小的成员函数副本（调用对象的真实处理程序）或者我可以分配给{{{ 1}}（我知道有匿名函数，但我不能在它们上使用WNDCLASS.lpfnWndProc属性）？

我可以这样做：

extern(Windows)

（省略registration \ creation \ msg-loop ...）

事件（）似乎没有......我错过了什么？

Answer 1

我在这里为你做了这个（基于BCS＆＃39;回答）：

version (Windows)
{
    import std.c.windows.windows;

    void makeExecutable(ubyte[] code)
    {
        DWORD old;
        VirtualProtect(code.ptr, code.length, PAGE_EXECUTE_READWRITE, &old);
    }
}
else
version (linux)
{
    import core.sys.posix.sys.mman;
    import core.sys.posix.unistd;

    static if (!is(typeof(&mprotect)))
        extern(C) int mprotect(void*, size_t, int);

    void makeExecutable(ubyte[] code)
    {
        auto pageSize = sysconf(_SC_PAGE_SIZE);
        auto address = ((cast(size_t)code.ptr) & ~(pageSize-1));
        int pageCount =
            (address/pageSize == (address+code.length)/pageSize) ? 1 : 2;
        mprotect(cast(void*)address, pageSize * pageCount,
            PROT_READ | PROT_WRITE | PROT_EXEC);
    }
}
else
    static assert(0, "TODO");

R function(A) delegate2function(R, A...)(R delegate(A) d)
{
    enum size_t TEMPLATE1 = cast(size_t)0x01234567_01234567;
    enum size_t TEMPLATE2 = cast(size_t)0x89ABCDEF_89ABCDEF;

    static R functionTemplate(A args)
    {
        R delegate(A) d;
        d.ptr     = cast(typeof(d.ptr    ))TEMPLATE1;
        d.funcptr = cast(typeof(d.funcptr))TEMPLATE2;
        return d(args);
    }

    static void functionTemplateEnd() {}

    static void replaceWord(ubyte[] a, size_t from, size_t to)
    {
        foreach (i; 0..a.length - size_t.sizeof + 1)
        {
            auto p = cast(size_t*)(a.ptr + i);
            if (*p == from)
            {
                *p = to;
                return;
            }
        }
        assert(0);
    }

    auto templateStart = cast(ubyte*)&functionTemplate;
    auto templateEnd   = cast(ubyte*)&functionTemplateEnd;
    auto templateBytes = templateStart[0 .. templateEnd - templateStart];

    // must allocate type with pointers, otherwise GC won't scan it
    auto functionWords = new void*[(templateBytes.length / (void*).sizeof) + 3];
    // store context in word-aligned boundary, so the GC can find it
    functionWords[0] = d.ptr;
    functionWords[1] = d.funcptr;
    functionWords = functionWords[2..$];

    auto functionBytes = (cast(ubyte[])functionWords)[0..templateBytes.length];
    functionBytes[] = templateBytes[];

    replaceWord(functionBytes, TEMPLATE1, cast(size_t)d.ptr    );
    replaceWord(functionBytes, TEMPLATE2, cast(size_t)d.funcptr);
    makeExecutable(functionBytes);

    return cast(typeof(return)) functionBytes.ptr;
}

void main()
{
    import std.stdio;

    auto context = 42;

    void del(string s)
    {
        writeln(s);
        writeln(context);
    }

    auto f = delegate2function(&del);
    f("I am a pretty function");
}

在Windows 32位和Linux 64位上测试。

Answer 2

一个非常不便携的解决方案是动态创建一个包装调用的函数。我会通过编写一个看起来像这样的函数来做到这一点：

extern(C) RetType TestFn(Arg arg /* and any others */) {
   Class c = cast(Class)(0xDEAD_BEEF);
   return c.Method(arg);
}

然后，您可以将此函数编译为未优化的PIC，对其进行反编译，并找到可以根据需要进行混合的字节序列。最终结果将是一个类型（可能是一个结构），它有一个返回函数指针的方法，并且在构造时，使用从上面的步骤找到的字节填充内部void数组并戳出相关对象进入适当的地方。

稍微更高级的解决方案将使用对象和方法指针填充委托，以便可以将两者都提供给构造函数。更高级的解决方案将模拟类型并利用C和D调用约定的知识来动态生成参数转发代码。

Answer 3

如何使用SetWindowLong将this存储在窗口中？

有没有办法创建一个优雅的类成员窗口函数？

3 个答案: