Question

如何在emacs中的所有缓冲区中“M-x replace-string”？

Answer 1

M-x ibuffer RET t U

但是你可能想要比这更具限制性，因为如果不能替换它会中止 - 例如遇到包含匹配文件名的只读dired缓冲区。

ibuffer中的

C-h m 读取模式帮助，并学习如何轻松地标记您感兴趣的缓冲区。

编辑：可以通过修改原始定义轻松编写ibuffer-do-replace-regexp的非正则表达式版本：

;; defines ibuffer-do-replace-string
(define-ibuffer-op replace-string (from-str to-str)
  "Perform a `replace-string' in marked buffers."
  (:interactive
   (let* ((from-str (read-from-minibuffer "Replace string: "))
          (to-str (read-from-minibuffer (concat "Replace " from-str
                                                " with: "))))
     (list from-str to-str))
   :opstring "replaced in"
   :complex t
   :modifier-p :maybe)
  (save-window-excursion
    (switch-to-buffer buf)
    (save-excursion
      (goto-char (point-min))
      (let ((case-fold-search ibuffer-case-fold-search))
        (while (search-forward from-str nil t)
          (replace-match to-str nil t))))
    t))

Answer 2

有许多不同的选择，这取决于你想要怎么做。

查看SearchBuffers的Emacs Wiki。有趣的是moccur-edit和icicles。

Answer 3

感谢Trey在这方面提到Icicles buffer searching。

让我在Dired中提及 Q （dired-do-query-replace）。非常便利。请注意，您可以使用这些键（以及更多）在Dired中轻松标记文件集：

％m （dired-mark-files-regexp） - 标记名称与正则表达式匹配的文件
％g （dired-mark-files-containing-regexp） - 标记文本（内容）与正则表达式匹配的文件
*。（dired-mark-extension） - 标记名称具有相同扩展名的文件（例如.el）

请务必加载标准库dired-x.el（可能还有dired-aux.el）。

Answer 4

我很久以前在网站上发现了这个，对不起，我不记得来源了。如果你找到一个只读缓冲区，它会停止，所以要小心。

只需将其放入.emacs

即可

(defun query-replace-in-open-buffers (arg1 arg2)
  "query-replace in open files"
  (interactive "sQuery Replace in open Buffers: \nsquery with: ")
  (mapcar
   (lambda (x)
     (find-file x)
     (save-excursion
       (beginning-of-buffer)
       (query-replace arg1 arg2)))
   (delq
    nil
    (mapcar
     (lambda (x)
       (buffer-file-name x))
     (buffer-list)))))

如何在emacs中的所有缓冲区中“M-x replace-string”？

4 个答案: