Question

有没有办法将DateDiff的DatePart参数作为变量传递？这样我可以编写与此类似的代码吗？

DECLARE @datePart VARCHAR(2)
DECLARE @dateParameter INT

SELECT @datePart = 'dd'
SELECT @dateParameter = 28

SELECT
    *
FROM
    MyTable
WHERE
    DATEDIFF(@datePart, MyTable.MyDate, GETDATE()) < @dateParameter

我能想到的唯一方法是使用CASE语句检查参数的值，或者将SQL构建为字符串并在EXEC中运行它。

有没有人有任何“更好”的建议？该平台是MS SQL Server 2005

Answer 1

根据SQL Server 2005的DATEDIFF（参数部分）上的BOL条目，

这些日期部分和缩写不能作为用户声明的变量提供。

因此您可能会遇到动态SQL或使用CASE语句。但我会选择CASE版本而不是动态SQL。

Answer 2

旧的但不幸的是仍然有效。

我是这样做的，只是想分享代码，所以你不必做我必须做的所有烦人的打字。涵盖所有可能的日期部分。只需替换函数的名称和日期函数，以实现其他T-SQL日期函数。

复制和粘贴部分

-- SELECT dbo.fn_DateAddFromStringPart('year', 1, GETDATE())
CREATE FUNCTION fn_DateAddFromStringPart
(
    @Interval VARCHAR(11),
    @Increment INT,
    @Date SMALLDATETIME
)
RETURNS DATETIME
AS
BEGIN
    -- Declare the return variable here
    DECLARE @NewDate DATETIME

    -- Add the T-SQL statements to compute the return value here
    SELECT @NewDate = CASE
        WHEN @Interval IN ('year', 'yy', 'yyyy') THEN DATEADD(YEAR, @Increment, @Date)
        WHEN @Interval IN ('quarter', 'qq', 'q') THEN DATEADD(QUARTER, @Increment, @Date)
        WHEN @Interval IN ('month', 'mm', 'm') THEN DATEADD(MONTH, @Increment, @Date)
        WHEN @Interval IN ('dayofyear', 'dy', '') THEN DATEADD(DAYOFYEAR, @Increment, @Date)
        WHEN @Interval IN ('day', 'dd', 'd') THEN DATEADD(DAY, @Increment, @Date)
        WHEN @Interval IN ('week', 'wk', 'ww') THEN DATEADD(WEEK, @Increment, @Date)
        WHEN @Interval IN ('weekday', 'dw', 'w') THEN DATEADD(WEEKDAY, @Increment, @Date)
        WHEN @Interval IN ('hour', 'hh') THEN DATEADD(HOUR, @Increment, @Date)
        WHEN @Interval IN ('minute', 'mi', 'n') THEN DATEADD(MINUTE, @Increment, @Date)
        WHEN @Interval IN ('second', 'ss', 's') THEN DATEADD(SECOND, @Increment, @Date)
        WHEN @Interval IN ('millisecond', 'ms') THEN DATEADD(MILLISECOND, @Increment, @Date)
        WHEN @Interval IN ('microsecond', 'mcs') THEN DATEADD(MICROSECOND, @Increment, @Date)
        WHEN @Interval IN ('nanosecond', 'ns') THEN DATEADD(NANOSECOND, @Increment, @Date)
    END

    -- Return the result of the function
    RETURN @NewDate

END
GO

Answer 3

除了建议的动态sql或case语句之外，你唯一可以做的就是始终在粒度DatePart上执行datediff然后upconvert。这不是万无一失的，如果你试图在一个太大的范围内对一个部分进行粒化处理，你会在函数中出现溢出，例如datediff（第二，0，getdate（））。但是如果你只是需要像微小部分这样的东西你应该没问题（仔细检查你关心的最大日期值）。

所以例如

select datediff(minute, 0, getdate())

如果我想将其转换为小时，天等，我可以将结果除以适当的数量。它不会考虑闰年等。

Answer 4

绝对使用下面这样的动态查询效果很好，我假设你打算只使用@datePart的缩写。我建议使用最少的VARCHAR（4）作为datepart，这将处理yyyy和mcs等缩写。快乐的编码：

DECLARE @datePart VARCHAR(2)
DECLARE @dateParameter INT
DECLARE @SQLTemp varchar(MAX)


SELECT @datePart = 'dd'
SELECT @dateParameter = 28

set  @SQLTemp ='SELECT * FROM MyTable
    WHERE DATEDIFF('+@datePart+', '+MyTable.MyDate+', GETDATE()) < '+@dateParameter

exec (@SQLTemp)

Answer 5

我不认为你描述的方法更好。 Sql Server可能会将DATEDIFF查询编译为依赖于datepart参数的一组操作。所以你需要一个CASE或动态查询。

Answer 6

我创建了一个Scalar值函数来执行此操作。它基于上面提到的解决方案，但在代码中更容易实现

CREATE FUNCTION [dbo].[dynamic_dateadd] 
(
@unit varchar(5),
@number int,
@dt datetime
)
RETURNS datetime
AS
BEGIN
    declare @result datetime
    if (@unit='M') BEGIN SET @result=(select DATEADD(M,@number,@dt)) END
    if (@unit='WW') BEGIN SET @result=(select DATEADD(WW,@number,@dt)) END
    if (@unit='D') BEGIN SET @result=(select DATEADD(D,@number,@dt)) END
    if (@unit='H') BEGIN SET @result=(select DATEADD(HH,@number,@dt)) END
    return(@result)
END

在查询中，您可以使用此功能：

select startdate, validity_unit, validity_number,
dbo.dynamic_dateadd(valididy_unit,validity_number,startdate) as enddate
from SALES_subscription

使用DateDiff时的SQL动态DatePart

6 个答案: