Question

在Delphi 2010中使用RTTI系统，有没有办法找出属性是否是TDateTime？每当我回调asVariant并且检查属性类型时，它现在将它视为双精度。这是因为它只能看到基本类型吗？（TDateTime = double）

Answer 1

尝试检查TRttiProperty.PropertyType

的Name属性

我没有Delphi 2010，但这适用于XE。

{$APPTYPE CONSOLE}

uses
  SysUtils,
  Classes,
  Rtti;

type
  TMyClass =class
  private
    FDate: TDateTime;
    FProp: Integer;
    FDate2: TDateTime;
    FDate1: TDateTime;
  public
   property Date1 : TDateTime read FDate1  Write FDate1;
   property Prop : Integer read FProp  Write FProp;
   property Date2 : TDateTime read FDate2  Write FDate2;
  end;

var
 ctx : TRttiContext;
 t :  TRttiType;
 p :  TRttiProperty;
begin
 ctx := TRttiContext.Create;
 try
   t := ctx.GetType(TMyClass.ClassInfo);
   for p in  t.GetProperties do
    if CompareText('TDateTime',p.PropertyType.Name)=0 then
     Writeln(Format('the property %s is %s',[p.Name,p.PropertyType.Name]));
 finally
   ctx.Free;
 end;
  Readln;
end.

此代码返回

the property Date1 is TDateTime
the property Date2 is TDateTime

Answer 2

定义类型时的关键点是类型指令。这两个定义是不同的：

Type
  TDateTime = Double; // here p.PropertyType.Name returns Double

but

Type
  TDateTime = type Double; // here p.PropertyType.Name returns TDateTime

or 

Type
  u8 = type Byte; // here p.PropertyType.Name returns u8

but

Type
  u8 = Byte; // here p.PropertyType.Name returns Byte !

如何通过RTTI区分TDateTime属性和Double属性？

2 个答案: