Question

在Visual Studio 2005-2015中，可以找到包含某些引用的所有行，并在“查找结果”窗口中显示它们。

既然显示了这些结果行，是否有任何键盘快捷键可以向所有这些行添加调试断点？

Answer 1

此答案不适用于Visual Studio 2015或更高版本。可以找到更新的答案here。

使用Visual Studio宏可以相当轻松地完成此操作。在Visual Studio中，按Alt-F11打开宏IDE并通过右键单击MyMacros并选择添加|添加模块...添加新模块...

将以下内容粘贴到源编辑器中：

Imports System
Imports System.IO
Imports System.Text.RegularExpressions
Imports EnvDTE
Imports EnvDTE80
Imports EnvDTE90
Imports System.Diagnostics

Public Module CustomMacros
    Sub BreakpointFindResults()
        Dim findResultsWindow As Window = DTE.Windows.Item(Constants.vsWindowKindFindResults1)

        Dim selection As TextSelection
        selection = findResultsWindow.Selection
        selection.SelectAll()

        Dim findResultsReader As New StringReader(selection.Text)
        Dim findResult As String = findResultsReader.ReadLine()

        Dim findResultRegex As New Regex("(?<Path>.*?)\((?<LineNumber>\d+)\):")

        While Not findResult Is Nothing
            Dim findResultMatch As Match = findResultRegex.Match(findResult)

            If findResultMatch.Success Then
                Dim path As String = findResultMatch.Groups.Item("Path").Value
                Dim lineNumber As Integer = Integer.Parse(findResultMatch.Groups.Item("LineNumber").Value)

                Try
                    DTE.Debugger.Breakpoints.Add("", path, lineNumber)
                Catch ex As Exception
                    ' breakpoints can't be added everywhere
                End Try
            End If

            findResult = findResultsReader.ReadLine()
        End While
    End Sub
End Module

此示例使用“查找结果1”窗口中的结果;您可能希望为每个结果窗口创建单独的快捷方式。

您可以转到工具|选项...并选择左侧导航中环境部分下的键盘来创建键盘快捷键。选择您的宏并指定您喜欢的任何快捷方式。

您还可以通过转到“工具”|“自定义...”并选择左侧导航中的宏部分，将宏添加到菜单或工具栏中。在列表中找到宏后，您可以将其拖动到任何菜单或工具栏，在其中可以将文本或图标自定义为您想要的任何内容。

Answer 2

如果您可以准确搜索单词，可以使用一对键盘快捷键快速完成。

工具 - ＆gt;选项 - ＆gt;环境 - ＆gt;键盘

Edit.GoToFindResults1NextLocation
EditorContextMenus.CodeWindow.Breakpoint.InsertBreakpoint

将它们分配给Control + Alt + F11和F10，您可以非常快速地完成所有结果。我没有找到进入下一个引用的快捷方式。

Answer 3

我需要类似的东西来禁用所有断点并在每个“Catch ex as Exception”上放置一个断点。但是，我对此进行了一些扩展，因此它会在您选择的字符串的每个出现处都放置一个断点。所有你需要做的就是突出显示你想要断点的字符串并运行宏。

 Sub BreakPointAtString()

    Try
        DTE.ExecuteCommand("Debug.DisableAllBreakpoints")
    Catch ex As Exception

    End Try

    Dim tsSelection As String = DTE.ActiveDocument.Selection.text
    DTE.ActiveDocument.Selection.selectall()
    Dim AllText As String = DTE.ActiveDocument.Selection.Text

    Dim findResultsReader As New StringReader(AllText)
    Dim findResult As String = findResultsReader.ReadLine()
    Dim lineNum As Integer = 1

    Do Until findResultsReader.Peek = -1
        lineNum += 1
        findResult = findResultsReader.ReadLine()
        If Trim(findResult) = Trim(tsSelection) Then
            DTE.ActiveDocument.Selection.GotoLine(lineNum)
            DTE.ExecuteCommand("Debug.ToggleBreakpoint")
        End If
    Loop

End Sub

希望它适合你：）

Answer 4

保罗，非常感谢，但我有以下错误（消息框），可能需要重启我的电脑：

Error
---------------------------
Error HRESULT E_FAIL has been returned from a call to a COM component.
---------------------------
OK   
---------------------------

我建议以下解决方案非常简单，但对我有用

Sub BreakPointsFromSearch()
    Dim n As Integer = InputBox("Enter the number of search results")

    For i = 1 To n
        DTE.ExecuteCommand("Edit.GoToNextLocation")
        DTE.ExecuteCommand("Debug.ToggleBreakpoint")            
    Next
End Sub

如何将调试断点添加到Visual Studio的“查找结果”窗口中显示的行

4 个答案: