Question

我想使用XSLT从XML创建ASP.NET用户控件。目前我真的把结果一点一点地放在一起：

<xsl:template match="TextField">
   <xsl:apply-templates select="Label" />
   <xsl:text><![CDATA[<asp:TextBox ID="]]></xsl:text>
   <xsl:value-of select="@id"/>
   <xsl:if test="@defaultValue">
      <xsl:text><![CDATA[" value="]]></xsl:text>
      <xsl:value-of select="@defaultValue"/>
   </xsl:if>
   <xsl:text><![CDATA[" runat="server"></asp:TextBox>]]></xsl:text>
   <xsl:copy-of select="$br"/>
</xsl:template>

如果我能做出类似的事情，那将会很酷：

<xsl:template match="TextField">
   <xsl:apply-templates select="Label" />

   <xsl:variable name="localTemplate" select="expression">
      <xsl:text><![CDATA[
         <asp:TextBox ID="{theID}" value="{theDefaultValue}" runat="server"></asp:TextBox>
      ]]></xsl:text>
      <xsl:copy-of select="$br"/>
   </xsl:variable>

   <!-- replace {theID} and {theDefaultValue} from the corresponding
       values of the input XML and then return the content of that
       variable
   -->
</xsl:template>

因为当需要更改html结构时，这看起来更清晰，更容易维护。

有没有办法实现这一目标，如果是，那会是什么样子？我不需要一个有效的解决方案，只需要提供一些提示即可。

更新：以下是一些示例输入XML：

<?xml version="1.0" encoding="utf-8" ?>
<Form xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"
   xsi:noNamespaceSchemaLocation="XmlForm.xsd">

   <Validation enabled="false" enableValidationSummary="true" />
   <FieldSet>
      <TextField id="firstInput" css-class="textfield-css-class" />

      <TextField id="secondInput" defaultValue="Wrdlbmrpft">
         <Label translatable="true" >Label Text</Label>
      </TextField>
   </FieldSet>
</Form>

输出应如下所示：

<%@ Control Language="C#" AutoEventWireup="true" Inherits="DevelopmentWeb.WebUserControl1" %>
<asp:TextBox runat="server" ID="firstInput" CssClass="textfield-css-class"></asp:TextBox>
<asp:Label runat="server" AssociatedControlID="secondInput">Label Text</asp:Label>
<asp:TextBox runat="server" ID="secondInput">Wrdlbrmpft</asp:TextBox>

Answer 1

我认为没有任何理由来创建变量。你应该可以这样做：

  <xsl:template match="TextField">
    <xsl:apply-templates select="Label" />
    <asp:TextBox ID="{@id}" value="{@defaultValue}" runat="server"/>    
    <xsl:copy-of select="$br"/>
  </xsl:template>

或者这个：

  <xsl:template match="TextField">
    <xsl:apply-templates select="Label" />
    <asp:TextBox runat="server">
      <xsl:if test="@id">
        <xsl:attribute name="ID">
          <xsl:value-of select="@id"/>
        </xsl:attribute>
      </xsl:if>    
      <xsl:if test="@defaultValue">
        <xsl:attribute name="value">
          <xsl:value-of select="@defaultValue"/>
        </xsl:attribute>
      </xsl:if>
    </asp:TextBox>
    <xsl:copy-of select="$br"/>
  </xsl:template>

Answer 2

为前缀asp定义适当的命名空间，例如：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:asp="System.Web.UI.WebControls">

在你的模板中写下：

<asp:TextBox ID="{@id}" runat="server">
    <xsl:if test="@defaultValue">
        <xsl:attribute name="value">
            <xsl:value-of select="@defaultValue"/>
        </xsl:attribute>
    </xsl:if>
</asp:TextBox>

我可以在XSLT中创建模板吗？

2 个答案: