Question

我想使用带有一组行节点和列节点的xslt将XML文档转换为xhtml表。

列节点定义关于关联行属性的数据。例如，第一列节点指定应该隐藏Row节点的ID属性（即，不显示在表中）。 Column节点的Caption元素定义列标题文本应该是什么。

我已经看到了解决方案，您知道要提前转换为列的属性，但我不确定如何使用相关的列数据来格式化标题

输入：

<TableData>
    <Columns>
         <Column Name="ID" Hidden="true" />
         <Column Name="Name" Caption="Item Name" />
         <Column Name="Desc" Caption="Item Description" />
    </Columns>
    <Rows>
         <Row ID="0" Name="A" />
         <Row ID="1" Name="B" Desc="Some description"/>
         <Row ID="3" Name="C" />
    </Rows>
</TableData>

所需的输出将是（x）html中的表格，如下所示：

Item Name      | Item Description
--------------------------------------
A              |      
B              | Some Description
C              |

Answer 1

此转化：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:key name="RowAttribsByName" match="Row/@*"
      use="concat(generate-id(..), '|', name())"/>

 <xsl:variable name="vColNames" select=
  "/*/Columns/*[not(@Hidden = 'true')]/@Name"/>

 <xsl:template match="/*">
  <table border="1">
    <tr>
     <xsl:apply-templates select="Columns/*"/>
    </tr>
    <xsl:apply-templates select="Rows/Row"/>
  </table>
 </xsl:template>

 <xsl:template match="Column[not(@Hidden = 'true')]">
  <td><xsl:value-of select="@Caption"/></td>
 </xsl:template>

 <xsl:template match="Row">
  <tr>
   <xsl:apply-templates select="$vColNames">
     <xsl:with-param name="pRowId"
          select="generate-id()"/>
   </xsl:apply-templates>
  </tr>
 </xsl:template>

 <xsl:template match="Column/@*">
  <xsl:param name="pRowId"/>

  <td width="50%">
    <xsl:value-of select=
      "key('RowAttribsByName',
           concat($pRowId, '|', .)
           )
    "/>
  </td>
 </xsl:template>
</xsl:stylesheet>

应用于提供的XML文档：

<TableData>
    <Columns>
        <Column Name="ID" Hidden="true" />
        <Column Name="Name" Caption="Item Name" />
        <Column Name="Desc" Caption="Item Description" />
    </Columns>
    <Rows>
        <Row ID="0" Name="A" />
        <Row ID="1" Name="B" Desc="Some description"/>
        <Row ID="3" Name="C" />
    </Rows>
</TableData>

生成想要的正确结果：

<table border="1">
   <tr>
      <td>Item Name</td>
      <td>Item Description</td>
   </tr>
   <tr>
      <td width="50%">A</td>
      <td width="50%"/>
   </tr>
   <tr>
      <td width="50%">B</td>
      <td width="50%">Some description</td>
   </tr>
   <tr>
      <td width="50%">C</td>
      <td width="50%"/>
   </tr>
</table>

xslt用于创建具有可自定义标头的动态表

1 个答案: