Question

我在使用xslt模板转换xml数据时遇到问题。我想问题是关于xml中的命名空间，在删除命名空间xmlns="http://schemas.microsoft.com/sharepoint/soap/后，一切正常。

<?xml version="1.0"?>
<soap:Envelope xmlns:soap="http://schemas.xmlsoap.org/soap/envelope/" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xmlns:xsd="http://www.w3.org/2001/XMLSchema">
    <soap:Body>
        <GetListCollectionResponse xmlns="http://schemas.microsoft.com/sharepoint/soap/">
            <GetListCollectionResult>
                <Lists>
                    <List Title="Announcement1" Description="Announcement 1"/>
                    <List Title="Announcement2" Description="Announcement 2"/>
                </Lists>
            </GetListCollectionResult>
        </GetListCollectionResponse>
    </soap:Body>
</soap:Envelope>

<xsl:stylesheet version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:msxsl="urn:schemas-microsoft-com:xslt"
    exclude-result-prefixes="msxsl">

  <xsl:template match="//Lists">
    <table>
      <xsl:for-each select="List">
        <tr>
          <td>
            <xsl:value-of select="@Title"/>:
          </td>
          <td>
            <xsl:value-of select="@Description"/>
          </td>
        </tr>
      </xsl:for-each>
    </table>
  </xsl:template>
</xsl:stylesheet>

Answer 1

只需在样式表中添加一个命名空间即可。这是使用名称空间ms的样式表。您可以使用您想要的任何前缀：

<xsl:stylesheet version="1.0"
  xmlns:ms="http://schemas.microsoft.com/sharepoint/soap/"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:msxsl="urn:schemas-microsoft-com:xslt"
  exclude-result-prefixes="msxsl ms">

  <xsl:template match="//ms:Lists">
    <table>
      <xsl:for-each select="ms:List">
        <tr>
          <td>
            <xsl:value-of select="@Title"/>:
          </td>
          <td>
            <xsl:value-of select="@Description"/>
          </td>
        </tr>
      </xsl:for-each>
    </table>
  </xsl:template>
</xsl:stylesheet>

这会产生以下输出：

<table><tr><td>Announcement1:
  </td><td>Announcement 1</td></tr><tr><td>Announcement2:
  </td><td>Announcement 2</td></tr></table>

或者，在XSLT 2.0中，您只需使用星号（*）作为前缀，而不是添加命名空间：

<xsl:stylesheet version="1.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:msxsl="urn:schemas-microsoft-com:xslt"
  exclude-result-prefixes="msxsl">

  <xsl:template match="//*:Lists">
    <table>
      <xsl:for-each select="*:List">
        <tr>
          <td>
            <xsl:value-of select="@Title"/>:
          </td>
          <td>
            <xsl:value-of select="@Description"/>
          </td>
        </tr>
      </xsl:for-each>
    </table>
  </xsl:template>
</xsl:stylesheet>

这将产生与前一个示例相同的输出。

使用XSLT进行XML转换，使用命名空间问题

1 个答案: