Question

我手边有一张图片（png格式）。限制椭圆（代表原子核）的线是直的，这是不切实际的。我怎么能从图像中提取线条并使它们弯曲，并且前提条件是它们仍然包围着原子核。

以下是图像：
enter image description here

弯曲后

enter image description here

编辑：如何将answer2中的扩张和过滤部分翻译成 Matlab 语言？我无法理解。

Answer 1

您输入的是Voronoi图。您可以使用另一个距离函数而不是欧几里德函数重新计算它。

以下是使用曼哈顿距离的Mathematica中的示例（i3是没有线条的输入图像）：

ColorCombine[{Image[
   WatershedComponents[
    DistanceTransform[Binarize@i3, 
      DistanceFunction -> ManhattanDistance] ]], i3, i3}]

enter image description here

修改

我正在使用另一种算法（初步结果）。你觉得怎么样？

Answer 2

好的，这是一种涉及获得“自然”非对称外观所需的几个随机化步骤的方法。

我在Mathematica中发布实际代码，以防有人关心将其翻译成Matlab。

(* A preparatory step: get your image and clean it*)
i = Import@"http://i.stack.imgur.com/YENhB.png";
i1 = Image@Replace[ImageData[i], {0., 0., 0.} -> {1, 1, 1}, {2}];
i2 = ImageSubtract[i1, i];
i3 = Inpaint[i, i2]

enter image description here

(*Now reduce to a skeleton to get a somewhat random starting point.  
The actual algorithm for this dilation does not matter, as far as we 
get a random area slightly larger than the original elipses *)
id = Dilation[SkeletonTransform[
             Dilation[SkeletonTransform@ColorNegate@Binarize@i3, 3]], 1]

enter image description here

(*Now the real random dilation loop*)
(*Init vars*)
p = Array[1 &, 70]; j = 1;
(*Store in w an image with a different color for each cluster, so we 
can find edges between them*)
w = (w1 = 
      WatershedComponents[
       GradientFilter[Binarize[id, .1], 1]]) /. {4 -> 0} // Colorize;
(*and loop ...*)
For[i = 1, i < 70, i++,
 (*Select edges in w and dilate them with a random 3x3 kernel*)
 ed = Dilation[EdgeDetect[w, 1], RandomInteger[{0, 1}, {3, 3}]];
 (*The following is the core*)
 p[[j++]] = w =
   ImageFilter[  (* We apply a filter to the edges*)
    (Switch[
          Length[#1],  (*Count the colors in a 3x3 neighborhood of each pixel*)
          0, {{{0, 0, 0}, 0}},          (*If no colors, return bkg*)
          1, #1,                        (*If one color, return it*)
          _, {{{0, 0, 0}, 0}}])[[1, 1]] (*If more than one color, return bkg*)&@
      Cases[Tally[Flatten[#1, 1]], 
       Except[{{0.`, 0.`, 0.`}, _}]] & (*But Don't count bkg pixels*),
    w, 1,
    Masking -> ed,       (*apply only to edges*)
    Interleaving -> True (*apply to all color chanels at once*)]
 ]

结果是：

enter image description here

修改

对于面向Mathematica的阅读器，最后一个循环的功能代码可以更容易（也更短）：

NestList[ ImageFilter[ If[Length[#1] == 1, #1[[1, 1]], {0, 0, 0}] &@ Cases[Tally[Flatten[#1, 1]], Except[{0.` {1, 1, 1}, _}]] & , #, 1, Masking -> Dilation[EdgeDetect[#, 1], RandomInteger[{0, 1}, {3, 3}]], Interleaving -> True ] &, WatershedComponents@GradientFilter[Binarize[id,.1],1]/.{4-> 0}//Colorize, 5]

Answer 3

以下是我提出的问题，它不是@belisarius代码的直接翻译，但应该足够接近..

%# read image (indexed image)
[I,map] = imread('http://i.stack.imgur.com/YENhB.png');

%# extract the blobs (binary image)
BW = (I==1);

%# skeletonization + dilation
BW = bwmorph(BW, 'skel', Inf);
BW = imdilate(BW, strel('square',2*1+1));

%# connected components
L = bwlabel(BW);
imshow(label2rgb(L))

%# filter 15x15 neighborhood
for i=1:13
    L = nlfilter(L, [15 15], @myFilterFunc);
    imshow( label2rgb(L) )
end

%# result
L(I==1) = 0;                %# put blobs back
L(edge(L,'canny')) = 0;     %# edges
imshow( label2rgb(L,@jet,[0 0 0]) )

myFilterFunc.m

function p = myFilterFunc(x)
    if range(x(:)) == 0
        p = x(1);                %# if one color, return it
    else
        p = mode(x(x~=0));       %# else, return the most frequent color
    end
end

结果：

screenshot

这是一个过程的动画：

animation

Matlab：如何在图像中弯曲线条

3 个答案:

myFilterFunc.m