Question

我的XML看起来像这样 -

<info>
<name>NameGoesHere</name>
<age>99</age>
</info>

使用XML :: LibXML :: Reader，我想打印年龄。

我从here阅读了文档，我正在寻找一个例子。我可以使用$reader->nextElement('info')然后打印innerXML，但无法弄清楚如何仅打印年龄而不是整个innerxml。

Answer 1

尝试localName：

#!/usr/bin/perl
use strict;
use warnings;
use XML::LibXML::Reader;

my $reader = XML::LibXML::Reader->new(IO => \*DATA)
    or die "Cannot read from \\*DATA\n";

while ( $reader->read ) {
    print $reader->readInnerXml if $reader->localName eq 'age';
}

$reader->finish;

__DATA__
<info>
<name>NameGoesHere</name>
<age>99</age>
</info>

主要来自Regex: keep everything in <profession></profession> tags

Answer 2

use strict;
use warnings;
use feature qw( say );

use XML::LibXML::Reader qw(
   XML_READER_TYPE_ELEMENT
   XML_READER_TYPE_END_ELEMENT
   XML_READER_TYPE_TEXT
);

my $reader = XML::LibXML::Reader->new(IO => \*DATA);

my $in_age = 0;
my $age;
while ($reader->read()) {
   if ($reader->nodeType() == XML_READER_TYPE_ELEMENT && $reader->name() eq 'age') {
      $age = '' if !$in_age;
      ++$in_age;
   }
   elsif ($reader->nodeType() == XML_READER_TYPE_END_ELEMENT && $reader->name() eq 'age') {
      --$in_age;
      say $age if !$in_age;
   }
   elsif ($in_age && $reader->nodeType() == XML_READER_TYPE_TEXT) {
      $age .= $reader->value();
   }
}

__DATA__
<info>
<name>NameGoesHere</name>
<age>99</age>
</info>

如何在Perl libXML :: Reader中读取节点的值

2 个答案: