Question

我正在使用一些XML，其中节点有很多属性，我正在使用XSL创建一个FO PDF文件（报告）。我正在尝试创建一个模板，该模板在当前节点上获取特定属性，并创建一个具有一些基本格式的fo:block。

这是一个模板，可以在一个节点上创建所有属性和值的大列表。

XSL：

<xsl:template name="createAttributeAndValueList">
    <xsl:param name="node" select="." />
    <xsl:for-each select="$node/@*">
        <fo:block>
        <xsl:value-of select="concat(name(),':   ')"/>
        <xsl:value-of select="."/>
        </fo:block>
    </xsl:for-each>
</xsl:template>

但是，有些时候我只想要取出其中一个或两个属性，而不是从节点中取出所有这些属性。我猜这是非常明显的事情，但由于我的经验不足，我还没想到。

我正在尝试进行相同的格式化，但我似乎无法正确地将语法传递给参数，并获得我想要的内容。这就是我所拥有的：

XSL：

<xsl:template name="createAttributeValuePair">
    <xsl:param name="attribute" select="." />
    <xsl:for-each select="@*">
        <fo:block>
        <xsl:value-of select="concat(name(),':   ')"/>
        <xsl:value-of select="."/>
        </fo:block>
    </xsl:for-each>
</xsl:template>

以下是我试图称之为： XSL：

<fo:block font-weight="normal" margin-left="6pt">
    <xsl:call-template name="createAttributeValuePair">
        <xsl:with-param name="attribute"                                     
                        select="/device:DevicePatientEncounter/device:Encounter/
                                     device:Followup/@UnderlyingRhythm"/>
    </xsl:call-template>
</fo:block>

我的XML看起来像这样：

<DevicePatientEncounter xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" 
                        xmlns:xsd="http://www.w3.org/2001/XMLSchema" 
                        GeneratedTime="2011-12-14T13:36:05" 
                        EncounterDate="2011-11-15T11:04:54" 
                        xmlns="device">
    <Encounter>
        <Followup UnderlyingRhythm="Sinus bradycardia" 
                  UnderlyingRhythmRateBpm="44" 
                  IsPmDependent="false" 
                  PresentingRhythm="Atrial fibrillation" 
                  BatteryChargeSeconds="5" 
                  AutoCapFrequency="3 Years" 
                  LastCapacitorFormDate="2011-10-25T00:00:00" 
                  BatteryLongevity="0" 
                  BatteryVoltage="11" 
                  BatteryStatus="MOL"/>
    </Encounter>
</DevicePatientEncounter>

Answer 1

一些注意事项：

您正在将属性传递给createAttributeValuePair，但您从未对参数
您在此模板中循环@*，但该模板似乎旨在输出单个属性的名称和值
此外，call-template不会更改当前节点，因此不清楚在循环中迭代哪些元素的属性

我猜你正在寻找这样的东西：

<xsl:template name="createAttributeValuePair">
    <xsl:param name="attribute" select="."/>
    <fo:block>
        <xsl:value-of select="concat(name($attribute),':   ')"/>
        <xsl:value-of select="$attribute"/>
    </fo:block>
</xsl:template>

这是一个完整的演示：

<xsl:stylesheet version="1.0" 
                xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
                xmlns:fo="http://www.w3.org/1999/XSL/Format" 
                xmlns:device="device">
    <xsl:output method="xml" indent="yes" omit-xml-declaration="yes"/>
    <xsl:template match="/">
        <fo:block font-weight="normal" margin-left="6pt">
            <xsl:call-template name="createAttributeValuePair">
                <xsl:with-param name="attribute" 
                      select="/device:DevicePatientEncounter/device:Encounter/
                                  device:Followup/@UnderlyingRhythm"/>
            </xsl:call-template>
        </fo:block>
    </xsl:template>
    <xsl:template name="createAttributeValuePair">
        <xsl:param name="attribute" select="."/>
        <fo:block>
            <xsl:value-of select="concat(name($attribute),':   ')"/>
            <xsl:value-of select="$attribute"/>
        </fo:block>
    </xsl:template>
</xsl:stylesheet>

给出示例XML时会生成以下输出：

<fo:block xmlns:fo="http://www.w3.org/1999/XSL/Format" xmlns:device="device"
          font-weight="normal"
          margin-left="6pt">
   <fo:block>UnderlyingRhythm:   Sinus bradycardia</fo:block>
</fo:block>

xslt模板 - 如何传递属性及其值？

1 个答案: