Question

我正在研究Cortex-A8和Cortex-A9。我知道有些架构没有整数除法，但除了转换为float，divide，转换为整数之外，最好的方法是什么？或者这确实是最好的解决方案？

干杯！ =）

Answer 1

通过执行64位乘法和右移，可以快速完成除以常数值的分割，例如：

LDR     R3, =0xA151C331
UMULL   R3, R2, R1, R3
MOV     R0, R2,LSR#10

这里R1除以1625。计算如下：64bitreg（R2：R3）= R1 * 0xA151C331，然后结果是上移32位右移10：

R1*0xA151C331/2^(32+10) = R1*0.00061538461545751488 = R1/1624.99999980

您可以使用以下公式计算自己的常量：

x / N ==  (x*A)/2^(32+n)   -->       A = 2^(32+n)/N

选择最大的n，其中A＆lt; 2 ^ 32

Answer 2

来自其他地方的一些复制意大利面的整数除法：基本上，每位3条指令。来自this网站，虽然我也看过很多其他地方。 This网站也有一个不错的版本，一般来说可能更快。


@ Entry  r0: numerator (lo) must be signed positive
@        r2: deniminator (den) must be non-zero and signed negative
idiv:
        lo .req r0; hi .req r1; den .req r2
        mov hi, #0 @ hi = 0
        adds lo, lo, lo
        .rept 32 @ repeat 32 times
          adcs hi, den, hi, lsl #1
          subcc hi, hi, den
          adcs lo, lo, lo
        .endr
        mov pc, lr @ return
@ Exit   r0: quotient (lo)
@        r1: remainder (hi)

Answer 3

编译器通常在其库中包含一个除法，例如gcclib我从gcc中提取它们并直接使用它们：

https://github.com/dwelch67/stm32vld/然后是stm32f4d / adventure / gcclib

漂浮和退回可能不是最好的解决方案。你可以尝试一下，看看它有多快......这是一个繁殖，但很容易让它成为一个分歧：

https://github.com/dwelch67/stm32vld/然后是stm32f4d / float01 / vectors.s

我没看时间，看看有多快/慢。理解我正在使用上面的皮层 - 你正在谈论皮质-a，光谱的不同末端，类似的浮动指令和gcc lib的东西是相似的，对于皮质-m我必须为拇指建立但你可以就像轻松建立手臂一样。实际上使用gcc它应该只是自动工作你不应该像我做的那样去做。其他编译器也不应该像我在上面的冒险游戏中那样做。

Answer 4

我编写了自己的例程来执行无符号分区，因为我在网上找不到未签名的版本。我需要将64位值除以32位值以获得32位结果。

内部循环不如上面提供的签名解决方案有效，但这确实支持无符号算术。如果分子（hi）的高部分小于分母（den），则该例程执行32位除法，否则执行完整的64位除法（hi：lo / den）。结果是lo。

  cmp     hi, den                   // if hi < den do 32 bits, else 64 bits
  bpl     do64bits
  REPT    32
    adds    lo, lo, lo              // shift numerator through carry
    adcs    hi, hi, hi
    subscc  work, hi, den           // if carry not set, compare        
    subcs   hi, hi, den             // if carry set, subtract
    addcs   lo, lo, #1              // if carry set, and 1 to quotient
  ENDR

  mov     r0, lo                    // move result into R0
  mov     pc, lr                    // return

do64bits:
  mov     top, #0
  REPT    64
    adds    lo, lo, lo              // shift numerator through carry
    adcs    hi, hi, hi
    adcs    top, top, top
    subscc  work, top, den          // if carry not set, compare        
    subcs   top, top, den           // if carry set, subtract
    addcs   lo, lo, #1              // if carry set, and 1 to quotient
  ENDR
  mov     r0, lo                    // move result into R0
  mov     pc, lr                    // return

可以添加额外检查边界条件和2的功率。有关详细信息，请访问http://www.idwiz.co.za/Tips%20and%20Tricks/Divide.htm

Answer 5

我为ARM GNU汇编程序编写了以下函数。如果您没有拥有udiv/sdiv机器支持的CPU，只需将前几行剪切到＆＃34; 0：＆＃34;两种功能中的标签。

.arm
.cpu    cortex-a7
.syntax unified

.type   udiv,%function
.globl  udiv
udiv:   tst     r1,r1
        bne     0f
        udiv    r3,r0,r2
        mls     r1,r2,r3,r0
        mov     r0,r3
        bx      lr
0:      cmp     r1,r2
        movhs   r1,r2
        bxhs    lr
        mvn     r3,0
1:      adds    r0,r0
        adcs    r1,r1
        cmpcc   r1,r2
        subcs   r1,r2
        orrcs   r0,1
        lsls    r3,1
        bne     1b
        bx      lr
.size   udiv,.-udiv

.type   sdiv,%function
.globl  sdiv
sdiv:   teq     r1,r0,ASR 31
        bne     0f
        sdiv    r3,r0,r2
        mls     r1,r2,r3,r0
        mov     r0,r3
        bx      lr
0:      mov     r3,2
        adds    r0,r0
        and     r3,r3,r1,LSR 30
        adcs    r1,r1
        orr     r3,r3,r2,LSR 31
        movvs   r1,r2
        ldrvc   pc,[pc,r3,LSL 2]
        bx      lr
        .int    1f
        .int    3f
        .int    5f
        .int    11f
1:      cmp     r1,r2
        movge   r1,r2
        bxge    lr
        mvn     r3,1
2:      adds    r0,r0
        adcs    r1,r1
        cmpvc   r1,r2
        subge   r1,r2
        orrge   r0,1
        lsls    r3,1
        bne     2b
        bx      lr
3:      cmn     r1,r2
        movge   r1,r2
        bxge    lr
        mvn     r3,1
4:      adds    r0,r0
        adcs    r1,r1
        cmnvc   r1,r2
        addge   r1,r2
        orrge   r0,1
        lsls    r3,1
        bne     4b
        rsb     r0,0
        bx      lr
5:      cmn     r1,r2
        blt     6f
        tsteq   r0,r0
        bne     7f
6:      mov     r1,r2
        bx      lr
7:      mvn     r3,1
8:      adds    r0,r0
        adcs    r1,r1
        cmnvc   r1,r2
        blt     9f
        tsteq   r0,r3
        bne     10f
9:      add     r1,r2
        orr     r0,1
10:     lsls    r3,1
        bne     8b
        rsb     r0,0
        bx      lr
11:     cmp     r1,r2
        blt     12f
        tsteq   r0,r0
        bne     13f
12:     mov     r1,r2
        bx      lr
13:     mvn     r3,1
14:     adds    r0,r0
        adcs    r1,r1
        cmpvc   r1,r2
        blt     15f
        tsteq   r0,r3
        bne     16f
15:     sub     r1,r2
        orr     r0,1
16:     lsls    r3,1
        bne     14b
        bx      lr

有两个函数，udiv表示无符号整数除法，sdiv表示有符号整数除法。它们都期望r1（高字）和r0（低字）中的64位被除数（有符号或无符号），以及r2中的32位除数。它们返回r0中的商和r1中的余数，因此您可以在C header中将它们定义为extern，返回64位整数并屏蔽商和之后的余数。误差（除以0或溢出）由具有大于或等于除数的绝对值的绝对值的余数表示。带符号的除法算法通过除数和除数的符号来区分大小写;它不会首先转换为正整数，因为它不能正确检测所有溢出条件。

如何对ARM进行整数（有符号或无符号）除法？

5 个答案: