Question

我正在从Erlang Programming一书中练习练习12-2。我有一个模块 db_server_otp ，它实现了一个OTP gen_server行为。作为一个独立的模块，我测试了它，它按预期工作。我现在必须为它添加一个主管。根据本章中的示例，我创建了一个模块 db_server_sup ，如下所示：

-module(db_server_sup).
-export([start/0,init/1]).
-behavior(supervisor).

start() ->
    supervisor:start_link({local, ?MODULE}, ?MODULE, []).

init(_Arguments) ->
    DbServerOtp = {db_server_otp,                %% Id
                   {db_server_otp, start, []},   %% child process
                   permanent,                    %% restart 
                   30000,                        %% shutdown (ms)
                   worker,                       %% type
                   {db_server_otp}},             %% required modules
    {ok, 
     {{one_for_all,           %% terminate all children and restart
       5,                     %% max of n restarts in MaxSeconds
       3600},                 %% MaxSeconds (s)
      [DbServerOtp]}}.        %% child process list

两个模块都位于同一个目录中，我用.beam文件编译这两个模块都在我启动erlang shell的同一个工作目录中。但是，使用erlang shell，我无法启动主管。

Erlang R13B03 (erts-5.7.4) [source] [64-bit] [smp:8:2] [rq:8] [async-threads:0] [hipe] [kernel-poll:false]
Eshell V5.7.4  (abort with ^G)
1> c(db_server_otp).
./db_server_otp.erl:5: Warning: undefined callback function code_change/3 (behaviour 'gen_server')
./db_server_otp.erl:5: Warning: undefined callback function handle_info/2 (behaviour 'gen_server')
{ok,db_server_otp}
2> c(db_server_sup).
{ok,db_server_sup}
3> db_server_sup:start().
** exception exit: {start_spec,{invalid_modules,{db_server_otp}}}

我是否必须导入 db_server_otp 模块？如果是这样，我必须导入哪些功能？我正在 db_server_otp ：

中导出我的所有OTP方法

-module(db_server_otp).
-export([start/0,stop/0]).
-export([write/2,read/1,delete/1,match/1]).
-export([init/1,terminate/2,handle_cast/2,handle_call/3]).
-behavior(gen_server).

Answer 1

'required modules'应该是一个列表，而不是一个元组。

尝试使用：

DbServerOtp = {db_server_otp,                %% Id
               {db_server_otp, start, []},   %% child process
               permanent,                    %% restart 
               30000,                        %% shutdown (ms)
               worker,                       %% type
               [db_server_otp]},             %% required modules

Answer 2

风格约定：看到db_server_sup和db_server_otp中的开始函数都会创建您应该称之为start_link的链接。这是一个普遍的惯例。

Erlang OTP主管

2 个答案: