Question

如果我只在emacs中显示一个窗口并使用M-x编译，则窗口分为两部分，我可以轻松地查看编译缓冲区。但是，如果我有更多的窗口显示，编译日志将接管其中一个，我觉得很烦人。如何使emacs始终拆分新窗口以显示编译日志？

编辑：我读过的一些信息，我一直在做的。看起来compile.el调用display-buffer，如果它是当前的全宽度，它只会拆分一个窗口。有没有办法避免这种行为？

Answer 1

您可以修改Trey Jackson提供的解决方案以满足您的需求。

以下代码段将缓冲区*compilation*标记为特殊，并将自定义函数设置为其显示功能，以便即使已经在拆分窗口中也可以拆分当前窗口。

(setq special-display-buffer-names
      '("*compilation*"))

(setq special-display-function
      (lambda (buffer &optional args)
        (split-window)
        (switch-to-buffer buffer)
        (get-buffer-window buffer 0)))

Answer 2

如果您想要的是一个专用的顶级窗口（Emacs称这些帧），那么这将为您提供帮助。此代码段包含展示位置指令，但自定义'special-display-buffer-names变量可为您提供所需内容。

(setq special-display-buffer-names
      `(("*compilation*" . ((name . "*compilation*")
                            ,@default-frame-alist
                            (left . (- 1))
                            (top . 0)))))

Answer 3

结合How can I prevent emacs from opening new window for compilation output?的代码和http://www.emacswiki.org/emacs/CompilationMode的代码，这是compile的全部代码，它为您提供了4个功能：

1）。使用compile-again自动运行与上次相同的编译，无提示。如果没有最后一次，或者有一个前缀参数，它就像M-x compile。

2）。 compile将拆分当前窗口，它不会影响此框架中的其他窗口。

3）。如果没有错误，它将自动关闭*compilation*缓冲区（窗口），如果错误存在则保留它。

4）。它将突出显示*compilation*缓冲区中源代码的错误行和行号，使用M-n/p导航错误行中*compilation*缓冲区Enter中的每个错误跳转到代码中的行。

(require 'compile)
(setq compilation-last-buffer nil)
(defun compile-again (ARG)
  "Run the same compile as the last time.

If there is no last time, or there is a prefix argument, this acts like M-x compile."
  (interactive "p")
  (if (and (eq ARG 1)
           compilation-last-buffer)
      (progn
        (set-buffer compilation-last-buffer)
        (revert-buffer t t))
    (progn
      (call-interactively 'compile)
      (setq cur (selected-window))
      (setq w (get-buffer-window "*compilation*"))
      (select-window w)
      (setq h (window-height w))
      (shrink-window (- h 10))
      (select-window cur))))
(global-set-key (kbd "C-x C-m") 'compile-again)
(defun my-compilation-hook ()
  "Make sure that the compile window is splitting vertically."
  (progn
    (if (not (get-buffer-window "*compilation*"))
        (progn
          (split-window-vertically)))))
(add-hook 'compilation-mode-hook 'my-compilation-hook)
(defun compilation-exit-autoclose (STATUS code msg)
  "Close the compilation window if there was no error at all."
  ;; If M-x compile exists with a 0
  (when (and (eq STATUS 'exit) (zerop code))
    ;; then bury the *compilation* buffer, so that C-x b doesn't go there
    (bury-buffer)
    ;; and delete the *compilation* window
    (delete-window (get-buffer-window (get-buffer "*compilation*"))))
  ;; Always return the anticipated result of compilation-exit-message-function
  (cons msg code))
(setq compilation-exit-message-function 'compilation-exit-autoclose)
(defvar all-overlays ())
(defun delete-this-overlay(overlay is-after begin end &optional len)
  (delete-overlay overlay)
  )
(defun highlight-current-line ()
"Highlight current line."
  (interactive)
  (setq current-point (point))
  (beginning-of-line)
  (setq beg (point))
  (forward-line 1)
  (setq end (point))
  ;; Create and place the overlay
  (setq error-line-overlay (make-overlay 1 1))

  ;; Append to list of all overlays
  (setq all-overlays (cons error-line-overlay all-overlays))

  (overlay-put error-line-overlay
               'face '(background-color . "red"))
  (overlay-put error-line-overlay
               'modification-hooks (list 'delete-this-overlay))
  (move-overlay error-line-overlay beg end)
  (goto-char current-point))
(defun delete-all-overlays ()
  "Delete all overlays"
  (while all-overlays
    (delete-overlay (car all-overlays))
    (setq all-overlays (cdr all-overlays))))
(defun highlight-error-lines(compilation-buffer process-result)
  (interactive)
  (delete-all-overlays)
  (condition-case nil
      (while t
        (next-error)
        (highlight-current-line))
    (error nil)))
(setq compilation-finish-functions 'highlight-error-lines)

Answer 4

在Emacs中安装smart-compile包。

将此添加到您的init.el或.emacs

中

(require 'compile)
(setq compilation-last-buffer nil)
;; save all modified buffers without asking before compilation
(setq compilation-ask-about-save nil)
(defun compile-again (ARG)
  "Run the same compile as the last time.

With a prefix argument or no last time, this acts like M-x compile,
and you can reconfigure the compile args."
  (interactive "p")
  ;; the following two lines create bug: split a new window every time
  ;; (if (not (get-buffer-window "*compilation*"))
  ;;      (split-window-below))
  (if (and (eq ARG 1) compilation-last-buffer)
      (recompile)
    (call-interactively 'smart-compile)))
(bind-key* "C-x C-m" 'compile-again)
;; create a new small frame to show the compilation info
;; will be auto closed if no error
(setq special-display-buffer-names
      `(("*compilation*" . ((name . "*compilation*")
                            ,@default-frame-alist
                            (left . (- 1))
                            (top . 0)))))
(setq compilation-finish-functions
      (lambda (buf str)
        (if (null (string-match ".*exited abnormally.*" str))
            ;;no errors, make the compilation window go away in a few seconds
            (progn
              (run-at-time
               "1 sec" nil 'delete-windows-on
               (get-buffer-create "*compilation*"))
              (message "No Compilation Errors!")))))

使用C-x C-m编译源代码，如果您是第一次执行C-x C-m，它会要求您更改默认命令（这通常就足够了），否则会执行您刚刚用于直接编译的命令，如果需要，您必须使用C-u C-x C-m来更改命令。如果当前目录中有Makefile，它会注意并提示您是否要使用它。

也许这个答案对你的问题太过分了，但请试一试。

如何让编译日志在Emacs中创建一个新窗口？

4 个答案: