我有一个列格式为a，b，c，d的列。有没有办法在T-SQL中计算该值中逗号的数量？
答案 0 :(得分：212)
首先想到的是通过用空字符串替换逗号并比较长度来间接地做到这一点
Declare @string varchar(1000)
Set @string = 'a,b,c,d'
select len(@string) - len(replace(@string, ',', ''))
答案 1 :(得分：62)
快速扩展cmsjr的答案，适用于多个角色的字符串。
CREATE FUNCTION dbo.CountOccurrencesOfString
(
@searchString nvarchar(max),
@searchTerm nvarchar(max)
)
RETURNS INT
AS
BEGIN
return (LEN(@searchString)-LEN(REPLACE(@searchString,@searchTerm,'')))/LEN(@searchTerm)
END
用法：
SELECT * FROM MyTable
where dbo.CountOccurrencesOfString(MyColumn, 'MyString') = 1
答案 2 :(得分：21)
您可以将字符串的长度与删除逗号的字符串进行比较：
len(value) - len(replace(value,',',''))
答案 3 :(得分：6)
@csmjr的回答在某些情况下有问题。
他的回答是：
Declare @string varchar(1000)
Set @string = 'a,b,c,d'
select len(@string) - len(replace(@string, ',', ''))
这适用于大多数情况，但请尝试运行：
DECLARE @string VARCHAR(1000)
SET @string = 'a,b,c,d ,'
SELECT LEN(@string) - LEN(REPLACE(@string, ',', ''))
由于某种原因，REPLACE摆脱了最后的逗号，但也是它之前的空间（不知道为什么）。当你期望4时，这会导致返回值为5.这是另一种方法，即使在这种特殊情况下也可以这样做：
DECLARE @string VARCHAR(1000)
SET @string = 'a,b,c,d ,'
SELECT LEN(REPLACE(@string, ',', '**')) - LEN(@string)
请注意，您不需要使用星号。任何两个字符的替换都可以。我们的想法是，对于您计算的每个字符实例，将字符串延长一个字符，然后减去原始字符的长度。它基本上是原始答案的相反方法，并没有带来奇怪的修剪副作用。
答案 4 :(得分：5)
在@ Andrew的解决方案的基础上，使用非过程表值函数和CROSS APPLY可以获得更好的性能：
SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER ON
GO
/* Usage:
SELECT t.[YourColumn], c.StringCount
FROM YourDatabase.dbo.YourTable t
CROSS APPLY dbo.CountOccurrencesOfString('your search string', t.[YourColumn]) c
*/
CREATE FUNCTION [dbo].[CountOccurrencesOfString]
(
@searchTerm nvarchar(max),
@searchString nvarchar(max)
)
RETURNS TABLE
AS
RETURN
SELECT (DATALENGTH(@searchString)-DATALENGTH(REPLACE(@searchString,@searchTerm,'')))/NULLIF(DATALENGTH(@searchTerm), 0) AS StringCount
答案 5 :(得分：2)
Declare @string varchar(1000)
DECLARE @SearchString varchar(100)
Set @string = 'as as df df as as as'
SET @SearchString = 'as'
select ((len(@string) - len(replace(@string, @SearchString, ''))) -(len(@string) -
len(replace(@string, @SearchString, ''))) % 2) / len(@SearchString)
答案 6 :(得分：1)
接受的答案是对的， 将其扩展为在子字符串中使用2个或更多字符：
Declare @string varchar(1000)
Set @string = 'aa,bb,cc,dd'
Set @substring = 'aa'
select (len(@string) - len(replace(@string, @substring, '')))/len(@substring)
答案 7 :(得分：1)
如果我们知道LEN和空间有限制，为什么我们不能先替换空间？ 那么我们知道没有空间来混淆LEN。
len(replace(@string, ' ', '-')) - len(replace(replace(@string, ' ', '-'), ',', ''))
答案 8 :(得分：0)
CHARINDEX()替换为PATINDEX()，您也可以在字符串中进行一些弱regex搜索...
比如说，你将它用于@pattern：
set @pattern='%[-.|!,'+char(9)+']%'
你为什么要这样做一些疯狂的事？
假设您正在将分隔的文本字符串加载到临时表中，其中包含数据的字段类似于varchar（8000）或nvarchar（max）...
有时使用数据而不是ETL（Extract-Transform-Load）更容易/更快地执行ELT（Extract-Load-Transform），并且一种方法是按原样加载分隔的记录进入临时表，特别是如果你可能想要一种更简单的方法来查看异常记录而不是将它们作为SSIS包的一部分处理......但这对于另一个线程来说是一场圣战。
答案 9 :(得分：0)
DECLARE @records varchar(400)
SELECT @records = 'a,b,c,d'
select LEN(@records) as 'Before removing Commas' , LEN(@records) - LEN(REPLACE(@records, ',', '')) 'After Removing Commans'
答案 10 :(得分：0)
以下内容应该可以解决单字符和多字符搜索问题：
CREATE FUNCTION dbo.CountOccurrences
(
@SearchString VARCHAR(1000),
@SearchFor VARCHAR(1000)
)
RETURNS TABLE
AS
RETURN (
SELECT COUNT(*) AS Occurrences
FROM (
SELECT ROW_NUMBER() OVER (ORDER BY O.object_id) AS n
FROM sys.objects AS O
) AS N
JOIN (
VALUES (@SearchString)
) AS S (SearchString)
ON
SUBSTRING(S.SearchString, N.n, LEN(@SearchFor)) = @SearchFor
);
GO
---------------------------------------------------------------------------------------
-- Test the function for single and multiple character searches
---------------------------------------------------------------------------------------
DECLARE @SearchForComma VARCHAR(10) = ',',
@SearchForCharacters VARCHAR(10) = 'de';
DECLARE @TestTable TABLE
(
TestData VARCHAR(30) NOT NULL
);
INSERT INTO @TestTable
(
TestData
)
VALUES
('a,b,c,de,de ,d e'),
('abc,de,hijk,,'),
(',,a,b,cde,,');
SELECT TT.TestData,
CO.Occurrences AS CommaOccurrences,
CO2.Occurrences AS CharacterOccurrences
FROM @TestTable AS TT
OUTER APPLY dbo.CountOccurrences(TT.TestData, @SearchForComma) AS CO
OUTER APPLY dbo.CountOccurrences(TT.TestData, @SearchForCharacters) AS CO2;
使用数字表（dbo.Nums）可以简化该功能：
RETURN (
SELECT COUNT(*) AS Occurrences
FROM dbo.Nums AS N
JOIN (
VALUES (@SearchString)
) AS S (SearchString)
ON
SUBSTRING(S.SearchString, N.n, LEN(@SearchFor)) = @SearchFor
);
答案 11 :(得分：0)
使用此代码，它可以正常工作。 我创建了一个接受两个参数的sql函数，第一个参数是我们要搜索的长字符串，它可以接受最多1500个字符的字符串长度（当然，您可以扩展它甚至将其更改为text数据类型）。 第二个参数是我们要计算其出现次数的子字符串（其长度最多为200个字符，当然您可以根据需要更改它）。并且输出是整数，代表频率的数目.....享受它。
CREATE FUNCTION [dbo].[GetSubstringCount]
(
@InputString nvarchar(1500),
@SubString NVARCHAR(200)
)
RETURNS int
AS
BEGIN
declare @K int , @StrLen int , @Count int , @SubStrLen int
set @SubStrLen = (select len(@SubString))
set @Count = 0
Set @k = 1
set @StrLen =(select len(@InputString))
While @K <= @StrLen
Begin
if ((select substring(@InputString, @K, @SubStrLen)) = @SubString)
begin
if ((select CHARINDEX(@SubString ,@InputString)) > 0)
begin
set @Count = @Count +1
end
end
Set @K=@k+1
end
return @Count
end
答案 12 :(得分：0)
我最终编写了该函数，该函数应涵盖所有可能的情况，并在输入中添加一个char前缀和后缀。此char被评估为与search参数中包含的任何char不同，因此不会影响结果。
CREATE FUNCTION [dbo].[CountOccurrency]
(
@Input nvarchar(max),
@Search nvarchar(max)
)
RETURNS int AS
BEGIN
declare @SearhLength as int = len('-' + @Search + '-') -2;
declare @conteinerIndex as int = 255;
declare @conteiner as char(1) = char(@conteinerIndex);
WHILE ((CHARINDEX(@conteiner, @Search)>0) and (@conteinerIndex>0))
BEGIN
set @conteinerIndex = @conteinerIndex-1;
set @conteiner = char(@conteinerIndex);
END;
set @Input = @conteiner + @Input + @conteiner
RETURN (len(@Input) - len(replace(@Input, @Search, ''))) / @SearhLength
END
用法
select dbo.CountOccurrency('a,b,c,d ,', ',')
答案 13 :(得分：0)
Declare @MainStr nvarchar(200)
Declare @SubStr nvarchar(10)
Set @MainStr = 'nikhildfdfdfuzxsznikhilweszxnikhil'
Set @SubStr = 'nikhil'
Select (Len(@MainStr) - Len(REPLACE(@MainStr,@SubStr,'')))/Len(@SubStr)
答案 14 :(得分：0)
在SQL 2017或更高版本中，您可以使用此：
declare @hits int = 0
set @hits = (select value from STRING_SPLIT('F609,4DFA,8499',','));
select count(@hits)
答案 15 :(得分：0)
此T-SQL代码查找并打印句子@s中所有出现的模式@p。您可以随后对句子进行任何处理。
declare @old_hit int = 0
declare @hit int = 0
declare @i int = 0
declare @s varchar(max)='alibcalirezaalivisualization'
declare @p varchar(max)='ali'
while @i<len(@s)
begin
set @hit=charindex(@p,@s,@i)
if @hit>@old_hit
begin
set @old_hit =@hit
set @i=@hit+1
print @hit
end
else
break
end
结果是： 1个 6 13 20
答案 16 :(得分：0)
对于SQL Server 2017
declare @hits int = 0;
set @hits = (select count(*) from (select value from STRING_SPLIT('F609,4DFA,8499',',')) a);
select @hits;
答案 17 :(得分：-1)
您可以使用以下存储过程来获取值。
IF EXISTS (SELECT * FROM sys.objects
WHERE object_id = OBJECT_ID(N'[dbo].[sp_parsedata]') AND type in (N'P', N'PC'))
DROP PROCEDURE [dbo].[sp_parsedata]
GO
create procedure sp_parsedata
(@cid integer,@st varchar(1000))
as
declare @coid integer
declare @c integer
declare @c1 integer
select @c1=len(@st) - len(replace(@st, ',', ''))
set @c=0
delete from table1 where complainid=@cid;
while (@c<=@c1)
begin
if (@c<@c1)
begin
select @coid=cast(replace(left(@st,CHARINDEX(',',@st,1)),',','') as integer)
select @st=SUBSTRING(@st,CHARINDEX(',',@st,1)+1,LEN(@st))
end
else
begin
select @coid=cast(@st as integer)
end
insert into table1(complainid,courtid) values(@cid,@coid)
set @c=@c+1
end
答案 18 :(得分：-1)
Replace / Len测试很可爱，但可能非常低效（特别是在内存方面）。 带循环的简单函数可以完成这项工作。
CREATE FUNCTION [dbo].[fn_Occurences]
(
@pattern varchar(255),
@expression varchar(max)
)
RETURNS int
AS
BEGIN
DECLARE @Result int = 0;
DECLARE @index BigInt = 0
DECLARE @patLen int = len(@pattern)
SET @index = CHARINDEX(@pattern, @expression, @index)
While @index > 0
BEGIN
SET @Result = @Result + 1;
SET @index = CHARINDEX(@pattern, @expression, @index + @patLen)
END
RETURN @Result
END
答案 19 :(得分：-3)
也许您不应该以这种方式存储数据。在字段中存储逗号分隔列表是一种不好的做法。查询的效率非常低。这应该是一张相关的表格。