Question

目前我收到了这个

<root>
<event>bla</event>
</root>

我想要的只是这个

<event>bla</event>

我的xsl看起来像这样

<?xml version="1.0" encoding="UTF-8" ?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" indent="yes" />
<xsl:param name="Number" />
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()" />
    </xsl:copy>
</xsl:template>
<xsl:template match="/root/event" />
<xsl:template match="/root/event[1]">
<xsl:copy-of select="current()" />
</xsl:template>
</xsl:stylesheet>

我无法弄清楚如何在不先越过/ root的情况下访问第一个节点。请帮忙

Answer 1

这个XSLT应该回答你的问题。它将为event个元素提供父节点的第一个子节点：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"  version="1.0">
    <xsl:template match="*">
        <xsl:apply-templates/>
    </xsl:template>
    <xsl:template match="event[1]">
        <xsl:copy-of select="."/>
    </xsl:template>
    <xsl:template match="text()"/>
</xsl:stylesheet>

root模板会跳过match="*"元素。

另一种方法（更简单但不那么进化）：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"  version="1.0">
    <xsl:template match="/">
        <xsl:copy-of select="root/event[1]"/>
    </xsl:template>
</xsl:stylesheet>

Answer 2

因为您使用的是身份规则，所以最好知道如何覆盖它以实现最大的灵活性：

0.1。覆盖排除元素但仍处理其子树中的所有节点：

<xsl:template match="root">
  <xsl:apply-templates/>
</xsl:template>

0.2。覆盖排除它的元素以及子树中的任何节点：

 <xsl:template match="event[position() > 1]"/>

这两个组合为我们提供了完整的通缉转换：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="node()|@*">
  <xsl:copy>
   <xsl:apply-templates select="node()|@*"/>
  </xsl:copy>
 </xsl:template>

 <xsl:template match="root">
  <xsl:apply-templates/>
 </xsl:template>

 <xsl:template match="event[position() > 1]"/>
</xsl:stylesheet>

将此转换应用于以下XML文档：

<root>
    <event>bla1</event>
    <event>bla2</event>
</root>

产生了想要的正确结果：

<event>bla1</event>

如何仅使用XSL显示第一个子节点

2 个答案: