Question

我相信你通常会按值对哈希进行排序：

foreach my $key (sort { $hash{$a} <=> $hash{$b} } (keys %hash) ) {
    print "$key=>$hash{$key}";
}

这将打印出从最小到最大的值。

现在，如果我有这样的哈希怎么办：

$hash{$somekey}{$somekey2}{$thirdkey}

我如何按值排序并获取所有键？

Answer 1

我只想创建一个新哈希：

my %new;
for my $k1 (keys %hash) {
  for my $k2 (keys %{$hash{$k1}}) {
    for my $k3 (keys %{$hash{$k1}{$k2}}) {
      $new{$k1,$k2,$k3} = $hash{$k1}{$k2}{$k3};
    }
  }
}

my @ordered = sort { $new{$a} <=> $new{$b} } keys %new;
for my $k (@ordered) {
  my @keys = split($;, $k);
  print "key: @k      - value: $new{$k}\n";
}

Answer 2

以下是使用Deep::Hash::Utils进行此操作的方法。

use Deep::Hash::Utils qw(slurp);

my %h = (
    A => {
        Aa => { Aaa => 4, Aab => 5 },
        Ab => { Aba => 1 },
        Ac => { Aca => 2, Acb => 9, Acc => 0 },
    },
    B => {
        Ba => { Baa => 44, Bab => -55 },
        Bc => { Bca => 22, Bcb => 99, Bcc => 100 },
    },
);

my @all_keys_and_vals = slurp \%h;
print "@$_\n" for sort { $a->[-1] <=> $b->[-1] } @all_keys_and_vals;

输出：

B Ba Bab -55
A Ac Acc 0
A Ab Aba 1
A Ac Aca 2
A Aa Aaa 4
A Aa Aab 5
A Ac Acb 9
B Bc Bca 22
B Ba Baa 44
B Bc Bcb 99
B Bc Bcc 100

Answer 3

我已经通过将引用向下移动到相应的哈希键来完成类似的操作。然后，您可以对指针执行排序。

这样做的好处是，如果等级改变，很容易调整。

我使用此方法是通过引用一组键系统地将指针移动到特定级别。（例如：我的@Keys =（'价值'，'价值2'）;）

我相信以下示例的衍生产品可能会为您提供所需内容。

my $list_ref;
my $pointer;

my %list = (
   Value => {
      Value2 => {
         A => '1',
         C => '3',
         B => '2',
      },
   },
);

$list_ref = \%list;
$pointer = $list_ref->{Value}->{Value2};

foreach my $key (sort { $pointer->{$a} <=> $pointer->{$b} } (keys %{$pointer})) {
   print "Key: $key\n";
}

Answer 4

出于学术目的，这是一个相当整洁的递归函数：

sub flatten_hash {
  my ($hash, $path) = @_;
  $path = [] unless defined $path;

  my @ret;

  while (my ($key, $value) = each %$hash) {
    if (ref $value eq 'HASH') {
      push @ret, flatten_hash($value, [ @$path, $key ]);
    } else {
      push @ret, [ [ @$path, $key ], $value ];
    }
  }

  return @ret;
}

采用类似

的哈希

{
    roman => {
        i => 1,
        ii => 2,
        iii => 3,
    },
    english => {
        one => 1,
        two => 2,
        three => 3,
    },
}

并将其转换为类似

的列表

(
    [ ['roman','i'], 1 ],
    [ ['roman', 'ii'], 2 ],
    [ ['roman', 'iii'], 3 ],
    [ ['english', 'one'], 1 ],
    [ ['english', 'two'], 2 ],
    [ ['english', 'three'], 3 ]
)

虽然订单当然会有所不同。根据该列表，您可以在{ $a->[1] <=> $b->[1] }或类似列表上对其进行排序，然后从@{ $entry->[0] }中为每个条目提取密钥路径。无论数据结构的深度如何，它都可以工作，即使叶节点不是全部都在同一深度。但它需要一点点扩展来处理不仅仅是hashrefs和plain scalars的结构。

当有多个键时，按值对哈希进行排序

4 个答案: