在XSL中进行双通道？

Question

是否可以将XSL转换的输出存储在某种变量中，然后对变量的内容执行额外的转换？ （所有在一个XSL文件中）

（XSLT-2.0首选）

Answer 1

XSLT 2.0解决方案：

<xsl:variable name="firstPassResult">
  <xsl:apply-templates select="/" mode="firstPass"/>
</xsl:variable>

<xsl:template match="/">
  <xsl:apply-templates select="$firstPassResult" mode="secondPass"/>
</xsl:template>

这里的诀窍是第一次使用mode =“firstPassResult”，而sedond pass的所有模板都应该有mode =“secondPass”。

修改

示例：

<root>
  <a>Init</a>
</root>

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output indent="yes"/>
  <xsl:strip-space elements="*"/>

  <xsl:variable name="firstPassResult">
    <xsl:apply-templates select="/" mode="firstPass"/>
  </xsl:variable>

  <xsl:template match="/" mode="firstPass">
      <test>
        <firstPass>
          <xsl:value-of select="root/a"/>
        </firstPass>
      </test>
  </xsl:template>

  <xsl:template match="/">
    <xsl:apply-templates select="$firstPassResult" mode="secondPass"/>
  </xsl:template>

  <xsl:template match="/" mode="secondPass">
    <xsl:message terminate="no">
      <xsl:copy-of select="."/>
    </xsl:message>
  </xsl:template>

</xsl:stylesheet>

输出：

[xslt] <test><firstPass>Init</firstPass></test>

所以第一遍创建了一些含有root / a内容的元素，第二遍打印出创建的元素到std out。希望这足以让你前进。

Answer 2

是的，使用XSLT 2.0很容易。使用XSLT 1.0，您当然也可以使用模式并将临时结果存储在变量中，与XSLT 2.0中的相同，但变量是结果树片段，以便能够使用您需要使用的apply-templates进一步处理它变量上的exsl:node-set扩展函数。