Question

我正在尝试向不可靠的服务器实施请求。请求是一个很好的，但我的perl脚本不能100％成功完成。问题是服务器偶尔会死锁（我们试图找出原因）并且请求永远不会成功。由于服务器认为它是活动的，它会使套接字连接保持打开状态，因此LWP :: UserAgent的超时值对我们来说没有任何好处。对请求强制执行绝对超时的最佳方法是什么？

仅供参考，这不是DNS问题。死锁与大量同时访问Postgres数据库的更新有关。出于测试目的，我们基本上在服务器响应处理程序中放置了while（1）{}行。

目前，代码如下：

my $ua = LWP::UserAgent->new;
ua->timeout(5); $ua->cookie_jar({});

my $req = HTTP::Request->new(POST => "http://$host:$port/auth/login");
$req->content_type('application/x-www-form-urlencoded');
$req->content("login[user]=$username&login[password]=$password");

# This line never returns 
$res = $ua->request($req);

我尝试使用信号来触发超时，但这似乎不起作用。

eval {
    local $SIG{ALRM} = sub { die "alarm\n" };
    alarm(1);
    $res = $ua->request($req);
    alarm(0);
};
# This never runs
print "here\n";

我将要使用的最终答案是有人离线提出的，但我会在这里提到它。出于某种原因，SigAction有效，而$ SIG（ALRM）却没有。仍然不确定为什么，但这已经过测试可行。这是两个工作版本：

# Takes a LWP::UserAgent, and a HTTP::Request, returns a HTTP::Request
sub ua_request_with_timeout {
    my $ua = $_[0];
    my $req = $_[1];
    # Get whatever timeout is set for LWP and use that to 
    #  enforce a maximum timeout per request in case of server
    #  deadlock. (This has happened.)
    use Sys::SigAction qw( timeout_call );
    our $res = undef;
    if( timeout_call( 5, sub {$res = $ua->request($req);}) ) {
        return HTTP::Response->new( 408 ); #408 is the HTTP timeout
    } else {
        return $res;
    }
}
sub ua_request_with_timeout2 {
    print "ua_request_with_timeout\n";
    my $ua = $_[0];
    my $req = $_[1];
    # Get whatever timeout is set for LWP and use that to 
    #  enforce a maximum timeout per request in case of server
    #  deadlock. (This has happened.)
    my $timeout_for_client = $ua->timeout() - 2;
    our $socket_has_timedout = 0;

    use POSIX;
    sigaction SIGALRM, new POSIX::SigAction(
                                            sub {
                                                $socket_has_timedout = 1;
                                                die "alarm timeout";
                                            }
                                            ) or die "Error setting SIGALRM handler: $!\n";
    my $res = undef;
    eval {
        alarm ($timeout_for_client);
        $res = $ua->request($req);
        alarm(0);
    };
    if ( $socket_has_timedout ) {
        return HTTP::Response->new( 408 ); #408 is the HTTP timeout
    } else {
        return $res;
    }
}

Answer 1

您可以尝试LWPx::ParanoidAgent，LWP :: UserAgent的子类，它对如何与远程Web服务器进行交互时更加谨慎。

除此之外，它还允许您指定全局超时。它由Brad Fitzpatrick开发，作为LiveJournal项目的一部分。

Answer 2

您可以像这样制作自己的超时：

use LWP::UserAgent;
use IO::Pipe;

my $agent = new LWP::UserAgent;

my $finished = 0;
my $timeout = 5;

$SIG{CHLD} = sub { wait, $finished = 1 };

my $pipe = new IO::Pipe;
my $pid = fork;

if($pid == 0) {
    $pipe->writer;
    my $response = $agent->get("http://stackoverflow.com/");
    $pipe->print($response->content);
    exit;
}

$pipe->reader;

sleep($timeout);

if($finished) {
    print "Finished!\n";
    my $content = join('', $pipe->getlines);
}   
else {
    kill(9, $pid);
    print "Timed out.\n";
}

Answer 3

据我所知，timeout属性没有考虑DNS超时。您可以单独进行DNS查找，然后在服务器上发出请求，并为useragent设置正确的超时值。

这是服务器的DNS问题还是别的什么？

编辑：IO :: Socket也可能存在问题。尝试更新您的IO :: Socket模块，看看是否有帮助。我很确定那里存在阻止LWP :: UserAgent超时工作的错误。

亚历

Answer 4

以下对其中一个原始答案的概括还会将警报信号处理程序恢复到上一个处理程序，并在eval时钟中的调用引发非警报异常并且我们要取消时添加对警报（0）的第二次调用闹钟。可以添加$ @检查和处理：

sub ua_request_with_timeout {
    my $ua = $_[0];
    my $request = $_[1];

    # Get whatever timeout is set for LWP and use that to 
    #  enforce a maximum timeout per request in case of server
    #  deadlock. (This has happened.)`enter code here`
    my $timeout_for_client_sec = $ua->timeout();
    our $res_has_timedout = 0; 

    use POSIX ':signal_h';

    my $newaction = POSIX::SigAction->new(
        sub { $res_has_timedout = 1; die "web request timeout"; },# the handler code ref
        POSIX::SigSet->new(SIGALRM),
        # not using (perl 5.8.2 and later) 'safe' switch or sa_flags
    );  

    my $oldaction = POSIX::SigAction->new();
    if(!sigaction(SIGALRM, $newaction, $oldaction)) {
        log('warn',"Error setting SIGALRM handler: $!");
        return $ua->request($request);
    }   

    my $response = undef;
    eval {
        alarm ($timeout_for_client_sec);
        $response = $ua->request($request);
        alarm(0);
    }; 

    alarm(0);# cancel alarm (if eval failed because of non alarm cause)
    if(!sigaction(SIGALRM, $oldaction )) {
        log('warn', "Error resetting SIGALRM handler: $!");
    }; 

    if ( $res_has_timedout ) {
        log('warn', "Timeout($timeout_for_client_sec sec) while waiting for a response from cred central");
        return HTTP::Response->new(408); #408 is the HTTP timeout
    } else {
        return $response;
     }
}

LWP :: UserAgent请求方法的真正超时

4 个答案: