Question

我使用ANTLR来解析数学表达式的字符串并使用MathML标记它们。

现在我的语法如下。现在我有三个问题：

语法允许使用2*(3+4)之类的完整表达式。我想要它还允许不完整的表达，例如2*(3+。成为一个在ANTLR完成新手我不知道如何实现这一目标。请指出正确的文件或举例。
似乎是原子中平方根规则sqrt的位置工作，但我很确定它应该在exponent的某个地方规则？或者应该吗？
如果我想扩展这个语法也实际执行计算，我可以以某种方式重复使用它，还是我必须复制和粘贴？

我对语法的任何其他意见或建议也表示赞赏，因为我对ANTLR的总体经验现在大约需要4个小时。

grammar Expr;

parse returns [String value]
    :   stat+ {$value = $stat.value;}
    ;

stat returns [String value]
    :   exponent NEWLINE {$value = "<math>" + $exponent.value + "</math>";}
    |   NEWLINE
    ;

exponent returns [String value]
    :   e=expr {$value = $e.value;}
        (   '^' e=expr {$value = "<msup><mrow>" + $value + "</mrow><mrow>" + $e.value + "</mrow></msup>";}
        )*
    ;

expr returns [String value]
    :   e=multExpr {$value = $e.value;}
        (   '+' e=multExpr {$value += "<mo>+</mo>" + $e.value;}
        |   '-' e=multExpr {$value += "<mo>-</mo>" + $e.value;}
        )*
    ;

multExpr returns [String value]
    :   e=atom {$value = $e.value;} 
        (   '*' e=atom {$value += "<mo>*</mo>" + $e.value;}
        |   '/' e=atom {$value += "<mo>/</mo>" + $e.value;}
        )*
    ; 

atom returns [String value]
    :   INT {$value = "<mn>" + $INT.text + "</mn>";}
    |   '-' e=atom {$value = "<mo>-</mo>" + $e.value;}
    |   'sqrt[' exponent ']' {$value = "<msqrt><mrow>" + $exponent.value + "</mrow></msqrt>";}
    |   '(' exponent ')' {$value = "<mo>(</mo>" + $exponent.value + "<mo>)</mo>";}
    ;

INT :   '0'..'9'+ ;
NEWLINE:'\r'? '\n' ;
WS  :   (' '|'\t')+ {skip();} ;

Answer 1

首先谈谈你的语法：

您应该为左侧和右侧（e1=atom ('*' e2=atom ...）;
您可能想要创建单独的sqrt和[令牌而不是1个sqrt[，否则请输入"sqrt [ 9 ]"（sqrt之间的空格并且[）处理不当;
一元减号通常优先于取幂。

rickythefox写道：

原子中的平方根规则sqrt的位置似乎有效，但我很确定它应该在指数规则中的某个位置？还是应该呢？

不，那里很好：它应该具有最高优先级。说到优先级，在你的情况下通常的优先级表（从最低到最高）将是：

添加＆amp;减法;
乘法＆amp;划分;
一元减号;
求幂;
带括号的表达式（包括函数调用，如sqrt[...]）。

rickythefox写道：

语法允许完整的表达式，如2 *（3 + 4）。我希望它也允许不完整的表达，例如2 *（3+。作为ANTLR的完全新手，我不知道如何实现这一点。请指出正确的文件或举例。

这很棘手。

我真的只看到一种方式：在你的统计规则中，你首先强制解析器在令牌流中向前看，以检查是否提前expr。这可以使用syntactic predicate来完成。一旦解析器确定存在expr，则只解析所述表达式。如果没有expr，请尝试匹配NEWLINE，如果还没有NEWLINE，则只需使用NEWLINE以外的单个令牌（必须成为不完整表达的一部分！）。 （我将在下面发布一个小演示）

rickythefox写道：

如果我想扩展这个语法以实际执行计算，我可以以某种方式重复使用它还是必须复制和粘贴？

ANTLR解析器规则可以返回多个对象。当然，这并不是真的，因为Java方法（解析器规则本质上是）只能返回单个对象。解析器规则返回一个对象，该对象包含对多个对象的引用。所以你可以这样做：

stat returns [String str, double num]
  :  ...
  ;

演示

考虑到我的所有提示，一个小型的工作演示可能如下所示：

grammar Expr;

parse returns [String str, double num]
@init{$str = "";}
  :  (stat 
     {
       $str += $stat.str;
       $num = $stat.num;
       if(!Double.isNaN($num)) {
         System.out.println($stat.text.trim() + " = " + $num);
       }
     })+
  ;

stat returns [String str, double num]
  : (expr)=> expr NEWLINE      {$str = "<math>" + $expr.str + "</math>"; $num = $expr.num;}
  |          NEWLINE           {$str = ""; $num = Double.NaN;}
  |          ~NEWLINE          {$str = ""; $num = Double.NaN; System.err.println("Ignoring: " + $text);}
  ;

expr returns [String str, double num]
  :  e1=multExpr       {$str = $e1.str; $num = $e1.num;}
     ( '+' e2=multExpr {$str += "<mo>+</mo>" + $e2.str; $num += $e2.num;}
     | '-' e2=multExpr {$str += "<mo>-</mo>" + $e2.str; $num -= $e2.num;}
     )*
  ;

multExpr returns [String str, double num]
  :  e1=unaryExpr       {$str = $e1.str; $num = $e1.num;} 
     ( '*' e2=unaryExpr {$str += "<mo>*</mo>" + $e2.str; $num *= $e2.num;}
     | '/' e2=unaryExpr {$str += "<mo>/</mo>" + $e2.str; $num /= $e2.num;}
     )*
  ; 

unaryExpr returns [String str, double num]
  :  '-' e=expExpr {$str = "<mo>-</mo>" + $e.str; $num = -1 * $e.num;}
  |  e=expExpr     {$str = $e.str; $num = $e.num;}
  ;

expExpr returns [String str, double num]
  :  e1=atom       {$str = $e1.str; $num = $e1.num;}
     ( '^' e2=atom {$str = "<msup><mrow>" + $str + "</mrow><mrow>" + $e2.str + "</mrow></msup>"; $num = Math.pow($num, $e2.num);}
     )*
  ;

atom returns [String str, double num]
  :  INT                 {$str = "<mn>" + $INT.text + "</mn>"; $num = Double.valueOf($INT.text);}
  |  'sqrt' '[' expr ']' {$str = "<msqrt><mrow>" + $expr.str + "</mrow></msqrt>"; $num = Math.sqrt($expr.num);}
  |  '(' expr ')'        {$str = "<mo>(</mo>" + $expr.str + "<mo>)</mo>"; $num = $expr.num;}
  ;

INT     : '0'..'9'+;
NEWLINE : '\r'? '\n';
WS      : (' '|'\t')+ {skip();};

（请注意，(...)=>就是所谓的句法谓词）

您可以使用以下类测试上面语法生成的解析器：

import org.antlr.runtime.*;

public class Main {
  public static void main(String[] args) throws Exception {
    String src =
        "sqrt [ 9 ] \n" +  
        "1+2*3      \n" + 
        "2*(3+      \n" +
        "2*(3+42)^2 \n";
    ExprLexer lexer = new ExprLexer(new ANTLRStringStream(src));
    ExprParser parser = new ExprParser(new CommonTokenStream(lexer));
    ExprParser.parse_return returnValue = parser.parse();
    String mathML = returnValue.str;
    double eval = returnValue.num;
    // ...
  }
}

如果您现在运行上面的课程，您将看到输入

sqrt [ 9 ]
1+2*3
2*(3+
2*(3+42)^2

将产生以下输出：

sqrt[9] = 3.0
1+2*3 = 7.0
Ignoring: 2
Ignoring: *
Ignoring: (
Ignoring: 3
Ignoring: +
2*(3+42)^2 = 4050.0

ANTLR - 允许不完整的语法

1 个答案:

演示