Question

我已经开始创建一个包含默认电子邮件模板的Perl包。

MANIFEST看起来像：

SendMyEmail.pm
SendMyEmail/defualt_email.tt

目前我知道模块（和模板）的位置 - 但模块本身是否知道它在磁盘上的位置？那么模块可以在没有我帮助的情况下找到默认模板吗？

# This is what I would like to do.
package SendMyEmail;
sub new {
    my ($self, $template) = @_;
    $template ||= $dir_of_SendMyEmail .'/SendMyEmail/default_email.tt'; # ??
}

是否有更好的方法来包含模板文本或更好的放置模板的地方？

欢迎对CPAN模块进行类似操作的任何引用。

提前致谢。

Answer 1

每个perl文件都可以访问变量__FILE__，该变量告诉它完整路径。这样的事情可以解决问题：

my $DEFAULT_TEMPLATE;
BEGIN {
    $DEFAULT_TEMPLATE = __FILE__;
    $DEFAULT_TEMPLATE =~ s,\.pm$,/default_email.tt,;
}

尽管如此，如果您只想将“数据”文件与模块捆绑在一起，那么请查看File::ShareDir，它提供了一种方法。

Answer 2

在文件与包名称不完全匹配的情况下，使用％INC会产生误导。（这是一种反模式，但它确实会发生，有时是出于正当理由。）如果你想找到文件，方便的__FILE__令牌是你最好的选择。可以找到自己的示例模块：

package Foo::Bar;

use Cwd qw(abs_path);
use File::Basename qw(dirname);

sub module_dir { abs_path(dirname(__FILE__)) }

1;

用法：

use Foo::Bar;

print Foo::Bar->module_dir, "\n";

Answer 3

如果已加载模块，则可以使用%INC哈希。例如：

## load the module
use Data::Dumper;

## output full path to Data::Dumper module loaded
print $INC{'Data/Dumper.pm'};

## see which module was loaded (if you have multiple folders with same modules)
print Dumper(\%INC);

Answer 4

Perl也会在％INC变量中记录文件位置。当__FILE__不可用时，您可以使用它。有关详细信息，请参阅perlvar中的文档。

Answer 5

重写以反映我在评论中学到的内容：

查找模块的路径

package FooBar;

use File::Spec;
sub location  {
return File::Spec->rel2abs( __FILE__);
}

放置模板的位置：

由于模板很可能是可编辑的，甚至可能是网络上工作的人，我强烈建议将其放入模板中包含的“代码”无法执行的目录中。

想象一下有人打来电话：http://your.home.net/cgi-bin/default_email.tt

Answer 6

您可以使用__FILE__令牌获取当前文件的名称（包括路径）。如果您想知道另一个模块（已经加载的模块）的路径，请检查%INC哈希的内容。

Answer 7

我使用这个bash别名来查找模块的位置（例如，查看其实现或破解一些调试打印语句）：

perlwhere() {
    perl -wle'eval "require $ARGV[0]" or die; ($mod = $ARGV[0]) =~ s|::|/|g; print $INC{"${mod}.pm"}' $1
}

$ perlwhere Test::More
/usr/lib/perl5/5.8.8/Test/More.pm

Perl模块是否知道它的安装位置？

7 个答案: