Question

我有一个SP prc_Foo_Delete，其签名如下：

ALTER PROCEDURE [prc_Foo_Delete]
    @fooIds [int_udtt] READONLY,
    @deleteReason int,
    @comment nvarchar(512),
    @deletedBy nvarchar(128)

int_udtt定义为：

CREATE TYPE [int_udtt] AS TABLE(
    [Id] [int] NOT NULL,
    PRIMARY KEY CLUSTERED 
(
    [Id] ASC
)WITH (IGNORE_DUP_KEY = OFF)
)

我尝试使用以下脚本在Management Studio中调用此SP：

DECLARE @return_value int
EXEC    @return_value = [prc_Foo_Delete]
        @fooIds = 3,
        @deleteReason = 2,
        @comment = N'asfdasdf',
        @deletedBy = N'asdfa'

SELECT  'Return Value' = @return_value
GO

我得到的错误是：操作数类型冲突：int与int_udtt不兼容。如何在此工具中传入int或int列表以进行调用（我知道如何在代码中执行此操作但不在Management Studio中执行。）

Answer 1

由于您已将用户定义的类型定义为存储过程的参数，因此在调用存储过程时，您还需要使用该用户定义的类型！您不能只发送一个INT ....

尝试这样的事情：

-- define an instance of your user-defined table type
DECLARE @IDs [int_udtt]

-- fill some values into that table
INSERT INTO @IDs VALUES(3), (5), (17), (42)

-- call your stored proc
DECLARE @return_value int
EXEC    @return_value = [prc_Foo_Delete]
        @fooIds = @IDs,   -- pass in that UDT table type here!
        @deleteReason = 2,
        @comment = N'asfdasdf',
        @deletedBy = N'asdfa'

SELECT  'Return Value' = @return_value
GO

如何将udtt传递到SQL Server Management Studio中的存储过程

1 个答案: