Question

我正在尝试对XML文档进行转换。我的XML转换可以产生两种不同类型的基本元素，具体取决于某个元素的值：

<xsl:template match="/">
  <xsl:choose>
    <xsl:when test="/databean/data[@id='pkhfeed']/value/text()='200'">
      <xsl:call-template name="StructureA">
        <xsl:with-param name="structure" select="//databean" />
      </xsl:call-template>
    </xsl:when>
    <xsl:otherwise>
      <xsl:call-template name="StructureB">
        <xsl:with-param name="structure" select="//databean" />
      </xsl:call-template>
    </xsl:otherwise>
  </xsl:choose>
</xsl:template>

然后使用自己的名称空间和schemaLocations创建StructureA或StructureB：

<StructureA xmlns="http://...">

StructureA＆amp; B共享一些共同元素，因此这些元素在一个名为“xmlcommon.xslt”的单独文件中定义，两个结构都包含来自的模板。此xmlcommon文件没有定义默认名称空间，因为我希望它可以从StructureA或StructureB中定义的名称空间中使用。但是当我运行我的转换时，从公共文件中提取的任何模板都会产生空白的xmlns属性：

<StructureA xmlns="http://...">
  <SharedElement xmlns="">Something</SharedElement>
</StructureA>

验证时，然后使用空白名称空间而不是正确的父名称空间。 是否有人知道如何阻止我的公共文件中的模板添加空白xmlns属性？

以下是公共文件的摘录：

<xsl:stylesheet version="1.0" xmlns:fn="http://www.w3.org/2005/02/xpath-functions" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

  <xsl:template name="ControlledListStructure">
    <xsl:param name="xmlElem" />
    <xsl:param name="structure" />

    <xsl:element name="{$xmlElem}">
      <!-- Blah blah blah -->
    </xsl:element>
  </xsl:template>
</xsl:stylesheet>

Answer 1

要意识到的关键是你的样式表规定了你添加到结果树的每个元素的名称。元素的名称有两部分：本地名称和名称空间URI。在上面的代码中，您提供了本地名称（$xmlElem的值），但是您没有指定名称空间URI，这意味着它将默认为空字符串。（实际上，它采用该样式表模块的默认命名空间;因为没有，所以它是空字符串。）换句话说，该元素将不在命名空间中。序列化文档时，XSLT处理器必须包含xmlns=""非声明，以便取消声明顶部显示的默认命名空间。否则，该元素将采用该命名空间，这不是您的样式表所指示的。修复此问题的最少侵入性方法是添加另一个参数（例如$namespaceURI），就像使用$xmlElem一样。然后你会写：

<xsl:element name="{$xmlElem}" namespace="{$namespaceURI}">

现在，结果元素将采用您告诉它的任何命名空间（这将删除那些默认的命名空间取消声明）。

那应该回答你的问题。我提供以下免费奖励材料。 ; - ）

您应该在值比较中删除text()节点测试。您很少需要直接比较文本节点的值。相反，您可以只比较元素本身的字符串值（它被定义为其所有后代文本节点的字符串值的串联）。这看起来像这样：

<xsl:when test="/databean/data[@id='pkhfeed']/value = '200'">

以这种方式执行此操作的优点是，如果有隐藏的注释，您的代码将不会中断：

<value>2<!--test-->00</value>

在这种情况下，有两个文本节点（“2”和“00”）。您的原始测试将失败，因为它会检查它们中的任何一个是否等于“200”。在这种情况下不太可能发生，但在任何情况下测试元素的字符串值（与其文本节点子元素相反）是一个很好的做法，当你的意图。

最后，我建议您了解模板规则和XPath上下文。我倾向于尽可能避免使用<xsl:choose>，<xsl:call-template>和<xsl:with-param>。首先，模板规则可以帮助您避免XSLT的许多丑陋，冗长的部分。

<xsl:template match="/databean[data[@id='pkhfeed']/value = '200']" priority="1">
  <StructureA xmlns="http://...">
    ...
  </StructureA>
</xsl:template>

<xsl:template match="/databean">
  <StructureB xmlns="http://...">
    ...
  </StructureB>
</xsl:template>

即使您继续使用<xsl:call-template>，也不必传递$structure参数，因为当前节点在被调用模板中将保持不变。您可以在//databean或/databean模板中轻松访问StructureA（或StructureB，我怀疑您的意思），因为当前节点将会仍然是“/”（文档节点）。

如果您有兴趣了解有关XSLT核心处理模型及其最强大功能（模板规则）的更多信息，那么我建议您查看我的 XSLT中的免费示例章节"How XSLT Works" 1.0口袋参考。

我希望这对你有所帮助，即使它比你讨价还价还要多！

空白xmlns =“”导入的属性

1 个答案: