Question

我正在构建一个具有特定日期/时间倒计时的东西。我有它的工作 - 至少小时，分钟和秒工作正常。我的问题是当我尝试实现Days时，它没有给出正确的结果。我知道DateUtils单元，但那里有很多东西，我不知道怎么做，特别是因为我对数学很恐怖。

我有一个间隔为100的计时器。然后我有一个全局fDestDT作为目标日期/时间，以倒计时为基础。在计时器中，我有一个名为DT的本地TDateTime。然后我将它分成多个字符串并将它们重新组合成一个“友好”字符串......

procedure TForm1.TmrTimer(Sender: TObject);
var
  DT: TDateTime;
  D, H, N, S: String;
  Str: String;
begin
  DT:= fDestDT - Now; //fDest = destination date/time of countdown
  //Need to format only plural numbers with 's'
  D:= FormatDateTime('d', DT)+' Days';    //Get number of days
  H:= FormatDateTime('h', DT)+' Hours';   //Get number of hours
  N:= FormatDateTime('n', DT)+' Minutes'; //Get number of minutes
  S:= FormatDateTime('s', DT)+' Seconds'; //Get number of seconds
  Str:= D+', '+H+', '+N+', '+S;           //Build friendly string
  if lblTitle.Caption <> Str then
    lblTitle.Caption:= Str;               //Update caption only if it's changed
end;

应该出现类似......

0 Days, 3 Hours, 1 Minute, 12 Seconds

但相反，日子显示错误，倒计时的日期/时间是今天的日期，它显示30天......

30 Days, 3 Hours, 1 Minute, 12 Seconds

我认为如果我提前超过1个月，它也不会正确显示。我如何正确获得天数？在DateUtils单元中是否有任何东西可以比我现在更好地自动完成大部分工作？

编辑：固定！问题是我用DT:= fDestDT - Now;愚蠢地减去了我在我的第一个代码段中正确的内容，但在转换为使用DateUtils.DaysBetween之后，我需要删除该减法，并设置DT:= Now;。

工作代码：

procedure TForm1.TmrTimer(Sender: TObject);
var           
  DT: TDateTime;
  Days, Hours, Mins, Secs: Word;
  SDays, SHours, SMins, SSecs: String;
  Str: String;
begin     
  DT:= Now;
  Days:= DaysBetween(DT, fDestDT);
  Hours:= HoursBetween(fDestDT, DT) mod 24; // Remove total days
  Mins:= MinutesBetween(DT, fDestDT) mod 60;
  Secs := SecondsBetween(DT, fDestDT) mod 60;
  if Days =  1  then SDays:=  'Day'    else SDays:=  'Days';
  if Hours = 1  then SHours:= 'Hour'   else SHours:= 'Hours';
  if Mins =  1  then SMins:=  'Minute' else SMins:=  'Minutes';
  if Secs =  1  then SSecs:=  'Second' else SSecs:=  'Seconds';
  Str:= Format('%d '+SDays+' %d '+SHours+' %d '+SMins+' %d '+SSecs,
    [Days, Hours, Mins, Secs]);
  if lblTime.Caption <> Str then
    lblTime.Caption:= Str;
end;

Answer 1

请参阅DaysBetween中的HoursBetween，MinutesBetween，SecondsBetween和DateUtils。你必须做一些小数学。：）

这是一个示例控制台应用程序，用于演示：

program Project2;

{$APPTYPE CONSOLE}

uses
  SysUtils, DateUtils;

procedure ShowTimeDiff(const StartDate, OldDate: TDateTime);
var
  Days, Hours, Mins, Secs: Word;
  OutputText: string;
begin
  Writeln(Format('Start: %s, Old: %s',
      [FormatDateTime('mm/dd/yyyy hh:nn:ss', StartDate),
      FormatDateTime('mm/dd/yyyy hh:nn:ss', OldDate)]));
  Days := DaysBetween(StartDate, OldDate);
  Hours := HoursBetween(OldDate, StartDate) mod 24; // Remove total days
  Mins := MinutesBetween(StartDate, OldDate) mod 60;
  Secs  := SecondsBetween(StartDate, OldDate) mod 60;
  OutputText := Format('  %d days, %d hours, %d min, %d secs',
                       [Days, Hours, Mins, Secs]);
  WriteLn(OutputText);

end;

var
  BeginDate, EndDate: TDateTime;
begin
  BeginDate := Now;
  EndDate := BeginDate - 0.5;   // about 12 hours earlier
  ShowTimeDiff(BeginDate, EndDate);

  EndDate := BeginDate - 2.53724;  // Create date about 2 1/2 days earlier
  ShowTimeDiff(EndDate, BeginDate);

  EndDate := BeginDate - 5.75724;  // Create date about 5 3/4 days earlier
  ShowTimeDiff(BeginDate, EndDate);
  ReadLn;
end.

产生以下输出：

Time differences

请注意，DaysBetween和HoursBetween之间参数顺序的反转是为了证明函数始终返回正值，因此参数的顺序并不重要。这在文档中提到。

Answer 2

问题在于，当您从Now中减去fDestDT时，您希望在两个日期之间获得差异，但实际上您获得了另一个日期时间值。由于您使用的值几乎相同，因此您可以获得Delphi的datetime系统的“零日期”，即30. 18ts。这就是为什么FormatDateTime('d', DT)+' Days'获得“30天”的原因。

由于您感兴趣的最小金额是秒，我建议您使用SecondsBetween来获取两个时间戳之间的差异，然后将其划分为

等部分

diff := SecondsBetween(Now, fDestDT);
S:= IntToStr(diff mod 60)+' Seconds';
diff := diff div 60;
N:= IntToStr(diff mod 60)+' Minutes';
diff := diff div 60;
H:= IntToStr(diff mod 24)+' Hours';
diff := diff div 24;
D:= IntToStr(diff)+' Days';

Answer 3

如果您使用的是Delphi 2010（我相信）或更高版本，您可以使用TimeSpan.pas单元简化代码并使其更清晰，其中包含可用于分析金额的记录在给定的时间段内的时间。

Answer 4

我需要更灵活的东西来涵盖不同的格式，因此我将TTimeDiff实施为：

uses
  SysUtils,
  DateUtils,
  StrUtils,
  Math;

type
  TTimeDiff = record
    type TTimeDiffFormat = (tdfFull, tdfSignificant, tdfAllNonZeros, tdfXNonZeros);
    procedure Init(const ANow, AThen: TDateTime);
    class function TimeDiff(const ANow, AThen: TDateTime): TTimeDiff; static;
    function ToString(const TimeDiffFormat: TTimeDiffFormat; const Delimiter: string = ', ';
      const NonZerosCount: Byte = 1): string;
    case Integer of
      0: (Years, Months, Days, Houres, Minutes, Seconds: Word);
      1: (Values: array[0..5] of Word);
  end;

{ TTimeDiff }

class function TTimeDiff.TimeDiff(const ANow, AThen: TDateTime): TTimeDiff;
begin
  Result.Init(ANow, AThen);
end;

procedure TTimeDiff.Init(const ANow, AThen: TDateTime);
begin
  Years := YearsBetween(ANow, AThen);
  Months := MonthsBetween(ANow, AThen) mod 12;
  Days := DaysBetween(IncMonth(Min(ANow, AThen), Years * 12 + Months), Max(ANow, AThen));
  Houres := HoursBetween(ANow, AThen) mod 24;
  Minutes := MinutesBetween(ANow, AThen) mod 60;
  Seconds := SecondsBetween(ANow, AThen) mod 60;
end;

function TTimeDiff.ToString(const TimeDiffFormat: TTimeDiffFormat; const Delimiter: string = ', ';
  const NonZerosCount: Byte = 1): string;
const
  Captions: array [0..5] of string = ('year', 'month', 'day', 'hour', 'minute', 'second');
var
  I: Integer;
  VisitedNonZeros: Byte;
begin
  Result := '';
  VisitedNonZeros := 0;
  for I := 0 to 5 do
  begin
    if Values[I] > 0 then
      Inc(VisitedNonZeros);
    if
      (TimeDiffFormat = tdfFull) or
      ((TimeDiffFormat = tdfSignificant) and (VisitedNonZeros > 0)) or
      ((TimeDiffFormat in [tdfAllNonZeros, tdfXNonZeros]) and (Values[I] > 0))
    then
    begin
      Result := Result + Format('%d %s%s%s', [Values[I], Captions[I], IfThen(Values[I] = 1, '', 's'), Delimiter]);
      if (TimeDiffFormat = tdfXNonZeros) and (VisitedNonZeros = NonZerosCount) then
        Break;
    end;
  end;
  Result := Copy(Result, 1, Length(Result) - Length(Delimiter));
end;

TTimeDiffFormat解释：

tdfFull：包括所有部分，无论它们的值如何（分别为年，月，日，小时，分钟和秒）。
tdfSignificant：排除了零价值的重要零件
tdfAllNonZeros：排除所有零值部分
tdfXNonZeros：仅包含前X个非零值部分，默认情况下X设置为1

使用方法：

var
  ANow, AThen: TDateTime;
  Diff: TTimeDiff;
begin
  try
    ANow := DateUtils.EncodeDateTime(1993, 11, 3, 21, 22, 18, 0);
    AThen := DateUtils.EncodeDateTime(1993, 9, 21, 6, 21, 34, 0);
    Writeln('Difference between ');
    Writeln(FormatDateTime('YYYY/MM/DD HH:NN:SS', ANow), ' and');
    Writeln(FormatDateTime('YYYY/MM/DD HH:NN:SS', AThen), ' is:');
    Writeln('');

    Diff.Init(ANow, AThen);
    with Diff do
    begin

      Writeln(ToString(tdfFull));
      Writeln(ToString(tdfSignificant, ' and '));
      Writeln(TTimeDiff.TimeDiff(Athen, ANow).ToString(tdfSignificant), ' (inverted)');
      Writeln(ToString(tdfAllNonZeros));
      Writeln(ToString(tdfXNonZeros, ', ', 2));
      Writeln(ToString(tdfXNonZeros));
      readln;
    end;
  except
    on E: Exception do
      Writeln(E.ClassName, ': ', E.Message);
  end;
end.

结果：

Difference between
1993/11/03 21:22:18 and
1993/09/21 06:21:34 is:

0 years, 1 month, 13 days, 15 hours, 0 minutes, 43 seconds
1 month and 13 days and 15 hours and 0 minutes and 43 seconds
1 month, 13 days, 15 hours, 0 minutes, 43 seconds (inverted)
1 month, 13 days, 15 hours, 43 seconds
1 month, 13 days
1 month

日期/时间操作 - 友好的倒计时字符串

4 个答案: