Question

我们使用Bob Swart的白皮书作为指南，创建了Datasnap服务（使用Delphi XE）。它工作正常，我们已将其部署到我们的测试服务器。

现在出现问题，当我们执行大量请求（通过JMeter）时，会发生某种内存损坏。有些请求成功，有些请求因访问冲突而失败。最后，它变得如此腐败，以至于对我们的OWN（而不是DSAdmin）方法的每个请求都会响应访问冲突。

但是，我无法获取堆栈跟踪以获取更多信息，因为在处理请求时已经捕获了异常。

如果我使用此应用程序的VCL版本进行大量测试，它仍可正常工作。

有没有人知道这可能是什么，或者遇到同样的问题，或者你能帮助我从被捕获的异常中获取堆栈跟踪（在别人的代码中，我无法编辑）？

提前致谢。

Answer 1

要使用JEDI JCL记录捕获和未捕获的异常，您应该安装JEDI JCL。

然后尝试一些代码，例如从jcl\examples\windows\debug\framestrack\FramesTrackDemoMain.pas获取的代码：

您应该在delphi项目选项的Compiler和Linker选项中使用完整的Debug信息进行编译，以实现此目的。

请注意，您不必调用LogException，它会自动调用您已添加异常通知程序回调（JclAddExceptNotifier）。当你要添加它的表单或数据模块被销毁时，不要忘记也调用JclRemoveExceptNotifier，如下所示：

procedure TForm1.LogException(ExceptObj: TObject; ExceptAddr: Pointer; IsOS: Boolean);
var
  TmpS: string;
  ModInfo: TJclLocationInfo;
  I: Integer;
  ExceptionHandled: Boolean;
  HandlerLocation: Pointer;
  ExceptFrame: TJclExceptFrame;

begin
  TmpS := 'Exception ' + ExceptObj.ClassName;
  if ExceptObj is Exception then
    TmpS := TmpS + ': ' + Exception(ExceptObj).Message;
  if IsOS then
    TmpS := TmpS + ' (OS Exception)';
  mmLog.Lines.Add(TmpS);
  ModInfo := GetLocationInfo(ExceptAddr);
  mmLog.Lines.Add(Format(
    '  Exception occured at $%p (Module "%s", Procedure "%s", Unit "%s", Line %d)',
    [ModInfo.Address,
     ModInfo.UnitName,
     ModInfo.ProcedureName,
     ModInfo.SourceName,
     ModInfo.LineNumber]));
  if stExceptFrame in JclStackTrackingOptions then
  begin
    mmLog.Lines.Add('  Except frame-dump:');
    I := 0;
    ExceptionHandled := False;
    while (chkShowAllFrames.Checked or not ExceptionHandled) and
      (I < JclLastExceptFrameList.Count) do
    begin
      ExceptFrame := JclLastExceptFrameList.Items[I];
      ExceptionHandled := ExceptFrame.HandlerInfo(ExceptObj, HandlerLocation);
      if (ExceptFrame.FrameKind = efkFinally) or
          (ExceptFrame.FrameKind = efkUnknown) or
          not ExceptionHandled then
        HandlerLocation := ExceptFrame.CodeLocation;
      ModInfo := GetLocationInfo(HandlerLocation);
      TmpS := Format(
        '    Frame at $%p (type: %s',
        [ExceptFrame.ExcFrame,
         GetEnumName(TypeInfo(TExceptFrameKind), Ord(ExceptFrame.FrameKind))]);
      if ExceptionHandled then
        TmpS := TmpS + ', handles exception)'
      else
        TmpS := TmpS + ')';
      mmLog.Lines.Add(TmpS);
      if ExceptionHandled then
        mmLog.Lines.Add(Format(
          '      Handler at $%p',
          [HandlerLocation]))
      else
        mmLog.Lines.Add(Format(
          '      Code at $%p',
          [HandlerLocation]));
      mmLog.Lines.Add(Format(
        '      Module "%s", Procedure "%s", Unit "%s", Line %d',
        [ModInfo.UnitName,
         ModInfo.ProcedureName,
         ModInfo.SourceName,
         ModInfo.LineNumber]));
      Inc(I);
    end;
  end;
  mmLog.Lines.Add('');
end;


procedure TForm1.FormCreate(Sender: TObject);
begin
  JclAddExceptNotifier(Form1.LogException);
end;

procedure TForm1.FormDestroy(Sender: TObject);
begin
  JclRemoveExceptNotifier(Form1.LogException);
end;

这是通常的初始化代码：

initialization

  JclStackTrackingOptions := JclStackTrackingOptions + [stExceptFrame];
  JclStartExceptionTracking;

这是运行的JCL FramesTrackExample.dproj演示：

enter image description here

出于您的目的，将更改行添加到TMemo.Lines的代码更改为写入磁盘上的日志文件。如果您已经有一个日志记录系统，那很好，如果没有，那么请考虑Log4D。

Answer 2

每个新的Web服务调用都是一个新线程。当下一个服务调用即将到来并且新线程尝试访问它们时，前一个线程可以分配一些资源。或者，当另一个线程尝试使用它们时，一个线程可能会释放一些资源。您应该使用TCriticalSection来确保所有资源仅适用于一个线程。还要确保TCriticalSection是一个全局变量，并且可以被所有实例访问。

如何从处理/捕获的异常中获取堆栈跟踪并将其转储到跟踪日志中

2 个答案: