Question

我想将我的对象的值转储到我的浏览器中，但它会不按顺序打印密钥。如何以（递归）排序顺序转储密钥？

use Data::Dumper;

sub dump{
    my($self) = @_;
    print "<pre>",Dumper($self),"</pre>";
}

Answer 1

设置$Data::Dumper::Sortkeys = 1以获取Perl的默认排序顺序。如果要自定义顺序，请将$Data::Dumper::Sortkeys设置为对接收对散列的引用作为输入的子例程的引用，并按照希望它们出现的顺序输出对散列键列表的引用。

# sort keys
$Data::Dumper::Sortkeys = 1;
print Dumper($obj);

# sort keys in reverse order - use either one
$Data::Dumper::Sortkeys = sub { [reverse sort keys %{$_[0]}] };
$Data::Dumper::Sortkeys = sub { [sort {$b cmp $a} keys %{$_[0]}] };
print Dumper($obj);

Answer 2

对不耐烦的

的简短回答

请改用Data::Dumper::Concise。它排序你的钥匙。像这样使用它：

use Data::Dumper::Concise;

my $pantsToWear = {
    pony       => 'jeans',
    unicorn    => 'corduroy',
    marsupials => {kangaroo => 'overalls', koala => 'shorts + suspenders'},
};

warn Dumper($pantsToWear);

更多关于好奇的话

Data :: Dumper :: Concise还为您提供更紧凑，更易读的输出。

请注意，Data :: Dumper :: Concise 是 Data :: Dumper，并为您设置了合理的默认配置值。它等同于使用Data :: Dumper：

use Data::Dumper;
{
  local $Data::Dumper::Terse = 1;
  local $Data::Dumper::Indent = 1;
  local $Data::Dumper::Useqq = 1;
  local $Data::Dumper::Deparse = 1;
  local $Data::Dumper::Quotekeys = 0;
  local $Data::Dumper::Sortkeys = 1;
  warn Dumper($var);
}

Answer 3

来自Data::Dumper文档：

$Data::Dumper::Sortkeys or $OBJ->Sortkeys([NEWVAL])
Can be set to a boolean value to control whether hash keys are dumped in sorted order. 
A true value will cause the keys of all hashes to be dumped in Perl's default sort order. 
Can also be set to a subroutine reference which will be called for each hash that is dumped. 
In  this case Data::Dumper will call the subroutine once for each hash, passing it the 
reference of the hash. The purpose of the subroutine is to return a reference to an array of 
the keys that will be dumped, in the order that they should be dumped. Using this feature, you 
can control both the order of the keys, and which keys are actually used. In other words, this 
subroutine acts as a filter by which you can exclude certain keys from being dumped. Default is  
0, which means that hash keys are not sorted.

Answer 4

您可以将$Data::Dumper::Sortkeys变量设置为true值以获得默认排序：

use Data::Dumper;
$Data::Dumper::Sortkeys  = 1;

my $hashref = {
    bob => 'weir',
    jerry =>, 'garcia',
    nested => {one => 'two', three => 'four'}};

print Dumper($hashref), "\n";

或在其中放置一个子程序，以便根据需要对键进行排序。

Answer 5

对于那些想要用Data::Dumper打印时按值排序hashref 的人，这是一个例子：

$Data::Dumper::Sortkeys = sub {
    # Using <=> to sort numeric values
    [ sort { $_[0]->{$a} <=> $_[0]->{$b} } keys %{ $_[0] } ]
};

这是一个更具可读性的替代方案，做同样的事情，但有一个变量来保存哈希值。效率较低，但对于小哈希，有些人可能会发现它更好：

$Data::Dumper::Sortkeys = sub {
    my %h = %{$_[0]};
    # cmp for string comparisons
    [ sort { $h{$a} cmp $h{$b} } keys %h ];
};

Answer 6

排序ascii和全数字：

$Data::Dumper::Sortkeys = sub {
  no warnings 'numeric';
  if(join('',keys %{$_[0]})=~/\d+/)
  {
    [ sort { $a <=> $b } keys %{$_[0]} ]
  }
  else
  {
    return [sort(keys %{$_[0]})];
  }
};

你如何对Data :: Dumper的输出进行排序？

6 个答案:

对不耐烦的

更多关于好奇的话