Question

在Delphi标准库中是否有一个函数来搜索字符串数组中的特定值？

e.g。

someArray:=TArray<string>.Create('One','Two','Three');
if ArrayContains(someArray, 'Two') then
    ShowMessage('It contains Two');

Answer 1

绝对没有必要重新发明轮子。 StrUtils.MatchStr完成这项工作。

procedure TForm1.FormCreate(Sender: TObject);
var
  someArray: TArray<string>;
begin
  someArray:=TArray<string>.Create('One','Two','Three');
  if MatchStr('Two', someArray) then
    ShowMessage('It contains Two');
end;

请注意参数顺序约定。

另一个注意事项：MatchStr是在Delphi 7和Delphi 2007之间分配给此函数的规范化名称。历史名称是AnsiMatchStr（约定与RTL的其余部分相同：Str /区分大小写的文本后缀，MBCS / Locale的Ansi前缀）

Answer 2

您可以使用TArray.BinarySearch函数，它是Generics.Collections单元的一部分。

检查此示例

{$APPTYPE CONSOLE}

{$R *.res}

uses    
  Generics.Defaults,
  Generics.Collections,
  System.SysUtils;

Var
  someArray: TArray<string>;
  FoundIndex : Integer;

begin
  try
    someArray:=TArray<string>.Create('a','b','c');
    if TArray.BinarySearch<String>(someArray, 'b', FoundIndex, TStringComparer.Ordinal) then
     Writeln(Format('Found in index %d',[FoundIndex]))
    else
     Writeln('Not Found');
  except
    on E: Exception do
      Writeln(E.ClassName, ': ', E.Message);
  end;
  Readln;
end.

注意：BinarySearch要求对数组进行排序。

Answer 3

我写了一个我在旧Clipper AScan函数（在XE中测试）后建模的模型。 @ RRUZ的答案更正确（有一个现有的），但是我不需要先对数组进行排序，并且在小数组上足够快。（它也适用于Delphi的pre-generics版本。）我还为各种类型的数组重载它 - 这里是string和integer的实现：

// Returns the 0-based index of Value if it's found in the array,
// -1 if not. (Similar to TStrings.IndexOf)
function AScan(const Ar: array of string; const Value: string): Integer; overload;
var
  i: Integer;
begin
  Result := -1;
  for i := Low(Ar) to High(Ar) do
    if SameText(Ar[i], Value) then
    begin
      Result := i;
      Break
    end;
end;

function AScan(const Ar: array of Integer; const Value: Integer): Integer; overload;
var
  i: Integer;
begin
  Result := -1;
  for i := Low(Ar) to High(Ar) do
    if (Ar[i] = Value) then
    begin
      Result := i;
      Break
    end;
end;

procedure TForm2.FormShow(Sender: TObject);
var
  someStrArray: TArray<string>;
  someIntArray: TArray<Integer>;
  Idx: Integer;
begin
  someStrArray := TArray<string>.Create('One', 'Two', 'Three');
  Idx := AScan(someStrArray, 'Two');
  if Idx > -1 then
    ShowMessage(Format('It contains Two at index %d', [Idx]))
  else
    ShowMessage('Not found');
  someIntArray := TArray<Integer>.Create(8, 16, 32);
  Idx := AScan(someIntArray, 32);
  if Idx > -1 then
    ShowMessage(Format('It contains 32 at %d', [Idx]))
  else
    ShowMessage('16 not found');
end;

对于支持泛型的Delphi版本，这里的版本不需要对数组进行排序，并且还允许您在需要时提供比较函数：

接口：

type
  TGenericsUtils = class
  public
    class function AScan<T>(const Arr: array of T; const Value: T; const Comparer: IEqualityComparer<T>):  Integer; overload;
    class function AScan<T>(const Arr: array of T; const Value: T): Integer; overload;
  end;

实施

class function TGenericsUtils.AScan<T>(const Arr: array of T; const Value: T): Integer;
begin
  Result := AScan<T>(Arr, Value, TEqualityComparer<T>.Default);
end;

class function TGenericsUtils.AScan<T>(const Arr: array of T; const Value: T;
  const Comparer: IEqualityComparer<T>): Integer;
var
  i: Integer;
begin
  for i := Low(Arr) to High(Arr) do
    if Comparer.Equals(Arr[i], Value) then
      Exit(i);
  Exit(-1);
end;

测试代码：

var
  AIntTest: TIntegerDynArray;
  AStrTest: TStringDynArray;

begin
  AIntTest := TIntegerDynArray.Create(12, 15, 6, 1, 4, 9, 5);
  AStrTest := TStringDynArray.Create('One', 'Six', 'Three', 'Four', 'Twelve');
  WriteLn('AIntTest contains 9 at index ', TGenericsUtils.AScan<Integer>(AIntTest, 9));
  WriteLn('AStrTest contains ''Four'' at index ', TGenericsUtils.AScan<String>(AStrTest, 'Four'));
  ReadLn;
end.

在Delphi中搜索String数组

3 个答案: