Question

我正在尝试编写Fibonacci的汇编代码版本，它给出第n个Fibonacci数并返回它。

由于某种原因，它无法存储斐波纳契数的返回值并添加它们。

我想要它打印第n个Fibonacci数字。

我对我的代码进行了一些修改，现在它仍然不正确，但它更接近。现在它告诉我第11个斐波纳契数是48.仍然不正确，但我们到了某个地方？

.text

    .globl _fibonacci
_fibonacci:
    pushl %ebp
    movl %esp,%ebp
    push %esi
    movl 8(%ebp),%esi

    cmp $1,%esi
    jle BASE
    sub $1,%esi
    push %esi
    call _fibonacci
    add $4,%esp
    movl %eax,%edx
    sub $1,%esi
    push %esi
    call _fibonacci
    add $4,%esp
    add %eax,%edx
    movl %edx,%eax

DONE:
    pop %esi
    pop %ebp
    ret

BASE:
    mov $1,%eax
    jmp DONE

我正在使用C：

调用此汇编代码

#include <stdio.h>

int fibonacci(int n);

int main(void){
  int n=111;
  int x=fibonacci(n);
  printf("The %d fibonaacci number is %d\n",n,x);
}

Answer 1

您的递归调用正在破坏%edx。您需要在序言中pushl %edx和邮件中的popl %edx，如下所示：

.text

    .globl _fibonacci
/* fib(n) = fib(n-1) + fib(n-2) */
_fibonacci:
    pushl %ebp
    movl %esp,%ebp
    pushl %esi
    pushl %edx  /* <-- PUSH TO SAVE BEFORE CLOBBERING */
    movl 8(%ebp),%esi

    /* 0th and 1st numbers are defined to be 1. */
    cmpl $1,%esi
    jle BASE

    /* find fib(n-1) */
    subl $1,%esi
    pushl %esi
    call _fibonacci

    addl $4,%esp
    movl %eax,%edx  /* <-- %edx CLOBBERED! */

    /* find fib(n-2) */
    subl $1,%esi
    pushl %esi
    call _fibonacci

    addl $4,%esp
    addl %edx,%eax

DONE:
    popl %edx  /* <-- POP TO RESTORE AFTER CLOBBERING */
    popl %esi
    popl %ebp
    ret

BASE:
    movl $1,%eax
    jmp DONE

使用此驱动程序：

// BUILD -arch i386 ONLY
// clang -arch i386 fib.s fibo.c -o fibo
#include <stdio.h>

int fibonacci(int n);

void Test(int i) {
  int r = fibonacci(i);
  printf("fib(%d) -> %d\n", i, r);
}

int main(void){
  for (int i = 0; i < 10; ++i) {
    Test(i);
  }
  return 0;
}

试运行看起来像：

$ ./fibo 
fib(0) -> 1
fib(1) -> 1
fib(2) -> 2
fib(3) -> 3
fib(4) -> 5
fib(5) -> 8
fib(6) -> 13
fib(7) -> 21
fib(8) -> 34
fib(9) -> 55

Answer 2

问题是你需要在递归调用中更谨慎地使用寄存器。

您的代码假定%edx在第二次调用时保留其值。

但事实并非如此，因为_fibonacci会更改它。

装配中的斐波纳契实现给出了意想不到的结果

2 个答案: