Question

我可以使用syscall进行写入将内存中的一些数据打印到STDOUT：

ssize_t write(int fd, const void *buf, size_t count);

那是：

movq    $1, %rax
movq    $1, %rdi
move address_of_variable %rsi
movq    $5, %rdx
syscall

但是如何打印寄存器值？

更新

.text
        call start
    start:
        movq $100, %rdi
        movq $10, %rsi
        call print_number
        ret

    buffer:
        .skip 64
    bufferend:
    # rdi = number
    # rsi = base
    print_number:
        leaq bufferend, %rcx
        movq %rdi, %rax
    1:
        xorq %rdx, %rdx
        divq %rsi

        add $'0', %dl
        cmp $'9', %dl
        jbe 2f
        add $'A'-'0'-10, %dl

    2:
        sub $1, %rcx
        mov %dl, (%rcx)

        and %rax, %rax
        jnz 1b

        mov %rcx, %rsi
        lea bufferend, %rdx
        sub %rcx, %rdx

        movq    $1, %rax
        movq    $1, %rdi
        syscall
        ret

Answer 1

您必须先将其转换为文字。你可以走简单的路线并使用例如来自libc的printf，或者如果您愿意，可以编写自己的转换实用程序。

更新：如果您希望代码与位置无关，则更容易使用堆栈。简单地将缓冲区移动到代码段中，因为您在注释中链接的代码不再起作用，因为现代处理器将代码段设置为只读。我已更新代码以使用堆栈进行临时存储。

    .text

    call start
start:
    movq    $186, %rax # sys_gettid
    syscall

    movq %rax, %rdi
    movq $10, %rsi
    call print_number

    #ret
    mov $60, %rax # sys_exit
    mov $0, %rdi
    syscall

# rdi = number
# rsi = base
print_number:
    sub $72, %rsp # alloc room for buffer on the stack, 8 more than needed

    lea 64(%rsp), %rcx # 64(%rsp) == buffer end
    movq %rdi, %rax # rax holds current number 
1:
    xorq %rdx, %rdx # clear rdx (div uses the 128-bit number in rdx:rax)
    divq %rsi # divide by base, updating rax for the next iteration 
              # and giving us our digit in rdx (dl)
    add $'0', %dl # turn into printable character
    cmp $'9', %dl # handle digits > 10
    jbe 2f
    add $'A'-'0'-10, %dl # adjust number so A=10, B=11 ...

2:
    sub $1, %rcx # subtract before adding character as we start from the end
    mov %dl, (%rcx) # store character in string

    and %rax, %rax # rax == 0?
    jnz 1b # if not, then keep working

    mov %rcx, %rsi # buf = address of last character stored
    lea 64(%rsp), %rdx # calculate length by subtracting buffer end
    sub %rcx, %rdx # from the buffer start

    movq $1, %rax # sys_write
    movq $1, %rdi # fd = STDOUT_FILENO
    syscall

    add $72, %rsp # adjust stack back
    ret

如果您反而希望将缓冲区实际存储在代码段中，则可以完成。您必须使用例如buffer将mprotect(2)所在的页面标记为可写sysconf(_SC_PAGE_SIZE) == 4096。这里没有在汇编中进行错误检查（并假设为mov $10, %rax # sys_mprotect lea buffer, %rdi # addr and $-4096, %rdi # page align mov $4096, %rsi # len mov $7, %rdx #prot = PROT_READ|PROT_WRITE|PROT_EXEC syscall）：

gcc x.s -nostdlib -ggdb -o x

现在，即使缓冲区位于代码段中，代码仍应正常工作。顺便说一下，我在我的例子中使用了sys_exit，因为我正在使用bufferend将其作为独立文件进行测试。

Update2：要在重定位代码时使用它，请使用RIP相对寻址。将bufferend(%rip)更改为{{1}}。

Answer 2

你不能编写纯数字（因为它们将被解释为指针），你需要将该数字转换为字符串并将指针作为write的arg传递给该字符串。类似this的内容。

如何在程序集中将RAX中的值写入STDOUT？

2 个答案: