Question

例如，我想创建一个整数三元组的MyType类型。但不仅仅是三个整数的笛卡尔积，我希望该类型代表所有（x，y，z），使x + y + z = 5

我该怎么做？除了使用just（x，y），因为z = 5 - x - y

同样的问题，如果我有三个构造函数A，B，C和类型应该全部（A x，B y，C z），使得x + y + z = 5

Answer 1

我认为这里的技巧是你没有在类型级别强制执行它，你使用“智能构造函数”：即只允许通过生成这样的值的函数创建这样的“元组”：

module Test(MyType,x,y,z,createMyType) where

data MyType = MT { x :: Int, y :: Int, z :: Int }

createMyType :: Int -> Int -> MyType
createMyType myX myY = MT { x = myX, y = myY, z = 5 - myX - myY }

如果要生成所有可能的此类值，则可以使用提供的或指定的边界编写一个函数来执行此操作。

很有可能使用类型级别的教会数字或其他类似的东西来强制创建这些，但对于你可能想要/需要的东西来说，这几乎肯定是太多了。

这可能不是你想要的（即“除了使用只是（x，y），因为z = 5 - x - y”）但它比尝试对类型级别有某种强制限制更有意义允许有效值。

类型可以确保正确的“类型”值（没有双关语）;确保隐藏构造函数的值的有效性，并且只允许通过批准的函数进行创建，以保证您需要的任何不变量。

Answer 2

是的，聪明的构造函数或Agda是走到这里的方式，但是如果你真的想用“依赖”方法疯狂，那么在Haskell：

{-# LANGUAGE GADTs, TypeFamilies, RankNTypes, StandaloneDeriving, UndecidableInstances, TypeOperators #-}

data Z = Z
data S n = S n

data Nat n where
  Zero :: Nat Z
  Suc  :: Nat n -> Nat (S n)

deriving instance Show (Nat n)

type family (:+) a b :: *
type instance (:+) Z b = b
type instance (:+) (S a) b = S (a :+ b)

plus :: Nat x -> Nat y -> Nat (x :+ y)
plus Zero y = y
plus (Suc x) y = Suc (x `plus` y)

type family (:*) a b :: *
type instance (:*) Z b = Z
type instance (:*) (S a) b = b :+ (a :* b)

times :: Nat x -> Nat y -> Nat (x :* y)
times Zero y = Zero
times (Suc x) y = y `plus` (x `times` y)

data (:==) a b where
  Refl :: a :== a

deriving instance Show (a :== b)

cong :: a :== b -> f a :== f b
cong Refl = Refl

data Triple where
  Triple :: Nat x -> Nat y -> Nat z -> (z :== (x :+ y)) -> Triple

deriving instance Show Triple

-- Half a decision procedure
equal :: Nat x -> Nat y -> Maybe (x :== y)
equal Zero Zero = Just Refl
equal (Suc x) Zero = Nothing
equal Zero (Suc y) = Nothing
equal (Suc x) (Suc y) = cong `fmap` equal x y

triple' :: Nat x -> Nat y -> Nat z -> Maybe Triple
triple' x y z = fmap (Triple x y z) $ equal z (x `plus` y)

toNat :: (forall n. Nat n -> r) -> Integer -> r
toNat f n | n < 0 = error "why can't we have a natural type?"
toNat f 0 = f Zero
toNat f n = toNat (f . Suc) (n - 1)

triple :: Integer -> Integer -> Integer -> Maybe Triple
triple x y z = toNat (\x' -> toNat (\y' -> toNat (\z' -> triple' x' y' z') z) y) x

data Yatima where
  Yatima :: Nat x -> Nat y -> Nat z -> ((x :* x) :+ (y :* y) :+ (z :* z) :== S (S (S (S (S Z))))) -> Yatima

deriving instance Show Yatima

yatima' :: Nat x -> Nat y -> Nat z -> Maybe Yatima
yatima' x y z = 
  fmap (Yatima x y z) $ equal ((x `times` x) `plus` (y `times` y) `plus` (z `times` z)) (Suc (Suc (Suc (Suc (Suc Zero)))))

yatima :: Integer -> Integer -> Integer -> Maybe Yatima
yatima x y z = toNat (\x' -> toNat (\y' -> toNat (\z' -> yatima' x' y' z') z) y) x


{-
λ> triple 3 4 5
Nothing
λ> triple 3 4 7
Just (Triple (Suc (Suc (Suc Zero))) (Suc (Suc (Suc (Suc Zero)))) Refl (Suc (Suc (Suc (Suc (Suc (Suc (Suc Zero))))))))

λ> yatima 0 1 2 
Just (Yatima Zero (Suc Zero) (Suc (Suc Zero)) Refl)
λ> yatima 1 1 2 
Nothing
-}

然后，你的代码中有一个静态检查的不变量！除了你可以撒谎......

Answer 3

执行此操作的常规依赖类型方法是使用sigma（依赖产品）类型，例如在Agda中：

open import Relation.Binary.PropositionalEquality (_≡_)
open import Data.Nat (ℕ; _+_)
open import Data.Product (Σ; ×; _,_)

FiveTriple : Set
FiveTriple = Σ (ℕ × ℕ × ℕ) (λ{ (x , y , z) → x + y + z ≡ 5 })

someFiveTriple : FiveTriple
someFiveTriple = (0 , 2 , 5) , refl

这就是为什么Σ通常被称为“存在主义”类型：它允许您指定一些数据和一些关于该数据的属性。

Answer 4

我不是这方面的专家，但我认为你不能在类型级别的Haskell中实现它，因为Haskell不支持依赖类型。你可能想看看Agda。

Answer 5

刚刚详细介绍了ivanm的answer：

data MyType = MT {x :: Int, y :: Int, z :: Int } deriving Show

createMyType :: Int -> Int -> Int -> Maybe MyType
createMyType a b c
    | a + b + c == 5 = Just MT { x = a, y = b, z = c }
    | otherwise      = Nothing

如何制作有限制的类型

5 个答案: