Question

以下是对所有mathematica代码关注者的挑战。通过创建imgur上传器，让我们更方便地将图像插入Mathematica的SO帖子中。

我们如何创建一个将光栅化其参数的函数imgur[g_]（确保最终大小不超过StackOverflow帖子的宽度），将其转换为PNG，将其上传到imgur，然后返回准备粘贴MarkDown行，例如![Mathematica graphic](http://i.imgur.com/ZENa4.jpg)？

有用的参考资料：

我无法使用后一种方法来上传图像而不先将其导出到文件中。

警告，谨慎使用！ StackOverflow使用separate imgur installation无限期保留图像。如果您使用主要imgur，the images will disappear after 6 months if no one views them。不幸的是，截至2011年11月，似乎有no official way以编程方式将图像上传到StackOverflow。

更新 See below直接上传到StackOverflow 的解决方案。

Answer 1

一只小鸟刚刚告诉我这个问题的 Mathematica 解决方案（底层实现仍然使用JLink，但这个答案隐藏了所有与java相关的代码）：

imgur[expr_] := Module[
 {url, key, image, data, xml, imgurUrl},
 url = "http://api.imgur.com/2/upload";
 key = "c07bc3fb59ef878d5e23a0c4972fbb29";
 image = Fold[ExportString, expr, {"PNG", "Base64"}];
 xml = Import[url, 
  "XML", "RequestMethod" -> "POST", 
  "RequestParameters" -> {"key" -> key, "image" -> image}];
 imgurUrl = Cases[xml, XMLElement["original", {}, {string_}] :> string, 
  Infinity][[1]];
 "![Mathematica graphic](" <> imgurUrl <> ")"
]

这仅限V8，XML导入选项"RequestMethod"和"RequestParameters"未记录且未经过实验（因此可能会发生变化）。

Answer 2

注意：使用此功能here获取现成的调色板。

Arnoud的解决方案让我感到兴奋和不耐烦，所以这里有一个改进。没有研究他的代码，我不可能做到这一点。这个版本似乎更可靠，更不容易出现超时错误，但老实说，我根本不懂Java，所以欢迎任何改进。

最重要的是：此版本直接上传到stack.imgur.com，因此可以安全地在StackOverflow上使用，而不必担心上传的图片会在一段时间后消失。

我提供三个功能：

stackImage上传表达式，导出为PNG，然后返回网址
stackMarkdown返回降价，准备复制
stackCopyMarkdown将降价复制到剪贴板

下一步：创建一个调色板按钮，自动为笔记本中的选定图形执行此操作。对代码的改进非常受欢迎。

Needs["JLink`"]


stackImage::httperr = "Server returned respose code: `1`";
stackImage::err = "Server returner error: `1`";

stackImage[g_] :=
 Module[
  {getVal, url, client, method, data, partSource, part, entity, code, 
   response, error, result},

  (* this function attempts to parse the response fro the SO server *)
  getVal[res_, key_String] :=
   With[{k = "var " <> key <> " = "},
    StringTrim[
     First@StringCases[First@Select[res, StringMatchQ[#, k ~~ ___] &], 
       k ~~ v___ ~~ ";" :> v],
     "'"]
    ];

  data = ExportString[g, "PNG"];

  JavaBlock[
    url = "https://stackoverflow.com/upload/image";
    client = JavaNew["org.apache.commons.httpclient.HttpClient"];
    method = JavaNew["org.apache.commons.httpclient.methods.PostMethod", url];
    partSource = JavaNew["org.apache.commons.httpclient.methods.multipart.ByteArrayPartSource", "mmagraphics.png", MakeJavaObject[data]@toCharArray[]];
    part = JavaNew["org.apache.commons.httpclient.methods.multipart.FilePart", "name", partSource];
    part@setContentType["image/png"];
    entity = JavaNew["org.apache.commons.httpclient.methods.multipart.MultipartRequestEntity", {part}, method@getParams[]];
    method@setRequestEntity[entity];
    code = client@executeMethod[method];
    response = method@getResponseBodyAsString[];
  ]

  If[code =!= 200, Message[stackImage::httperr, code]; Return[$Failed]];
  response = StringTrim /@ StringSplit[response, "\n"];

  error = getVal[response, "error"];
  result = getVal[response, "result"];
  If[StringMatchQ[result, "http*"],
   result,
   Message[stackImage::err, error]; $Failed]
  ]


stackMarkdown[g_] := "![Mathematica graphics](" <> stackImage[g] <> ")"


stackCopyMarkdown[g_] := Module[{nb, markdown},
  markdown = Check[stackMarkdown[g], $Failed];
  If[markdown =!= $Failed,
   nb = NotebookCreate[Visible -> False];
   NotebookWrite[nb, Cell[markdown, "Text"]];
   SelectionMove[nb, All, Notebook];
   FrontEndTokenExecute[nb, "Copy"];
   NotebookClose[nb];
   ]
  ]

<强>更新

这是一个按钮，可以显示选择的预览，并提供上传（或取消）。它需要定义先前的函数。

Button["Upload to SO",
 Module[{cell = NotebookRead@InputNotebook[], img},
  If[cell =!= {}, img = Rasterize[cell];
   MessageDialog[
    Column[{"Upload image to StackExchange sites?", 
      img}], {"Upload and copy MarkDown" :> stackCopyMarkdown[img], 
     "Cancel" :> Null}, WindowTitle -> "Upload to StackExchange"]]]]

不幸的是我无法将按钮放在调色板（CreatePalette）中，因为调色板尺寸会影响光栅化。欢迎解决这个问题。

更新2：

根据this question的答案，这是一个仅适用于Windows的调色板按钮：

button = Button["Upload to SO",
  Module[{sel},
   FrontEndExecute[
    FrontEndToken[FrontEnd`SelectedNotebook[], "CopySpecial", "MGF"]];
   sel = Cases[NotebookGet@ClipboardNotebook[], 
     RasterBox[data_, ___] :> 
      Image[data, "Byte", ColorSpace -> "RGB", Magnification -> 1], 
     Infinity];
   If[sel =!= {},
    With[{img = First[sel]},
     MessageDialog[
      Column[{"Upload image to StackExchange sites?", 
        img}], {"Upload and copy MarkDown" :> stackCopyMarkdown[img], 
       "Cancel" :> Null}, WindowTitle -> "Upload to StackExchange"]
     ]
    ]
   ]
  ]

CreatePalette[button]

警告：即使您在预览框中单击取消，它也会破坏剪贴板内容。

Answer 3

注意：这是使用我的匿名密钥匿名imgur上传器。 imgur网站将上传限制为每小时上传50次，这应该是正常的，但如果很多人同时尝试这种情况，这可能会导致问题。所以请在这里获取您自己的匿名密钥：

http://imgur.com/register/api_anon

然后用您自己的密钥替换下面代码中的密钥（ thanks！）。

代码中最棘手的部分是从Mathematica表达式到PNG图像到Base64编码到URL编码的转换。大约有1000种方法可以做错，我想我设法尝试了所有这些方法。

代码分解为几个部分：

构建POST网址
建立HTTP连接
发送POST网址
回读结果，即XML
从XML
将imgur网址格式化为markdown（或作为 Mathematica Hyperlink函数）。

以下是代码：

imgur[expr_] :=
 Module[{url, key, image, data, jUrl, jConn, jWriter, jInput, buffer,
   byte, xml, imgurUrl},
  Needs["JLink`"];
  JLink`JavaBlock[
   JLink`LoadJavaClass["java.net.URLEncoder"];
   url = "http://api.imgur.com/2/upload";
   key = "c07bc3fb59ef878d5e23a0c4972fbb29";
   image = ExportString[ExportString[expr, "PNG"], "Base64"];
   data =
    URLEncoder`encode["key"   , "UTF-8"] <> "=" <>
    URLEncoder`encode[ key    , "UTF-8"] <> "&" <>
    URLEncoder`encode["image" , "UTF-8"] <> "=" <>
    URLEncoder`encode[ image  , "UTF-8"] ;
   jUrl = JLink`JavaNew["java.net.URL", url];
   jConn = jUrl@openConnection[];
   jConn@setDoOutput[True];
   jWriter =
    JLink`JavaNew["java.io.OutputStreamWriter",
     jConn@getOutputStream[]];
   jWriter@write[data];
   jWriter@flush[];
   jInput = jConn@getInputStream[];
   buffer = {};
   While[(byte = jInput@read[]; byte >= 0), AppendTo[buffer, byte]];
   ];
  xml = ImportString[FromCharacterCode[buffer], "XML"];
  imgurUrl =
   Cases[xml,
     XMLElement["original", {}, {string_}] :>
      string, \[Infinity]][[1]];
  "![Mathematica graphic](" <> imgurUrl <> ")"
  ]

测试：

In[]:= g = Graphics[{Blue, Disk[]}, PlotRange -> 1.2, ImageSize -> Small];
       pic = Overlay[{Blur[Binarize@g, 10], g}];
       imgur[pic]

Out[]= ![Mathematica graphic](http://i.imgur.com/eGOlL.png)

实际图片：

Mathematica graphic

从Mathematica上传图片到Imgur

3 个答案: