Fortran：从一行一次读取一个值

Question

我正在使用FORTRAN从ASCII文本文件中读取数据。该文件每行包含多个数据值，但每行的值数不是常数。

101.5 201.6 21.4 2145.5
45.6 21.2
478.5
...

通常在读取语句之后，Fortran会转到下一行。我想要做的是一次读取一个数据值。如果它到达行的末尾，它应该继续读下一行。这可能吗？

Answer 1

正如IRO-bot在对你的问题的评论中指出的那样，M.S.B已经给出了答案。下面我只提供了一些说明答案的代码（因为M.S.B.的帖子中没有答案）：

program test

   character(len=40) :: line
   integer           :: success, i, indx, prev, beginning
   real              :: value

   open(1,file='test.txt')

   do  
      read(1,'(A)',iostat=success) line
      if (success.ne.0) exit

      prev      = 1 
      beginning = 1 

      do i=1,len(line)

         ! is the current character one out of the desired set? (if you
         ! have got negative numbers as well, don't forget to add a '-')
         indx = index('0123456789.', line(i:i))

         ! store value when you have reached a blank (or any other 
         ! non-real number character)
         if (indx.eq.0 .and. prev.gt.0) then
            read(line(beginning:i-1), *) value
            print *, value
         else if (indx.gt.0 .and. prev.eq.0) then
            beginning = i 
         end if

         prev = indx
      end do
   end do

   close(1)

end program test

使用您提供的样本行运行此程序时，输出为

101.5000    
201.6000    
21.40000    
2145.500    
45.60000    
21.20000    
478.5000

我希望你会发现这有用。