如何从OTA包向导中获取欢迎页面浏览器导航到某些URI？

Question

我要做的是创建一种查看（不编辑）项目中包含的HTML页面的功能。欢迎页面已经嵌入了Web浏览器，因此它似乎是一个很好的候选者。

Curios为什么？这是一个带有背景信息的question。

Answer 1

这是我专门为您制作的解决方案......

从here下载源代码，在Delphi中提取并加载包（我在Delphi XE中创建，但它将加载到任何版本中！您需要更改单位输出路径关于pre-XE版本的项目选项，但是）...安装包。

在“帮助”菜单中，找到创建浏览器并单击它。然后，这将创建并显示一个导航到我的博客的选项卡（用于示例）。

您可以轻松修改它以满足您的需求！帮助菜单项代码位于EditWizard.MenuItem.pas，可以忽略不计！请注意，当点击(BorlandIDEServices as IOTAEditorViewServices).ShowEditorView(CreateTab('http://www.simonjstuart.com'));时，它正在拨打电话，这实际上是创建浏览器标签实例！

浏览器选项卡的所有代码（包括其框架布局）都包含在EditorWizard.Frame.pas中，这使得它很容易修改以满足您的需求！

单元EditorWizard.Wizard.pas包含将自定义浏览器选项卡注册到IDE所需的少量代码。

当然，您需要做一些调整，但这肯定会成为您尝试做的事情的一个非常可接受的基础。

享受：）

Answer 2

如果您愿意使用这样的黑客：

type
  TOpenNewURLModule = procedure(const URL: string; EditorForm: TCustomForm);

procedure OpenURL(const URL: string);
var
  EditWindow: INTAEditWindow;
  Lib: HMODULE;
  OpenNewURLModule: TOpenNewURLModule;
begin
  EditWindow := (BorlandIDEServices as INTAEditorServices).TopEditWindow;
  if not Assigned(EditWindow) or not Assigned(EditWindow.Form) then
    Exit;

  Lib := GetModuleHandle('startpageide150.bpl');
  if Lib = 0 then
    Exit;
  OpenNewURLModule := GetProcAddress(Lib, '@Urlmodule@OpenNewURLModule$qqrx20System@UnicodeStringp22Editorform@TEditWindow');
  if @OpenNewURLModule <> nil then
    OpenNewURLModule(URL, EditWindow.Form);
end;

缺点：

• 这是一个黑客攻击（startpageidexx.bpl不通过API公开或记录）
• 它是硬编码的Delphi XE（您需要为其他版本使用不同的文件名，方法签名也可能不同 - 例如在较旧的AnsiString版本中）
• 如果没有编辑窗口（必须至少有一个打开的模块），它什么都不做
• 它始终会打开一个新的浏览器视图

---

编辑：似乎可以重用现有的打开欢迎页面，并使此黑客与旧版本的Delphi兼容。以下显示了两个备选方案：Delphi XE和Delphi 2007（两者似乎都在工作）：

type
  IURLModule = interface(IOTAModuleData)
  ['{9D215B02-6073-45DC-B007-1A2DBCE2D693}']
    function GetURL: string;
    procedure SetURL(const URL: string);
    property URL: string read GetURL write SetURL;
  end;
  TOpenNewURLModule = procedure(const URL: string; EditorForm: TCustomForm);

function FindURLModule: IURLModule;
var
  I: Integer;
begin
  Result := nil;
  with BorlandIDEServices as IOTAModuleServices do
    for I := 0 to ModuleCount - 1 do
      if Supports(Modules[I], IURLModule, Result) then
        Break;
end;

procedure OpenURL(const URL: string; ReuseExistingView: Boolean = True);
{$IFDEF VER220} // Delphi XE
const
  SStartPageIDE = 'startpageide150.bpl';
  SOpenNewURLModule = '@Urlmodule@OpenNewURLModule$qqrx20System@UnicodeStringp22Editorform@TEditWindow';
{$ENDIF}
{$IFDEF VER185} // Delphi 2007
const
  SStartPageIDE = 'startpageide100.bpl';
  SOpenNewURLModule = '@Urlmodule@OpenNewURLModule$qqrx17System@AnsiStringp22Editorform@TEditWindow';
{$ENDIF}
var
  Module: IURLModule;
  EditWindow: INTAEditWindow;
  Lib: HMODULE;
  OpenNewURLModule: TOpenNewURLModule;
begin
  EditWindow := nil;
  Module := nil;
  if ReuseExistingView then
    Module := FindURLModule;
  if Assigned(Module) then
  begin
    Module.URL := URL;
    (Module as IOTAModule).Show;
  end
  else
  begin
{$IFDEF VER220}
    EditWindow := (BorlandIDEServices as INTAEditorServices).TopEditWindow;
{$ENDIF}
{$IFDEF VER185}
  if Assigned((BorlandIDEServices as IOTAEditorServices).TopView) then
    EditWindow := (BorlandIDEServices as IOTAEditorServices).TopView.GetEditWindow;
{$ENDIF}
    if not Assigned(EditWindow) or not Assigned(EditWindow.Form) then
      Exit;
    Lib := GetModuleHandle(SStartPageIDE);
    if Lib = 0 then
      Exit;

    OpenNewURLModule := GetProcAddress(Lib, SOpenNewURLModule);
    if @OpenNewURLModule <> nil then
      OpenNewURLModule(URL, EditWindow.Form);
  end;
end;

剩下的缺点：

• 它仍然是一个黑客
• 对于Delphi XE（Unicode）和Delphi 2007（ANSI），它仍然是硬编码的
• 如果没有编辑窗口，它仍然无效

如果您需要兼容其他版本，也许可以将此作为开头。

Answer 3

最好显示自己的TForm，其中包含TWebBrowser组件，您可以将HTML加载到其中。