Question

我无法弄清楚这里的格式规则..我的例子中有太多行代码为每行添加4个空格，所以这里是我需要帮助的代码的链接

http://nitemsg.blogspot.com/2011/01/heres-unit-written-in-delphi-7-that-you.html

我遇到的问题是我对delphi不太了解将此代码与表单一起使用。我只是一个拖放程序员。

当检测到USB设备时，showmessage（'friendly name ='+ ...）的示例是我需要的。

欢呼，

Answer 1

如果您只熟悉拖放式编程，并且对对象或其他单元知之甚少，那么您需要熟悉使用自动创建的表单以外的对象以及放入的组件它们。

此链接的代码是整个单元。您需要在项目中创建一个新单位（文件＆gt;新＆gt;单位）。它看起来像这样：

unit Unit1;

interface

implementation

end.

现在，当您保存单位时，单位的名称将自动更改为文件名（不带扩展名），如下所示：

unit MahUSB;

interface

implementation

end.

在此示例中，您应使用与您尝试使用的源相同的单位名称。将单位保存为“MahUSB.pas”，并且应与项目的其余部分（或其他地方，只是建议）位于同一文件夹中。复制/粘贴该网站的所有代码，并立即替换此单元中的所有内容。

现在为了实际使用它，您需要创建此对象的实例。只有一个实例（我说这只是因为从外观来看，不需要多于一个）。

非常重要：看到你不熟悉对象，让我快速解释一下。需要创建对象才能工作。与此同时，任何创建的内容在完成后也需要免费提供。在这种情况下，我们将在您的应用程序启动时创建此对象，并在应用程序关闭时释放该对象。

现在，在您的MAIN FORM（不是任何其他表单）上，您需要为OnCreate和OnDestroy设置事件处理程序。您还需要声明一个变量来表示此对象。在主窗体的声明中，添加一个带有此对象类型的变量“USB”。确保在“私人”或“公共”部分下，任何一个都可以。另外，请确保在uses子句中声明主单元顶部的“MahUSB”单元。

以主窗体声明对象：

type
  TForm1 = class(TForm)
  private
    USB: TUsbClass;
  public

  end;

在您的应用启动/关闭时创建/释放对象：

  procedure TForm1.FormCreate(Sender: TObject);
  begin
    USB:= TUsbClass.Create;
  end;

  procedure TForm1.FormDestroy(Sender: TObject);
  begin
    if assigned(USB) then USB.Free;
  end;

现在我们还没有完成。现在我们需要添加事件处理程序。请注意，您在此单元的顶部有两种类型，称为 TOnDevVolumeEvent 和 TOnUsbChangeEvent 。这些是事件类型。事件处理程序中的参数必须与这些类型中声明的参数相同。现在，在您的主窗体中，声明这些事件处理程序...

  type
    TForm1 = class(TForm)
      procedure FormCreate(Sender: TObject);
      procedure FormDestroy(Sender: TObject);
    private
      USB: TUsbClass;
      procedure VolumeEvent(const bInserted : boolean; const sDrive : string);
      procedure ChangeEvent(const bInserted : boolean;
        const ADevType,ADriverName, AFriendlyName : string);
    public

    end;

现在还有一件事我们必须要做才能做到这一点。 USB对象需要知道要使用的事件处理程序，因此，我们需要将这些过程分配给事件。在您的表单创建后，我们需要分配这些事件......

    procedure TForm1.FormCreate(Sender: TObject);
    begin
      USB:= TUsbClass.Create;
      USB.OnUsbChange:= Self.ChangeEvent;
      USB.OnDevVolume:= Self.VolumeEvent;
    end;

完成所有操作后，您的主表单元应如下所示：

unit uUSBTest;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, MahUSB;

type
  TForm1 = class(TForm)
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
  private
    USB: TUsbClass;
    procedure VolumeEvent(const bInserted : boolean; const sDrive : string);
    procedure ChangeEvent(const bInserted : boolean;
      const ADevType,ADriverName, AFriendlyName : string);
  public

  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.ChangeEvent(const bInserted: boolean; const ADevType,
  ADriverName, AFriendlyName: string);
begin
  ShowMessage('Change event for "'+AFriendlyName+'"');
end;

procedure TForm1.VolumeEvent(const bInserted: boolean;
  const sDrive: string);
begin
  ShowMessage('Volume event for "'+sDrive+'\"');
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  USB:= TUsbClass.Create;
  USB.OnUsbChange:= Self.ChangeEvent;
  USB.OnDevVolume:= Self.VolumeEvent;
end;

procedure TForm1.FormDestroy(Sender: TObject);
begin
  if assigned(USB) then USB.Free;
end;

end.

你有！您将拥有这两个事件处理程序过程，您可以在其中进一步处理这两个事件中的任何一个。

使用delphi检测usb驱动器/设备

1 个答案: