如何删除SQL Server数据库中的所有表？

Question

我正在尝试编写一个完全清空SQL Server数据库的脚本。这就是我到目前为止所做的：

USE [dbname]
GO
EXEC sp_msforeachtable 'ALTER TABLE ? NOCHECK CONSTRAINT all'
EXEC sp_msforeachtable 'DELETE ?'

当我在Management Studio中运行它时，我得到：

  

命令已成功完成。

但是当我刷新表格列表时，它们仍然存在。我做错了什么？

Answer 1

您也可以仅使用MSSMS工具（不使用sql）从数据库中删除所有表。有时这种方式可以更舒适（特别是如果偶尔进行）

我按照以下步骤逐步完成：

1. 选择表格＆＃39;在数据库树（对象资源管理器）
上
2. 按F7打开“对象资源管理器详细信息”视图
3. 在此视图中选择必须删除的表（在本例中为所有表）
4. 按Delete键直到删除所有表格（由于键约束/依赖项，您重复多次表示错误）

Answer 2

当有多个外键表时，它对我不起作用 我发现代码可以运行并执行您尝试的所有内容（删除数据库中的所有表）：

DECLARE @Sql NVARCHAR(500) DECLARE @Cursor CURSOR

SET @Cursor = CURSOR FAST_FORWARD FOR
SELECT DISTINCT sql = 'ALTER TABLE [' + tc2.TABLE_SCHEMA + '].[' +  tc2.TABLE_NAME + '] DROP [' + rc1.CONSTRAINT_NAME + '];'
FROM INFORMATION_SCHEMA.REFERENTIAL_CONSTRAINTS rc1
LEFT JOIN INFORMATION_SCHEMA.TABLE_CONSTRAINTS tc2 ON tc2.CONSTRAINT_NAME =rc1.CONSTRAINT_NAME

OPEN @Cursor FETCH NEXT FROM @Cursor INTO @Sql

WHILE (@@FETCH_STATUS = 0)
BEGIN
Exec sp_executesql @Sql
FETCH NEXT FROM @Cursor INTO @Sql
END

CLOSE @Cursor DEALLOCATE @Cursor
GO

EXEC sp_MSforeachtable 'DROP TABLE ?'
GO

您可以找到帖子here。这是格罗克的帖子。

Answer 3

delete用于从表中删除行。您应该使用drop table代替。

EXEC sp_msforeachtable 'drop table [?]'

Answer 4

/* Drop all Primary Key constraints */
DECLARE @name VARCHAR(128)
DECLARE @constraint VARCHAR(254)
DECLARE @SQL VARCHAR(254)

SELECT @name = (SELECT TOP 1 TABLE_NAME FROM INFORMATION_SCHEMA.TABLE_CONSTRAINTS WHERE constraint_catalog=DB_NAME() AND CONSTRAINT_TYPE = 'PRIMARY KEY' ORDER BY TABLE_NAME)

WHILE @name IS NOT NULL
BEGIN
    SELECT @constraint = (SELECT TOP 1 CONSTRAINT_NAME FROM INFORMATION_SCHEMA.TABLE_CONSTRAINTS WHERE constraint_catalog=DB_NAME() AND CONSTRAINT_TYPE = 'PRIMARY KEY' AND TABLE_NAME = @name ORDER BY CONSTRAINT_NAME)
    WHILE @constraint is not null
    BEGIN
        SELECT @SQL = 'ALTER TABLE [dbo].[' + RTRIM(@name) +'] DROP CONSTRAINT [' + RTRIM(@constraint)+']'
        EXEC (@SQL)
        PRINT 'Dropped PK Constraint: ' + @constraint + ' on ' + @name
        SELECT @constraint = (SELECT TOP 1 CONSTRAINT_NAME FROM INFORMATION_SCHEMA.TABLE_CONSTRAINTS WHERE constraint_catalog=DB_NAME() AND CONSTRAINT_TYPE = 'PRIMARY KEY' AND CONSTRAINT_NAME <> @constraint AND TABLE_NAME = @name ORDER BY CONSTRAINT_NAME)
    END
SELECT @name = (SELECT TOP 1 TABLE_NAME FROM INFORMATION_SCHEMA.TABLE_CONSTRAINTS WHERE constraint_catalog=DB_NAME() AND CONSTRAINT_TYPE = 'PRIMARY KEY' ORDER BY TABLE_NAME)
END
GO

/* Drop all tables */
DECLARE @name VARCHAR(128)
DECLARE @SQL VARCHAR(254)

SELECT @name = (SELECT TOP 1 [name] FROM sysobjects WHERE [type] = 'U' AND category = 0 ORDER BY [name])

WHILE @name IS NOT NULL
BEGIN
    SELECT @SQL = 'DROP TABLE [dbo].[' + RTRIM(@name) +']'
    EXEC (@SQL)
    PRINT 'Dropped Table: ' + @name
    SELECT @name = (SELECT TOP 1 [name] FROM sysobjects WHERE [type] = 'U' AND category = 0 AND [name] > @name ORDER BY [name])
END
GO

Answer 5

你几乎是对的，改为使用：

EXEC sp_msforeachtable 'ALTER TABLE ? NOCHECK CONSTRAINT all'
EXEC sp_msforeachtable 'DROP TABLE ?'

但第二行你可能需要再执行一次，直到你不再收到错误：

Could not drop object 'dbo.table' because it is referenced by a FOREIGN KEY constraint.

消息：

Command(s) completed successfully.

表示所有表格都已成功删除。

Answer 6

在SSMS中：

• 右键单击数据库
• 转到＆＃34;任务＆＃34;
• 点击＆＃34;生成脚本＆＃34;
• 在＆＃34;选择对象＆＃34;部分，选择＆＃34;脚本整个数据库和所有数据库对象＆＃34;
• 在＆＃34;设置脚本选项＆＃34;部分，单击＆＃34;高级＆＃34;按钮
• On＆＃34; Script DROP AND CREATE＆＃34;切换＆＃34;脚本创建＆＃34; to＆＃34; Script DROP＆＃34;然后按OK
• 然后，保存到文件，剪贴板或新查询窗口。
• 运行脚本。

现在，这将删除所有内容，包括数据库。请务必删除您不想删除的项目的代码。或者，在＆＃34;选择对象＆＃34;部分，而不是选择脚本整个数据库只需选择要删除的项目。

Answer 7

短而甜蜜：

USE YOUR_DATABASE_NAME
-- Disable all referential integrity constraints
EXEC sp_MSforeachtable 'ALTER TABLE ? NOCHECK CONSTRAINT ALL'
GO

-- Drop all PKs and FKs
declare @sql nvarchar(max)
SELECT @sql = STUFF((SELECT '; ' + 'ALTER TABLE ' + Table_Name  +'  drop constraint ' + Constraint_Name  from Information_Schema.CONSTRAINT_TABLE_USAGE ORDER BY Constraint_Name FOR XML PATH('')),1,1,'')
EXECUTE (@sql)
GO

-- Drop all tables
EXEC sp_MSforeachtable 'DROP TABLE ?'
GO

Answer 8

接受的答案不支持Azure。它使用未记录的存储过程“sp_MSforeachtable”。如果在运行时遇到“azure无法找到存储过程'sp_msforeachtable”错误，或者只是想避免依赖未记录的功能（可以删除或在任何时候更改其功能），请尝试以下操作。

此版本忽略实体框架迁移历史记录表“__MigrationHistory”和“database_firewall_rules”，它是您无权删除的Azure表。

在Azure上进行了轻微测试。请检查这是否对您的环境没有任何不良影响。

DECLARE @sql NVARCHAR(2000)

WHILE(EXISTS(SELECT 1 from INFORMATION_SCHEMA.TABLE_CONSTRAINTS WHERE CONSTRAINT_TYPE='FOREIGN KEY'))
BEGIN
    SELECT TOP 1 @sql=('ALTER TABLE ' + TABLE_SCHEMA + '.[' + TABLE_NAME + '] DROP CONSTRAINT [' + CONSTRAINT_NAME + ']')
    FROM INFORMATION_SCHEMA.TABLE_CONSTRAINTS
    WHERE CONSTRAINT_TYPE = 'FOREIGN KEY'
    EXEC(@sql)
    PRINT @sql
END

WHILE(EXISTS(SELECT * from INFORMATION_SCHEMA.TABLES WHERE TABLE_NAME != '__MigrationHistory' AND TABLE_NAME != 'database_firewall_rules'))
BEGIN
    SELECT TOP 1 @sql=('DROP TABLE ' + TABLE_SCHEMA + '.[' + TABLE_NAME + ']')
    FROM INFORMATION_SCHEMA.TABLES
    WHERE TABLE_NAME != '__MigrationHistory' AND TABLE_NAME != 'database_firewall_rules'
    EXEC(@sql)
    PRINT @sql
END

取自：

https://edspencer.me.uk/2013/02/25/drop-all-tables-in-a-sql-server-database-azure-friendly/

http://www.sqlservercentral.com/blogs/sqlservertips/2011/10/11/remove-all-foreign-keys/

Answer 9

现货!!

您可以使用以下查询从数据库中删除所有表

EXEC sp_MSforeachtable @ command1 =“ DROP TABLE吗？”

编码愉快！

Answer 10

似乎命令应该没有方形毯子

EXEC sp_msforeachtable 'drop table ?'

Answer 11

对我而言，最简单的方法是：

--First delete all constraints

DECLARE @sql NVARCHAR(MAX);
SET @sql = N'';

SELECT @sql = @sql + N'
ALTER TABLE ' + QUOTENAME(s.name) + N'.'
+ QUOTENAME(t.name) + N' DROP CONSTRAINT '
+ QUOTENAME(c.name) + ';'
FROM sys.objects AS c
INNER JOIN sys.tables AS t
ON c.parent_object_id = t.[object_id]
INNER JOIN sys.schemas AS s 
ON t.[schema_id] = s.[schema_id]
WHERE c.[type] IN ('D','C','F','PK','UQ')
ORDER BY c.[type];

EXEC sys.sp_executesql @sql;

-- Then drop all tables

exec sp_MSforeachtable 'DROP TABLE ?'

Answer 12

如何删除整个数据库然后再次创建它？这对我有用。

DROP DATABASE mydb;
CREATE DATABASE mydb;

Answer 13

我知道这是一篇很老的帖子，但是我已经尝试了很多数据库上的所有答案，我发现它们有时都工作但不是所有的时间（我只能假设）SQL的怪癖服务器

最终我想出了这个。我已经测试了这个（一般来说）我可以和它工作（没有任何隐藏的存储过程）。

主要是关于SQL Server 2014的说明。（但我尝试过的大多数其他版本似乎也运行良好）。

我已尝试过while循环和null等等，游标和其他各种形式，但它们似乎总是在某些数据库上失败但在其他情况下却没有明显的原因。

计算并使用它进行迭代似乎总是适用于我测试的所有内容。

USE [****YOUR_DATABASE****]
GO

SET ANSI_NULLS ON
GO

SET QUOTED_IDENTIFIER ON
GO

-- Drop all referential integrity constraints --
-- Drop all Primary Key constraints.          --

DECLARE @sql  NVARCHAR(296)
DECLARE @table_name VARCHAR(128)

DECLARE @constraint_name VARCHAR(128)
SET @constraint_name = ''

DECLARE @row_number INT

SELECT @row_number = Count(*) FROM INFORMATION_SCHEMA.REFERENTIAL_CONSTRAINTS rc1
LEFT JOIN INFORMATION_SCHEMA.TABLE_CONSTRAINTS tc2 ON tc2.CONSTRAINT_NAME = rc1.CONSTRAINT_NAME

WHILE @row_number > 0
BEGIN
    BEGIN
        SELECT TOP 1 @table_name = tc2.TABLE_NAME, @constraint_name = rc1.CONSTRAINT_NAME FROM INFORMATION_SCHEMA.REFERENTIAL_CONSTRAINTS rc1
        LEFT JOIN INFORMATION_SCHEMA.TABLE_CONSTRAINTS tc2 ON tc2.CONSTRAINT_NAME = rc1.CONSTRAINT_NAME
        AND rc1.CONSTRAINT_NAME > @constraint_name
        ORDER BY rc1.CONSTRAINT_NAME
        SELECT @sql = 'ALTER TABLE [dbo].[' + RTRIM(@table_name) +'] DROP CONSTRAINT [' + RTRIM(@constraint_name)+']'
        EXEC (@sql)
        PRINT 'Dropped Constraint: ' + @constraint_name + ' on ' + @table_name
        SET @row_number = @row_number - 1
    END
END
GO

-- Drop all tables --

DECLARE @sql  NVARCHAR(156)
DECLARE @name VARCHAR(128)
SET @name = ''

DECLARE @row_number INT

SELECT @row_number = Count(*) FROM sysobjects WHERE [type] = 'U' AND category = 0

WHILE @row_number > 0
BEGIN
    SELECT @name = (SELECT TOP 1 [name] FROM sysobjects WHERE [type] = 'U' AND category = 0 AND [name] > @name ORDER BY [name])
    SELECT @sql = 'DROP TABLE [dbo].[' + RTRIM(@name) +']'
    EXEC (@sql)
    PRINT 'Dropped Table: ' + @name
    SET @row_number = @row_number - 1
END
GO

Answer 14

如果要删除所有表，也可以删除数据库，然后创建一个新的数据库。

T-SQL：

  

DROP DATABASE罗斯文（Northwind）
  开始
  创建数据库Northwind
  开始

要在 SQL Management Studio（在我的情况下为SSMS v 17.9.1）中实现此目标，

1. 右键单击要删除的数据库，例如“北风”;
   在上下文菜单中选择“删除”
2. 右键单击“数据库” （文件夹图标）；
   选择“新数据库...”
3. 键入数据库名称，例如“北风”;
   点击确定

您完成了！您有一个没有任何表的新数据库。这种方法的优点是，您无需担心任何约束，禁止删除表，从属视图或SP不再起作用，也不需要任何动态SQL脚本。您可以在以后进行备份的情况下重新添加它们，所以

记住，要在之前备份数据库！如果只需要一些SP或视图，请在重新创建数据库之前将它们另存为脚本，然后对其进行编辑，以便它们可用于新表并在以后添加它们。

Answer 15

对于临时表，由于可能存在一些外键以及例外情况，因此更为复杂

Drop table operation failed on table XXX because it is not a supported operation on system-versioned temporal tables

您可以使用的是：

-- Disable constraints (foreign keys)
EXEC sp_MSForEachTable 'ALTER TABLE ? NOCHECK CONSTRAINT ALL'
GO

-- Disable system versioning (temporial tables)
EXEC sp_MSForEachTable '
 IF OBJECTPROPERTY(object_id(''?''), ''TableTemporalType'') = 2
  ALTER TABLE ? SET (SYSTEM_VERSIONING = OFF)
'
GO

-- Removing tables
EXEC sp_MSForEachTable 'DROP TABLE ?'
GO