Question

我正在使用Barcode Studio 2011将QR码绘制到Graphics32 - TImage32组件中，我希望将其保存为png格式，但白色为透明，这是我在Graphics32的OuterColor中指定的。

OnFormCreate我刚刚

procedure TForm1.FormCreate(Sender: TObject);
begin
  psBarcodeComponent1.BarCode := 'some text here...';
end;

目前我已将绘画分配给按钮点击事件

procedure TForm1.Button8Click(Sender: TObject); // Paint the barcode
var
  bmp: TBitmap32;
  Coords: TRect;
begin
 bmp := TBitmap32.Create;
 bmp.SetSize(image.Width, image.Height);
 bmp.Canvas.Brush.Color := color;
 bmp.Canvas.Rectangle(-1, -1, image.Width+2, image.Height+2);

 bmp.DrawMode := dmTransparent;
 bmp.OuterColor := clWhite;

 // make Coords the size of image
 Coords := Rect(0,0,image.Width,image.Height);
 psBarcodeComponent1.PaintBarCode(bmp.Canvas, Coords);
 image.Bitmap.Assign(bmp);
end;

我正在使用Vampyre成像库将Bitmap转换为PNG格式，但我很乐意使用任何库，功能和建议 - 我一直试图这样做近一个星期！我已阅读并重新阅读了graphics32以及Vampyre Imaging Library的文档，但我尝试的任何内容都不会将白色转换为透明色。我已经尝试过clWhite，clWhite32并且还将drawMode设置为dmBlend并且应用ChromaKey功能都无济于事但是很多挫折，咖啡和一点啤酒也是如此;）

这就是我如何保存它......

procedure TForm1.Button7Click(Sender: TObject); // Save with Vampyre Imaging Lib
{ Try to save in PNG format with transparancy }
var
  FImage: TSingleImage;
begin
  FImage := TSingleImage.Create;
  ConvertBitmap32ToImage(image.Bitmap, FImage);
  FImage.SaveToFile('VampyreLibIMG.png');
end;

这会产生黑色缩略图，在Windows照片查看器中查看时，它完全透明。

我希望我提供了足够的信息，并且有人能够帮助我。

克里斯

Answer 1

这种方法对我有用：

uses GR32, GR32_PNG, GR32_PortableNetworkGraphic;

var
  Y: Integer;
  X: Integer;
  Png: TPortableNetworkGraphic32;

  function IsWhite(Color32: TColor32): Boolean;
  begin
    Result:= (TColor32Entry(Color32).B = 255) and
             (TColor32Entry(Color32).G = 255) and
             (TColor32Entry(Color32).R = 255);
  end;

begin
  with Image321 do
  begin
    Bitmap.ResetAlpha;
    for Y := 0 to Bitmap.Height-1 do
      for X := 0 to Bitmap.Width-1 do
      begin
        if IsWhite(Bitmap.Pixel[X, Y]) then
          Bitmap.Pixel[X,Y]:=Color32(255,255,255,0);
      end;
    Png:= TPortableNetworkGraphic32.Create;
    Png.Assign(Bitmap);
    Png.SaveToFile('C:\Temp\NowTransparent.png');
    Png.Free;
  end;
end;

这使用GR32 PNG library。这是一种非常直接的方式，将所有白色像素设置为透明。

PS：Image321是TImage32组件，包含我的TBitmap32。

Answer 2

你没有指定Delphi版本，但是如果你的delphi版本有“PngImage”（我相信它附带D2009 +），代码下面的工作完美（在Gimp和Windows Photo Viewer中加载，它绘制了一个框架和一些文本透明背景，随意玩它：

uses
  PngImage;

procedure TForm1.OnBtnClick(Sender: TObject);
var
  bmp: TBitmap;
  png: TPngImage;
begin
  bmp := TBitmap.Create;
  bmp.Width := 200;
  bmp.Height := 200;

  bmp.Canvas.Brush.Color := clBlack;
  bmp.Canvas.Rectangle( 20, 20, 160, 160 );

  bmp.Canvas.Brush.Style := bsClear;
  bmp.Canvas.Rectangle(1, 1, 199, 199);

  bmp.Canvas.Brush.Color := clWhite;
  bmp.Canvas.Pen.Color := clRed;
  bmp.Canvas.TextOut( 35, 20, 'Hello transparent world');

  bmp.TransparentColor := clWhite;
  bmp.Transparent := True;

  png := TPngImage.Create;
  png.Assign( bmp );
  png.SaveToFile( 'C:\test.png' );

  bmp.Free;
  png.Free;
end;

如何保存透明度的png文件？

2 个答案: