Question

我有2个文件

的catalog.xml

<?xml version="1.0" encoding="UTF-8"?>
<catalog>
    <CD Title="Still got the blues" vinyl="unknown"/>
    <CD Title="When a man loves a woman" vinyl="unknown"/>
</catalog>

vinyl.xml

<?xml version="1.0" encoding="UTF-8"?>
<Vinyl>
    <Album>
        <Title>When a man loves a woman</Title>
        <Vinyl>Yes</Vinyl>
    </Album>
</Vinyl>

如何用xslt生成这样的output.xml？

<?xml version="1.0" encoding="UTF-8"?>
<catalog>
    <CD Title="Still got the blues" vinyl="unknown"/>
    <CD Title="When a man loves a woman" vinyl="yes"/>***   
</catalog>

***标记此行，因为它在output.xml中已更改

Answer 1

以下转换使用 catalog.xml 作为输入，并使用document()加载 vinyl.xml 。它只是通过一个简单的测试来执行合并。

[XSLT 1.0]

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output indent="yes"/>
    <xsl:variable name="vinyl" select="document('test_i2.xml')"/>

    <xsl:template match="node()|@*">
        <xsl:copy>
            <xsl:apply-templates select="node()|@*"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="@vinyl">
        <xsl:attribute name="vinyl">
            <xsl:variable name="test" select="
                 $vinyl/Vinyl/Album[Title=current()/../@Title]/Vinyl"/>
            <xsl:choose>
                <xsl:when test="$test">
                    <xsl:value-of select="$test"/>
                </xsl:when>
                <xsl:otherwise>
                    <xsl:value-of select="."/>
                </xsl:otherwise>
            </xsl:choose>
        </xsl:attribute>
    </xsl:template>

</xsl:stylesheet>

该属性的模板不那么直接，但它利用了纯XPath：

<xsl:template match="@vinyl">
    <xsl:attribute name="vinyl">
        <xsl:value-of select="
          $vinyl/Vinyl/Album[Title=current()/../@Title]/Vinyl
          |
          self::node()[count($vinyl/Vinyl/Album[Title=current()/../@Title])=0]"/>
    </xsl:attribute>
</xsl:template>

如果XML元素中存在另一个XML，那么XSLT用于替换属性？

1 个答案: