Question

我已经编写了这个小小模式，以便在主模式执行初始缩进行为后让TAB键继续缩进和/或在主模式认为不需要缩进时强制缩进。

有人向我指出，组合setq和make-local-variable可能会简化为let范围。鉴于这需要同时跨多个缓冲区工作，如何将其更改为使用let而不是make-local-variable？

;;; dwim-tab.el --- minor mode to force indentation when TAB would otherwise stall

; internal tracking variables
(setq dwim-tab-point-before nil)
(setq dwim-tab-point-after nil)

(defun dwim-tab ()
  "Indents normally once, then switches to tab-to-tab-stop if invoked again.
Always performs tab-to-tab-stop if the first TAB press does not cause the
point to move."
  (interactive)
  (setq dwim-tab-point-before (point))
  (if (eq dwim-tab-point-before dwim-tab-point-after) ; pressed TAB again
      (tab-to-tab-stop) 
    (indent-for-tab-command))
  (if (eq (point) dwim-tab-point-before) ; point didn't move
      (tab-to-tab-stop))
  (setq dwim-tab-point-after (point)))

(define-minor-mode dwim-tab-mode
  "Toggle dwim-tab-mode.
With a non-nil argument, turns on dwim-tab-mode. With a nil argument, turns it
off.

When dwim-tab-mode is enabled, pressing the TAB key once will behave as normal,
but pressing it subsequent times, will continue to indent, using
tab-to-tab-stop.

If dwim-tab determines that the first TAB key press resulted in no movement of
the point, it will indent according to tab-to-tab-stop instead."
  :init-value nil
  :lighter " DWIM"
  :keymap '(("\t" . dwim-tab))
  (make-local-variable 'dwim-tab-point-before)
  (make-local-variable 'dwim-tab-point-after))

(provide 'dwim-tab)

Answer 1

这样做你想要的吗？看，我没有变数！

(defun tab-dwim ()
  (interactive)
  (when (or (eq last-command this-command)      
            (= (point) (progn
                         (indent-for-tab-command)
                         (point))))
      (tab-to-tab-stop)))

假设indent-for-tab-command不会再次神奇地开始缩进，那么最后一次命令检查并不是绝对必要的。但它的CPU效率稍高。

用于次要模式的Elisp内部变量作用域（setq / make-local-variable / let）

1 个答案: