Question

保存NSIS中显示的安装日志的最简单方法是什么？我似乎记得在某处你可以用特殊标志重新编译NSIS代码以使其能够保存日志。有更简单的方法吗？

Answer 1

为了保持较小的文件大小，NSIS编译器的默认安装不会生成日志文件。下载版本的Special Build并将其复制到makensis.exe应用程序（和Stub文件夹）以对其进行修补以获得日志记录支持。

完成后，只需将以下内容添加到脚本中：

 LogSet on

无需其他更改。我不知道为什么这不是默认值，因为在我的情况下，它只增加48个字节到文件大小！

Answer 2

试用NSISLog插件。

还有LogEx。

Answer 3

这是直接来自NSIS website

的解决方案

StrCpy $0 "$EXEDIR\install.log"
Push $0
Call DumpLog



!define LVM_GETITEMCOUNT 0x1004
!define LVM_GETITEMTEXT 0x102D

Function DumpLog
  Exch $5
  Push $0
  Push $1
  Push $2
  Push $3
  Push $4
  Push $6

  FindWindow $0 "#32770" "" $HWNDPARENT
  GetDlgItem $0 $0 1016
  StrCmp $0 0 exit
  FileOpen $5 $5 "w"
  StrCmp $5 "" exit
    SendMessage $0 ${LVM_GETITEMCOUNT} 0 0 $6
    System::Alloc ${NSIS_MAX_STRLEN}
    Pop $3
    StrCpy $2 0
    System::Call "*(i, i, i, i, i, i, i, i, i) i \
      (0, 0, 0, 0, 0, r3, ${NSIS_MAX_STRLEN}) .r1"
    loop: StrCmp $2 $6 done
      System::Call "User32::SendMessageA(i, i, i, i) i \
        ($0, ${LVM_GETITEMTEXT}, $2, r1)"
      System::Call "*$3(&t${NSIS_MAX_STRLEN} .r4)"
      FileWrite $5 "$4$\r$\n"
      IntOp $2 $2 + 1
      Goto loop
    done:
      FileClose $5
      System::Free $1
      System::Free $3
  exit:
    Pop $6
    Pop $4
    Pop $3
    Pop $2
    Pop $1
    Pop $0
    Exch $5
FunctionEnd

保存NSIS安装日志

3 个答案: