Question

我找到了有关自动填充括号的配置，

inoremap ' ''<Left>
inoremap " ""<Left>
inoremap { {}<Left>
inoremap ( ()<Left>

但是当我试图删除'（'，''）'停留时，但在Sublime Text 2中，那也会消失。那么如何配置.vimrc ro make that？

//更新：获得了vim-autoclose插件，现在似乎正常工作。

Answer 1

如果您安装surround.vim，可以使用

执行此操作

inoremap ' ''<Left>
inoremap " ""<Left>
inoremap { {}<Left>
inoremap ( ()<Left>

imap <expr> <C-h> "\<C-\>\<C-n>x".((col('.')==col('$'))?(""):("h"))."a"
imap <BS>  <C-h>
let s:pairsymbols={"'": "'",
            \      '"': '"',
            \      '{': '}',
            \      '(': ')',}
function! s:DelPair()
    let cnt=v:count1
    if col('$')==1
        let shiftline=(line('.')<line('$'))
        normal! dd
        if shiftline
            normal! k
        endif
        normal! $
        if cnt>1
            execute 'normal '.(cnt-1).'x'
        endif
        return
    endif
    let curch=getline('.')[col('.')-1]
    if has_key(s:pairsymbols, curch)
        let oldchtick=b:changedtick
        if getline('.')[col('.')] is# s:pairsymbols[curch]
            normal! 2x
        else
            execute "normal \<Plug>Dsurround".s:pairsymbols[curch]
            if b:changedtick==oldchtick
                normal! x
            endif
        endif
    else
        normal! x
    endif
    if cnt>1
        execute 'normal '.(cnt-1).'x'
    endif
endfunction
nnoremap x :<C-u>call <SID>DelPair()<CR>

如何配置.vimrc使自动完成功能与Sublime Text 2一起使用？

1 个答案: