Question

我有以下形式的XML数据：

<Parent>
    <Child>Value1</Child>
    <Child>Value2</Child>
    <Child>Value3</Child>
    .
    .
    .
</Parent>

我必须将封闭标记的HTML title属性设置为连接值，如：

<xsl:attribute name="title">Value1,Value2,Value3,.,.,.</xsl:attribute>

我之前检查了SO上提出的问题，但大多数解决方案都是多线的，（并且是XSL的新手）我认为我不能在我的<xsl:attribute></xsl:attribute>标签中包含多行代码。怎么去做这件事？

Answer 1

XSLT 2.0解决方案：

<xsl:stylesheet version="2.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="Parent">
     <Parent title="{string-join(Child, ', ')}"/>
 </xsl:template>
</xsl:stylesheet>

在提供的XML文档上应用此转换时：

<Parent>
    <Child>Value1</Child>
    <Child>Value2</Child>
    <Child>Value3</Child>
</Parent>

产生了想要的正确结果：

<Parent title="Value1, Value2, Value3"/>

或者，如果想要覆盖身份规则以获得更大的灵活性：

<xsl:stylesheet version="2.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema">
    <xsl:output omit-xml-declaration="yes" indent="yes"/>
    <xsl:strip-space elements="*"/>

 <xsl:template match="node()|@*">
     <xsl:copy>
       <xsl:apply-templates select="node()|@*"/>
     </xsl:copy>
 </xsl:template>

 <xsl:template match="Child[1]">
  <xsl:attribute name="title" select="string-join(../Child, ', ')"/>
 </xsl:template>

 <xsl:template match="Child"/>
</xsl:stylesheet>

当此转换应用于同一个XML文档（上图）时，会再次生成相同的想要的正确结果：

<Parent title="Value1, Value2, Value3"/>

Answer 2

<xsl:template match="Parent">
  <xsl:attribute name="title">
   <xsl:for-each select="Child">
     <xsl:if test="position() != 1">, </xsl:if>
     <xsl:value-of select="."/>
   </xsl:for-each>
  </xsl:attribute>
</xsl:template>

Answer 3

<xsl:template match="Parent">
  <xsl:attribute name="title">
   <xsl:for-each select="Child">
     <xsl:value-of select="."/>
     <xsl:if test="not(position()=last())">, </xsl:if>
   </xsl:for-each>
  </xsl:attribute>
</xsl:template>

Answer 4

我对xsl不太了解，但是有一个xpath函数 string-join 可以在xsl中使用，这样就可以减少行数。我通常在Orbeon Xforms中使用此功能。

string-join(/Parent/Child, ',')

参考：http://www.w3schools.com/xpath/xpath_functions.asp

在XSL中连接节点并将值放入HTML“title”属性

4 个答案: