Question

在 Python ：

中

def select(x):
    y = []
    for e in x:
        if e!=0:
            y.append(e)
    return y

的作用如下：

x = [1,0,2,0,0,3]
select(x)
[1,2,3]

要翻译成 Fortran ：

function select(x,n) result(y)
    implicit none
    integer:: x(n),n,i,j,y(?)
    j = 0
    do i=1,n
        if (x(i)/=0) then
            j = j+1
            y(j) = x(i)
        endif
    enddo
end function

问题出在Fortran：

如何申报y（？）？
如何声明x的预定义值
如何避免尺寸信息

为1如果定义为 y（n），则输出为：

x = (/1,0,2,0,0,3/)
print *,select(x,6)
1,2,3,0,0,0

这是不可取的！
！-------------------------------
的评论：
1 - 所有给出的答案在本文中都很有用。特别是M.S.B和eryksun的。
2 - 我尝试调整我的问题的想法并使用F2Py进行编译但是它没有成功。我已经使用GFortran对它们进行了调试，所有这些都是成功的。它可能是F2Py中的一个错误，或者我不知道正确使用它的错误。我将尝试在另一篇文章中介绍这个问题。

更新可以在here找到关联的问题。

Answer 1

我希望真正的Fortran程序员出现，但是如果没有更好的建议，我只会指定x(:)的形状而不是大小，使用临时数组temp(size(x))，并使输出y allocatable。然后在第一次传递后，allocate(y(j))并复制临时数组中的值。但是我不能强调我不是Fortran程序员，所以我不能说该语言是否有可扩展的数组，或者是否存在后者的库。

program test
    implicit none
    integer:: x(10) = (/1,0,2,0,3,0,4,0,5,0/)
    print "(10I2.1)", select(x)

contains

    function select(x) result(y)
        implicit none
        integer, intent(in):: x(:) 
        integer:: i, j, temp(size(x))
        integer, allocatable:: y(:)

        j = 0
        do i = 1, size(x)
            if (x(i) /= 0) then
                j = j + 1
                temp(j) = x(i)
            endif
        enddo

        allocate(y(j))
        y = temp(:j)
    end function select

end program test

编辑：

根据M.S.B.的回答，这里是一个修订版本的函数，它增加 ~~temp~~ y并进行过度分配。 ~~和之前一样，结果将结果复制到y。~~事实证明我没有必要以最终大小显式分配新数组。相反，它可以通过分配自动完成。

    function select(x) result(y)
        implicit none
        integer, intent(in):: x(:) 
        integer:: i, j, dsize
        integer, allocatable:: temp(:), y(:)

        dsize = 0; allocate(y(0))

        j = 0
        do i = 1, size(x)
            if (x(i) /= 0) then
                j = j + 1

                if (j >= dsize) then         !grow y using temp
                    dsize = j + j / 8 + 8 
                    allocate(temp(dsize))
                    temp(:size(y)) = y
                    call move_alloc(temp, y) !temp gets deallocated
                endif

                y(j) = x(i)
            endif
        enddo
        y = y(:j)
    end function select

Answer 2

以下是返回可变长度数组的Fortran函数的示例。这是Fortran 2003的一个功能。在测试驱动程序中使用的还有自动分配，另一个Fortran 2003功能。

module my_subs

contains

function select(x) result(y)
    implicit none
    integer, dimension (:), intent (in) :: x
    integer, dimension (:), allocatable :: y
    integer :: i, j

    j = 0
    do i=1, size (x)
        if (x(i)/=0) j = j+1
    enddo

    allocate ( y (1:j) )

    j = 0
    do i=1, size (x)
        if (x(i)/=0) then
            j = j+1
            y(j) = x(i)
        endif
    enddo

    return

end function select

end module my_subs

program test

use my_subs

implicit none
integer, dimension (6) :: array = [ 5, 0, 3, 0, 6, 1 ]
integer, dimension (:), allocatable :: answer

answer = select (array)

write (*, *) size (array), size (answer)
write (*, *) array
write (*, *) answer

stop


end program test

这是一种替代解决方案，它使用临时数组根据需要“增长”输出数组（函数返回）。虽然避免了两次通过输入数组，但是需要数组副本。另一个Fortran 2003功能move_alloc减少了所需的副本数量。 move_alloc还负责输出数组（此处为“y”）的（重新）分配和输入数组的释放（此处为“temp”）。也许这更优雅，但由于使用了多个副本，因此可能效率较低。这个版本可能更具教育性，然后有用。 @ eryksun的版本使用一次传递和一次复制，代价是使临时数组的大小完整。

function select(x) result(y)
    implicit none
    integer, dimension (:), intent (in) :: x
    integer, dimension (:), allocatable :: y, temp
    integer :: i, j

    j = 0
    do i=1, size (x)
        if (x(i)/=0) then
            j = j+1
            allocate (temp (1:j))
            if ( allocated (y) ) temp (1:j-1) = y
            call move_alloc (temp, y)
            y(j) = x(i)
        endif
    enddo

    return

end function select

Answer 3

如果您问题中的示例确实是您想要做的，那么您可以使用Fortran90内部`pack'：

program pack_example

implicit none

integer, dimension(6) :: x

x = (/ 1,0,2,0,0,3 /)

! you can also use other masks than 'x/=0'
write(*,*) pack(x, x/=0)

end program pack_example

示例程序的输出是：1 2 3

如何将先前未知的数组作为Fortran中函数的输出

3 个答案: