Question

我已经用几十种语言编程了20年但是我无法理解“FOR”在windows cmd shell批处理文件中是如何工作的，无论我怎么努力。我读了

http://www.amazon.com/Windows-Administration-Command-Line-Vista/dp/0470046163/ref=sr_1_1?ie=UTF8&s=books&qid=1241362727&sr=8-1

http://www.ss64.com/nt/for.html

和互联网上的其他几篇文章但仍然混淆，无法完成任何事情。

有人可以简单解释一下“FOR”的工作原理吗？

对于更具体的问题，我如何遍历％PATH％变量中的每个路径？我试过

rem showpathenv.bat
for /f "delims=;" %%g in ("%PATH%") do echo %%g

这只显示第一条路径，而不是所有路径。为什么？我做错了什么？

Answer 1

所有答案都没有实际效果。我自己设法找到了解决方案。这有点hackish，但它解决了我的问题：

echo off
setlocal enableextensions
setlocal enabledelayedexpansion
set MAX_TRIES=100
set P=%PATH%
for /L %%a in (1, 1, %MAX_TRIES%) do (
  for /F "delims=;" %%g in ("!P!") do (
    echo %%g
    set P=!P:%%g;=!
    if "!P!" == "%%g" goto :eof
  )
)

哦，哦！我讨厌批量文件编程!!

<强>更新

Mark的解决方案更简单，但它不适用于包含空格的路径。这是Mark解决方案的一个小修改版本

echo off
setlocal enabledelayedexpansion
set NonBlankPath=%PATH: =#%
set TabbedPath=%NonBlankPath:;= %
for %%g in (%TabbedPath%) do (
  set GG=%%g
  echo !GG:#= !
)

Answer 2

Mark的想法很好，但也许忘记了一些路径中有空格。替换';'用“”“代替将所有路径切换为带引号的字符串。

set _path="%PATH:;=" "%"
for %%p in (%_path%) do if not "%%~p"=="" echo %%~p

所以在这里，你显示了你的路径。

cmd中的FOR命令有一个繁琐的学习曲线，特别是因为变量如何在（）的语句中作出反应...你可以分配任何变量，但你不能在（）中读回，除非你使用“setlocal ENABLEDELAYEDEXPANSION”语句，因此也使用!!而不是%%的变量（！_var！）

我目前只使用cmd编写脚本，为了工作，必须学习所有这些：）

Answer 3

你有正确的想法，但for /f旨在处理多行文件或命令，而不是单个字符串。

最简单的形式是for就像Perl的for，或其他所有语言foreach。你传递一个令牌列表，然后迭代它们，每次调用相同的命令。

for %a in (hello world) do @echo %a

扩展仅提供构建令牌列表的自动方式。您当前代码没有任何结果的原因是';'是行（注释）符号的默认结尾。但即使你改变了，你也必须使用%%g, %%h, %%i, ...访问单个令牌，这将严重限制你的批处理文件。

你能得到的最接近的是：

set TabbedPath=%PATH:;= %
for %%g in (%TabbedPath%) do echo %%g

但对于包含分号的引用路径，这将失败。

根据我的经验，for /l和for /r适合扩展现有命令，但for非常有限。使用延迟变量扩展（cmd /v:on）可以使它更强大（并且令人困惑），但它实际上只对文件名列表有用。

如果您需要执行字符串操作，我建议使用WSH或PowerShell。如果您尝试为Windows编写whereis，请尝试where /?。

Answer 4

无法抗拒把它抛出那里，因为这个线程很老......通常当需要迭代遍历PATH中的每个文件时，你真正想做的就是找到一个特定的文件......如果在这种情况下，这个单行将吐出它找到你的文件的第一个目录：

（例如：寻找java.exe）

for %%x in (java.exe) do echo %%~dp$PATH:x

Answer 5

我知道这是超级老......但为了好玩，我决定尝试一下：

@Echo OFF
setlocal
set testpath=%path: =#%
FOR /F "tokens=* delims=;" %%P in ("%testpath%") do call :loop %%P
:loop
if '%1'=='' goto endloop
set testpath=%1
set testpath=%testpath:#= %
echo %testpath%
SHIFT
goto :loop
:endloop
pause
endlocal
exit

这不需要计数，直到完成为止。我对空格有同样的问题，但它通过整个变量。关键是循环标签和SHIFT功能。

Answer 6

for /f迭代每行输入，因此在您的程序中只会输出第一个路径。

你的程序将％PATH％视为单行输入，并按;消除，将第一个结果放到%% g，然后输出%% g（第一个消除路径）。

Answer 7

FOR基本上是在数据集中的“行”上进行迭代。在这种情况下，有一行包含路径。 "delims=;"只是告诉它在分号上分开。如果您将正文更改为echo %%g,%%h,%%i,%%j,%%k，您会看到它将输入视为单行并将其分成多个标记。

Answer 8

这对我有用：

@ECHO OFF
SETLOCAL ENABLEDELAYEDEXPANSION ENABLEEXTENSIONS
@REM insure path is terminated with a ;
set tpath=%path%;
echo.
:again
@REM This FOR statement grabs the first element in the path
FOR /F "delims=;" %%I IN ("%TPATH%") DO (
  echo    %%I 
  @REM remove the current element of the path
  set TPATH=!TPATH:%%I;=!
)
@REM loop back if there is more to do. 
IF DEFINED TPATH GOTO :again

ENDLOCAL

Answer 9

您还必须使用tokens=1,2,...循环允许的for部分选项。这可以做你想要的事情：

for /f "tokens=1,2,3,4,5,6,7,8,9,10,11,12 delims=;" %a in ("%PATH%") ^
do ( ^
     echo. %b ^
   & echo. %a ^
   & echo. %c ^
   & echo. %d ^
   & echo. %e ^
   & echo. %f ^
   & echo. %g ^
   & echo. %h ^
   & echo. %i ^
   & echo. %j ^
   & echo. %k ^
   & echo. ^
   & echo.   ...and now for some more... ^
   & echo. ^
   & echo. %a ^| %b ___ %c ... %d ^
   & dir "%e" ^
   & cd "%f" ^
   & dir /tw "%g" ^
   & echo. "%h  %i  %j  %k" ^
   & cacls "%f")

此示例仅处理前12个令牌（=来自％path％的目录）。它使用每个使用过的令牌的显式枚举。请注意，令牌名称区分大小写：％a与％A不同。

要保存包含空格的路径，请使用类似“％i”的引号环绕所有％x。我没有在这里做，我只是回应了令牌。

你也可以做s.th.像这样：

for /f "tokens=1,3,5,7-26* delims=;" %a in ("%PATH%") ^
do ( ^
     echo. %c ^
   & echo. %b ^
   & echo. %a ^
   & echo. %d ^
   & echo. %e ^
   & echo. %f ^
   & echo. %g ^
   & echo. %h ^
   & echo. %i ^
   & echo. %j ^
   & echo. %k )

这个跳过令牌2,4,6并使用一个小捷径（“7-26”）来命名其余的。请注意，与第一个示例相比，此次如何以相反的顺序处理％c，％b，％a，以及它们现在如何“表示”不同的令牌。

所以这肯定不是你要求的简明解释。但也许这些例子现在有助于澄清一点......

Answer 10

这是一个很好的指南：

FOR /F - Loop command: against a set of files.

FOR /F - Loop command: against the results of another command.

FOR - Loop command: all options Files, Directory, List.

[整个指南（Windows XP命令）：

http://www.ss64.com/nt/index.html

编辑：抱歉，没有看到该链接已经在OP中，因为它在我看来是亚马逊链接的一部分。

Answer 11

它对我有用，试一试。

for /f "delims=;" %g in ('echo %PATH%') do echo %g%

Answer 12

它对我有用，试一试。

for / f“tokens = * delims =;” （'echo％PATH％'）中的％g执行回显％g％

“FOR”如何在cmd批处理文件中工作？

12 个答案: