Question

我正在使用XSLT将一些配置XML转换为SOAP请求。但是我很难找到一种不需要完整XPATH表达式并且仍然生成有效SOAP XML的方法。

以下是配置XML的简化版本。

<CreateOrder>
    <client_info>
        <name>John Doe</name>
        <address>
            <street1>1211 Lakeview Dr.</street1>
            <city>New York</city>
            <state>NY</state>
            <country>USA</country>
            <zip>12345</zip>
        </address>
    </client_info>
    <subscriber_number>AAANNNDDDD</subscriber_number>
</CreateOrder>

这是我正在使用的简化XSLT。

<?xml version="1.0" encoding="ISO-8859-1"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
    <xsl:output method="xml" />
    <xsl:template match="/">
        <soapenv:Envelope xmlns:soapenv="http://schemas.xmlsoap.org/soap/envelope/">
            <soapenv:Header/>
            <soapenv:Body>
                <DirectoryNumber><xsl:value-of select="CreateOrder/subscriber_number"/></DirectoryNumber>
                <Locale>
                    <xsl:choose>
                        <xsl:when test="CreateOrder/client_info/address/country = 'USA'">
                            <xsl:text>English (US)</xsl:text>
                        </xsl:when>
                        <xsl:otherwise>
                            <xsl:text>User Defined 1</xsl:text>
                        </xsl:otherwise>
                    </xsl:choose>
                </Locale>
            </soapenv:Body>
        </soapenv:Envelope>
    </xsl:template>
</xsl:stylesheet>

这将生成以下XML输出 - 这是我期望/想要的。 [请注意，我必须将其打印出来 - 我的输出实际上只是一行而没有换行/缩进。]

<?xml version="1.0" encoding="UTF-8"?>
<soapenv:Envelope xmlns:soapenv="http://schemas.xmlsoap.org/soap/envelope/">
    <soapenv:Header/>
    <soapenv:Body>
        <DirectoryNumber>
            AAANNNDDDD
        </DirectoryNumber>
        <Locale>
            English (US)
        </Locale>
    </soapenv:Body>
</soapenv:Envelope>

通过游戏，似乎我需要使用<xsl:template match="/">来匹配整个输入文档，否则我不会将SOAP XML输入到输出中。是否有其他方法可以从XSLT生成一系列新XML？

但是当<xsl:template match="/">存在时，我无法嵌套其他<xsl:template match=...">元素（例如匹配“地址”），因此必须使用完整的XPATH节点表达式（例如{{1在测试中。这可行，但不是特别优雅，并且对于现实世界更长的例子而言有些容易出错。有没有更好的方法呢？

Answer 1

模板不嵌套。您可以在模板中的适当位置使用<xsl:apply-templates.../>获得所需内容。在您的简单示例中，无需指定路径，但在更大，更复杂的样式表中，您可以拥有许多可重用的模板。

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">

  <xsl:output method="xml" indent="yes"/>
  <xsl:template match="/">
    <soapenv:Envelope xmlns:soapenv="http://schemas.xmlsoap.org/soap/envelope/">
      <soapenv:Header/>
      <soapenv:Body>
        <DirectoryNumber><xsl:value-of select="CreateOrder/subscriber_number"/></DirectoryNumber>
        <Locale>
          <xsl:apply-templates select="CreateOrder/client_info/address/country"/>
        </Locale>
      </soapenv:Body>
    </soapenv:Envelope>
  </xsl:template>

  <xsl:template match="country">
    <xsl:choose>
      <xsl:when test=". = 'USA'">
        <xsl:text>English (US)</xsl:text>
      </xsl:when>
      <xsl:otherwise>
        <xsl:text>User Defined 1</xsl:text>
      </xsl:otherwise>
    </xsl:choose>
  </xsl:template>

</xsl:stylesheet>

理解XSLT的关键是要意识到它不是程序性的......你的样式表不受控制。相反，XSLT处理器正在检查每个输入标记，然后在样式表中搜索匹配的模板。找到并应用匹配规则后，即可完成对该标记的处理。如果匹配/，则整个文档将被该模板使用。可以调用其他模板的唯一方法是通过<xsl:apply-templates select="some xpath"/>，它告诉处理器使用“some xpath”选择的节点重新启动匹配过程。样式表中的第一个模板与/匹配非常常见。

使用XSLT生成SOAP XML的问题

1 个答案: