Question

我正在使用flex中的inDesign扩展，我将对象编码为JSON，然后尝试从JSON字符串创建对象。

我使用JSOD.encode（）编码的类公共类ManualProductLink {

    private var _productID:String;
    private var _productName:String;
    private var _productDescription:String;
    private var _productPrice:String;

    public function ManualProductLink(productID:String, productName:String, productDescription:String, productPrice:String):void {
        this._productID = productID;
        this._productName = productName;
        this._productDescription = productDescription;
        this._productPrice = productPrice;
    }

    public function get productID():String
    {
        return _productID;
    }

    public function set productID(value:String):void
    {
        _productID = value;
    }

    public function get productName():String
    {
        return _productName;
    }

    public function set productName(value:String):void
    {
        _productName = value;
    }

    public function get productDescription():String
    {
        return _productDescription;
    }

    public function set productDescription(value:String):void
    {
        _productDescription = value;
    }

    public function get productPrice():String
    {
        return _productPrice;
    }

    public function set productPrice(value:String):void
    {
        _productPrice = value;
    }

}

这是我对对象进行编码的函数

        /**
     * Creates ManualProductLink, encodes to JSON and sends it to AsCppBridge
     */
    public function manualProductLink(productID:String, productName:String, productDescription:String, productPrice:String):void {
        var manualProductLinkl:ManualProductLink = new ManualProductLink(productID, productName, productDescription, productPrice);
        bridge.saveManualProductLink(JSON.encode(manualProductLinkl));
    }

生成的JSON字符串为：

{"productName":"testName","productDescription":"testDescription","productID":"testID","productPrice":"100.00"}

我的问题是解码字符串，我正在尝试这样的事情：

public function getManualProductLinkJSON():ManualProductLink {
        var jsonString:String = bridge.getManualProductLink() as String;
        var data:ManualProductLink = JSON.decode(jsonString) as ManualProductLink;

        var manualProductLink:ManualProductLink = new ManualProductLink(data.productID, data.productName, data.productDescription, data.productPrice);

        return manualProductLink;
    }

但是尝试从返回的对象中获取变量，如下所示：

var str:String = manualProductLink.productID;

对我不起作用。

我很感激帮助将JSON String解码为类似于原始对象的对象。

Answer 1

似乎我可以回答我自己的问题：

public function getManualProductLinkJSON():ManualProductLink {
    var jsonString:String = bridge.getManualProductLink() as String;
    var data:Object = JSON.decode(jsonString);

    var manualProductLink:ManualProductLink = new ManualProductLink(data.productID, data.productName, data.productDescription, data.productPrice);

    return manualProductLink;
}

我无法直接解码到编码对象，但通过解码到数据：对象可以重新创建原始对象。

as3corelib无法使用JSON.decode（）解码JSON字符串;

1 个答案: