如何开始使用GTest和CMake

Question

我最近因使用CMake编译我的C ++项目而被出售，现在我想开始为我的代码编写一些单元测试。我决定使用Google Test实用程序来帮助解决这个问题，但在入门时需要一些帮助。

我一直在阅读各种指南和示例，其中包括Primer，introduction at IBM以及有关SO（here和here）以及其他来源的一些问题我已经失去了追踪。我意识到那里有很多，但不知怎的，我仍然遇到困难。

我目前正在尝试实施最基本的测试，以确认我已经编译/安装了gtest，并且它无法正常工作。唯一的源文件（testgtest.cpp）几乎完全取自this之前的答案：

#include <iostream>

#include "gtest/gtest.h"

TEST(sample_test_case, sample_test)
{
    EXPECT_EQ(1, 1);
}

和我关联的CMakeLists.txt如下：

cmake_minimum_required(VERSION 2.6)
project(basic_test)

# Setup testing
enable_testing()
find_package(GTest REQUIRED)
include_directories(${GTEST_INCLUDE_DIR})

# Add test cpp file
add_executable(runUnitTests
    testgtest.cpp
)

# Link test executable against gtest & gtest_main
target_link_libraries(runUnitTests ${GTEST_LIBRARY_DEBUG} ${GTEST_MAIN_LIBRARY_DEBUG})

add_test(
    NAME runUnitTests
    COMMAND runUnitTests
)

请注意，我选择链接gtest_main而不是在cpp文件末尾提供main，因为我相信这样可以让我更轻松地将测试扩展到多个文件。

构建生成的.sln文件（在Visual C ++ 2010 Express中）时，遗憾的是我得到了一长串错误

2>msvcprtd.lib(MSVCP100D.dll) : error LNK2005: "public: virtual __thiscall std::basic_iostream<char,struct std::char_traits<char> >::~basic_iostream<char,struct std::char_traits<char> >(void)" (??1?$basic_iostream@DU?$char_traits@D@std@@@std@@UAE@XZ) already defined in gtestd.lib(gtest-all.obj)

我认为这意味着我没有成功链接到gtest库。我已经确定在链接调试库时，我已经尝试在调试模式下构建。

修改

我做了一些挖掘，我认为我的问题与我正在构建gtest的库的类型有关。使用CMake构建gtest时，如果未检查BUILD_SHARED_LIBS，并且我将程序与这些.lib文件链接，则会出现上述错误。但是，如果选中BUILD_SHARED_LIBS，那么我会生成一组.lib和.dll文件。当现在链接这些.lib文件时，程序会编译，但是当运行时抱怨它找不到gtest.dll。

SHARED和非SHARED库之间有什么区别，如果我选择不共享，为什么它不起作用？我错过的项目的CMakeLists.txt中是否有一个选项？

Answer 1

解决方案涉及将gtest源目录作为项目的子目录。如果它对任何人都有帮助，我已经在下面包含了工作的CMakeLists.txt。

cmake_minimum_required(VERSION 2.6)
project(basic_test)

################################
# GTest
################################
ADD_SUBDIRECTORY (gtest-1.6.0)
enable_testing()
include_directories(${gtest_SOURCE_DIR}/include ${gtest_SOURCE_DIR})

################################
# Unit Tests
################################
# Add test cpp file
add_executable( runUnitTests testgtest.cpp )
# Link test executable against gtest & gtest_main
target_link_libraries(runUnitTests gtest gtest_main)
add_test( runUnitTests runUnitTests )

Answer 2

这是我刚刚测试过的一个完整的工作示例。它直接从Web下载，可以是固定的tarball，也可以是最新的subversion目录。

cmake_minimum_required (VERSION 3.1)

project (registerer)

##################################
# Download and install GoogleTest

include(ExternalProject)
ExternalProject_Add(gtest
  URL https://googletest.googlecode.com/files/gtest-1.7.0.zip
  # Comment above line, and uncomment line below to use subversion.
  # SVN_REPOSITORY http://googletest.googlecode.com/svn/trunk/ 
  # Uncomment line below to freeze a revision (here the one for 1.7.0)
  # SVN_REVISION -r700

  PREFIX ${CMAKE_CURRENT_BINARY_DIR}/gtest
  INSTALL_COMMAND ""
)
ExternalProject_Get_Property(gtest source_dir binary_dir)

################
# Define a test
add_executable(registerer_test registerer_test.cc)

######################################
# Configure the test to use GoogleTest
#
# If used often, could be made a macro.

add_dependencies(registerer_test gtest)
include_directories(${source_dir}/include)
target_link_libraries(registerer_test ${binary_dir}/libgtest.a)
target_link_libraries(registerer_test ${binary_dir}/libgtest_main.a)

##################################
# Just make the test runnable with
#   $ make test

enable_testing()
add_test(NAME    registerer_test 
         COMMAND registerer_test)

Answer 3

最有可能的是，测试二进制文件和Google Test库之间的编译器选项的差异应该归咎于此类错误。这就是为什么建议在源代码表单中引入Google Test并将其与测试一起构建。在CMake中很容易做到。您只需使用gtest根路径调用ADD_SUBDIRECTORY，然后就可以使用在那里定义的公共库目标（gtest和gtest_main）。 googletest框架组中的CMake thread中有更多背景信息。

[编辑] BUILD_SHARED_LIBS选项仅在Windows上有效。它指定了您希望CMake构建的库的类型。如果将其设置为ON，则CMake会将它们构建为DLL而不是静态库。在这种情况下，您必须使用-DGTEST_LINKED_AS_SHARED_LIBRARY = 1构建测试，并将CMake生成的DLL文件复制到包含测试二进制文件的目录中（默认情况下，CMake将它们放在单独的输出目录中）。除非静态库中的gtest不适合你，否则更容易不设置该选项。

Answer 4

你可以充分利用这两个世界。可以使用ExternalProject下载gtest源代码，然后使用add_subdirectory()将其添加到您的构建版本中。这具有以下优点：

• gtest是作为主构建的一部分构建的，因此它使用相同的编译器标志等，因此避免了问题中描述的问题。
• 无需将gtest源添加到您自己的源代码树中。

以正常方式使用，ExternalProject不会在配置时（即运行CMake时）进行下载和解包，但是只需要一点点工作就可以实现。我写了一篇关于如何做到这一点的博客文章，其中还包括一个通用实现，适用于任何使用CMake作为其构建系统的外部项目，而不仅仅是gtest。你可以在这里找到它们：

• https://crascit.com/2015/07/25/cmake-gtest/
• https://github.com/Crascit/DownloadProject

更新：此方法现在也是part of the googletest documentation。

Answer 5

  

我做了一些挖掘，我认为我的问题与我正在构建gtest的库的类型有关。使用CMake构建gtest时，如果未检查BUILD_SHARED_LIBS，并且我将程序与这些.lib文件链接，则会出现上述错误。但是，如果选中了BUILD_SHARED_LIBS，那么我会生成一组.lib和.dll文件。当现在链接这些.lib文件时，程序会编译，但是当运行时抱怨它找不到gtest.dll。

这是因为如果要将gtest用作共享库，则必须将-DGTEST_LINKED_AS_SHARED_LIBRARY = 1添加到项目中的编译器定义中。

如果您使用gtest_force_shared_crt选项编译它，也可以使用静态库来消除您看到的错误。

我喜欢图书馆但是将它添加到项目中真的很痛苦。除非你挖掘（并入侵）gtest cmake文件，否则你没有机会做到正确。耻辱。特别是我不喜欢添加gtest作为源的想法。 ：）

Answer 6

OP正在使用Windows，今天使用GTest的一种更简单的方法是使用 vcpkg + cmake。

---

按照https://github.com/microsoft/vcpkg安装vcpkg，并确保可以从cmd行运行vcpkg。记下vcpkg安装文件夹，例如。 C:\bin\programs\vcpkg。

使用vcpkg install gtest安装gtest：这将下载，编译并安装GTest。

使用CmakeLists.txt，如下所示：注意，我们可以使用 targets 而不是包含文件夹。

cmake_minimum_required(VERSION 3.15)
project(sample CXX)
enable_testing()
find_package(GTest REQUIRED)
add_executable(test1 test.cpp source.cpp)
target_link_libraries(test1 GTest::GTest GTest::Main)
add_test(test-1 test1)

使用以下命令运行cmake（如有必要，请编辑vcpkg文件夹，并确保vcpkg.cmake工具链文件的路径正确）

cmake -B build -DCMAKE_TOOLCHAIN_FILE=C:\bin\programs\vcpkg\scripts\buildsystems\vcpkg.cmake

并照常使用cmake --build build进行构建。 请注意，vcpkg还将将所需的gtest（d）.dll / gtest（d）_main.dll从安装文件夹复制到Debug / Release文件夹。

使用cd build & ctest测试。

Answer 7

你和VladLosevs＆＃39;解决方案可能比我的好。但是，如果你想要一个暴力解决方案，试试这个：

SET(CMAKE_EXE_LINKER_FLAGS /NODEFAULTLIB:\"msvcprtd.lib;MSVCRTD.lib\")

FOREACH(flag_var
    CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_DEBUG CMAKE_CXX_FLAGS_RELEASE
    CMAKE_CXX_FLAGS_MINSIZEREL CMAKE_CXX_FLAGS_RELWITHDEBINFO)
    if(${flag_var} MATCHES "/MD")
        string(REGEX REPLACE "/MD" "/MT" ${flag_var} "${${flag_var}}")
    endif(${flag_var} MATCHES "/MD")
ENDFOREACH(flag_var)

Answer 8

只是对已接受答案中@Patricia的评论和对原始问题的@Fraser的评论的更新，如果您有权使用CMake 3.11+，则可以使用CMake的FetchContent函数。

CMake的FetchContent页面以googletest为例！

我对接受的答案做了一个小修改：

cmake_minimum_required(VERSION 3.11)
project(basic_test)

set(GTEST_VERSION 1.6.0 CACHE STRING "Google test version")

################################
# GTest
################################
FetchContent_Declare(googletest
GIT_REPOSITORY https://github.com/google/googletest.git
GIT_TAG release-${GTEST_VERSION})

FetchContent_GetProperties(googletest)
if(NOT googletest_POPULATED)
  FetchContent_Populate(googletest)
  add_subdirectory(${googletest_SOURCE_DIR} ${googletest_BINARY_DIR})
endif()

enable_testing()

################################
# Unit Tests
################################
# Add test cpp file
add_executable(runUnitTests testgtest.cpp)

# Include directories
target_include_directories(runUnitTests 
                      $<TARGET_PROPERTY:gtest,INTERFACE_SYSTEM_INCLUDE_DIRECTORIES>
                      $<TARGET_PROPERTY:gtest_main,INTERFACE_SYSTEM_INCLUDE_DIRECTORIES>)

# Link test executable against gtest & gtest_main
target_link_libraries(runUnitTests gtest
                                   gtest_main)

add_test(runUnitTests runUnitTests)

您可以使用在Google测试CMakeLists.txt脚本中设置的gtest和gtest_main目标的INTERFACE_SYSTEM_INCLUDE_DIRECTORIES目标属性。

Answer 9

我决定快速地将一些通用的东西放在一起，以演示与以前发布的答案不同的方式，希望它能对某人有所帮助。以下在我的Mac上对我有用。首先，我为gtests运行了设置命令。我只是使用发现的脚本来设置所有内容。

#!/usr/bin/env bash

# install gtests script on mac
# https://gist.github.com/butuzov/e7df782c31171f9563057871d0ae444a

#usage
# chmod +x ./gtest_installer.sh
# sudo ./gtest_installer.sh

# Current directory
__THIS_DIR=$(pwd)


# Downloads the 1.8.0 to disc
function dl {
    printf "\n  Downloading Google Test Archive\n\n"
    curl -LO https://github.com/google/googletest/archive/release-1.8.0.tar.gz
    tar xf release-1.8.0.tar.gz
}

# Unpack and Build
function build {
    printf "\n  Building GTest and Gmock\n\n"
    cd googletest-release-1.8.0
    mkdir build 
    cd $_
    cmake -Dgtest_build_samples=OFF -Dgtest_build_tests=OFF ../
    make
}

# Install header files and library
function install {
    printf "\n  Installing GTest and Gmock\n\n"

    USR_LOCAL_INC="/usr/local/include"
    GTEST_DIR="/usr/local/Cellar/gtest/"
    GMOCK_DIR="/usr/local/Cellar/gmock/"

    mkdir $GTEST_DIR

    cp googlemock/gtest/*.a $GTEST_DIR
    cp -r ../googletest/include/gtest/  $GTEST_DIR
    ln -snf $GTEST_DIR $USR_LOCAL_INC/gtest
    ln -snf $USR_LOCAL_INC/gtest/libgtest.a /usr/local/lib/libgtest.a
    ln -snf $USR_LOCAL_INC/gtest/libgtest_main.a /usr/local/lib/libgtest_main.a

    mkdir $GMOCK_DIR
    cp googlemock/*.a   $GMOCK_DIR
    cp -r ../googlemock/include/gmock/  $GMOCK_DIR
    ln -snf $GMOCK_DIR $USR_LOCAL_INC/gmock
    ln -snf $USR_LOCAL_INC/gmock/libgmock.a /usr/local/lib/libgmock.a
    ln -snf $USR_LOCAL_INC/gmock/libgmock_main.a /usr/local/lib/libgmock_main.a
}

# Final Clean up.
function cleanup {
    printf "\n  Running Cleanup\n\n"

    cd $__THIS_DIR
    rm -rf $(pwd)/googletest-release-1.8.0
    unlink $(pwd)/release-1.8.0.tar.gz
}

dl && build && install && cleanup 

接下来，我制作了一个简单的文件夹结构并编写了一些快速的类

utils/
  cStringUtils.cpp
  cStringUtils.h
  CMakeLists.txt
utils/tests/
    gtestsMain.cpp
    cStringUtilsTest.cpp
    CMakeLists.txt

我为utils文件夹创建了一个顶级CMakeLists.txt，为tests文件夹创建了一个CMakeLists.txt

cmake_minimum_required(VERSION 2.6)

project(${GTEST_PROJECT} C CXX)

set(CMAKE_C_STANDARD 98)
set(CMAKE_CXX_STANDARD 98)

#include .h and .cpp files in util folder
include_directories("${CMAKE_CURRENT_SOURCE_DIR}")

##########
# GTests
#########
add_subdirectory(tests)

这是测试文件夹中的CMakeLists.txt

cmake_minimum_required(VERSION 2.6)

set(GTEST_PROJECT gtestProject)

enable_testing()

message("Gtest Cmake")

find_package(GTest REQUIRED)

# The utils, test, and gtests directories
include_directories("${CMAKE_CURRENT_SOURCE_DIR}")
include_directories("/usr/local/Cellar/gtest/include")
include_directories("/usr/local/Cellar/gtest/lib")

set(SOURCES
  gtestsMain.cpp
  ../cStringUtils.cpp
  cStringUtilsTest.cpp
)

set(HEADERS
  ../cStringUtils.h
)

add_executable(${GTEST_PROJECT} ${SOURCES})
target_link_libraries(${GTEST_PROJECT} PUBLIC
  gtest
  gtest_main
)

add_test(${GTEST_PROJECT} ${GTEST_PROJECT})

然后剩下的就是编写示例gtest和gtest main

示例gtest

#include "gtest/gtest.h"
#include "cStringUtils.h"

namespace utils
{

class cStringUtilsTest : public ::testing::Test {

 public:

  cStringUtilsTest() : m_function_param(10) {}
  ~cStringUtilsTest(){}

 protected:
  virtual void SetUp() 
  {
    // declare pointer 
    pFooObject = new StringUtilsC();    
  }

  virtual void TearDown() 
  {
    // Code here will be called immediately after each test
    // (right before the destructor).
    if (pFooObject != NULL)
    {
      delete pFooObject;
      pFooObject = NULL;
    }
  }


  StringUtilsC fooObject;              // declare object
  StringUtilsC *pFooObject;
  int m_function_param;                // this value is used to test constructor
};

TEST_F(cStringUtilsTest, testConstructors){
    EXPECT_TRUE(1);

  StringUtilsC fooObject2 = fooObject; // use copy constructor


  fooObject.fooFunction(m_function_param);
  pFooObject->fooFunction(m_function_param);
  fooObject2.fooFunction(m_function_param);
}

} // utils end

gtest主样本

#include "gtest/gtest.h"
#include "cStringUtils.h"

int main(int argc, char **argv) {
  ::testing::InitGoogleTest(&argc, argv); 
  return RUN_ALL_TESTS();
}

然后我可以使用utils文件夹中的以下命令编译并运行gtests

cmake .
make 
./tests/gtestProject

Answer 10

最简单的CMakeLists.txt我从这个帖子的答案中提炼出来并且有些试错：

project(test CXX C)
cmake_minimum_required(VERSION 2.6.2)

#include folder contains current project's header filed
include_directories("include")

#test folder contains test files
set (PROJECT_SOURCE_DIR test) 
add_executable(hex2base64 ${PROJECT_SOURCE_DIR}/hex2base64.cpp)

# Link test executable against gtest nothing else required
target_link_libraries(hex2base64 gtest pthread)

Gtest应该已经安装在您的系统上。