Question

我有无约束的泛型类型Atomic，它实现了一个初始化器（我的previous question中的详细信息）。

type
  Atomic<T> = class
    type TFactory = reference to function: T;
    class function Initialize(var storage: T; factory: TFactory): T;
  end;

现在我想编写简化的Initialize函数，该函数将从T获取类型信息（假设typeof（T）是tkClass）并使用默认构造函数创建新实例（必要时）。

可悲的是，这失败了：

class function Atomic<T>.Initialize(var storage: T): T;
begin
  if not assigned(PPointer(@storage)^) then begin
    if PTypeInfo(TypeInfo(T))^.Kind  <> tkClass then
      raise Exception.Create('Atomic<T>.Initialize: Unsupported type');
    Result := Atomic<T>.Initialize(storage,
      function: T
      begin
        Result := TClass(T).Create; // <-- E2571
      end);
  end;
end;

编译器报告错误E2571 Type parameter 'T' doesn't have class or interface constraint。

如何欺骗编译器创建类T的实例？

Answer 1

您可以使用GetTypeData获取课程参考：

Result := T(GetTypeData(PTypeInfo(TypeInfo(T)))^.ClassType.Create);

在Delphi XE2中（希望在下一版本中），你可以这样做：

var
  xInValue, xOutValue: TValue;

xInValue := GetTypeData(PTypeInfo(TypeInfo(T)))^.ClassType.Create;
xInValue.TryCast(TypeInfo(T), xOutValue);
Result := xOutValue.AsType<T>;

（在OmniThreadLibrary论坛中使用cjsalamon发现了这种相当规避的方式：Error in OtlSync XE2。）

Answer 2

您可以使用新的Delphi Rtti来完成此任务。给定解决方案的缺点是，如果构造函数未命名为Create，则它将无法工作。如果你需要让它一直工作，只需枚举你的类型方法，检查它是否是一个构造函数并且有0个参数，然后调用它。适用于Delphi XE。示例代码：

class function TTest.CreateInstance<T>: T;
var
  AValue: TValue;
  ctx: TRttiContext;
  rType: TRttiType;
  AMethCreate: TRttiMethod;
  instanceType: TRttiInstanceType;
begin
  ctx := TRttiContext.Create;
  rType := ctx.GetType(TypeInfo(T));
  AMethCreate := rType.GetMethod('Create');

  if Assigned(AMethCreate) and rType.IsInstance then
  begin
    instanceType := rType.AsInstance;

    AValue := AMethCreate.Invoke(instanceType.MetaclassType, []);// create parameters

    Result := AValue.AsType<T>;
  end;
end;

更新解决方案：

class function TTest.CreateInstance<T>: T;
var
  AValue: TValue;
  ctx: TRttiContext;
  rType: TRttiType;
  AMethCreate: TRttiMethod;
  instanceType: TRttiInstanceType;
begin
  ctx := TRttiContext.Create;
  rType := ctx.GetType(TypeInfo(T));
  for AMethCreate in rType.GetMethods do
  begin
    if (AMethCreate.IsConstructor) and (Length(AMethCreate.GetParameters) = 0) then
    begin
      instanceType := rType.AsInstance;

      AValue := AMethCreate.Invoke(instanceType.MetaclassType, []);

      Result := AValue.AsType<T>;

      Exit;
    end;
  end;
end;

并称之为：

var
  obj: TTestObj;
begin
  obj := TTest.CreateType<TTestObj>;

Answer 3

如果我做对了，通用类型“T”就是一个类。在这种情况下，只需声明：

Atomic< T: class > = class

而不是单位

Atomic< T > = class

这将告诉编译器T是类类型，因此您将能够使用构造函数和类类型的所有其他功能，而无需任何额外的解决方法。

如果我的理解在基础假设中是错误的，我道歉。

基于无约束泛型类型创建对象实例

3 个答案: