Question

我是动作脚本3.0的新手。帮助我了解如何使用URLLoader加载数据。

所以，我的答案如下：

var PATH:String = "http://www.somesite.com/myFirstPage.php?a=10&b=20";


var urlRequest:URLRequest = new URLRequest(PATH);
var urlLoader:URLLoader = new URLLoader();
urlLoader.dataFormat = URLLoaderDataFormat.TEXT;
urlLoader.addEventListener(Event.COMPLETE, urlLoader_complete);
urlLoader.load(urlRequest);

function urlLoader_complete(evt:Event):void {
    some_result = urlLoader.data;
}

php脚本看起来像：

<?php
//retrieve GET params

int c = a + b; //a and b come from GET request

return "{{"result_equal":"20"}}"; //result in JSON

?>

我真的不明白.php页面的JSON结果是如何进入我的URLLoader对象的。请通过简单的例子帮助我。感谢名单！

Answer 1

您需要使用此项目：https://github.com/mikechambers/as3corelib

使用示例：

<mx:Script>
    <![CDATA[
        import mx.collections.ArrayCollection;
        import mx.rpc.events.ResultEvent;
        import com.adobe.serialization.json.JSON;

        private function onJSONLoad(event:ResultEvent):void
        {
            var rawData:String = String(event.result);
            var arr:Array = (JSON.decode(rawData) as Array);

            var dp:ArrayCollection = new ArrayCollection(arr);

            grid.dataProvider = dp;
        }
    ]]>
</mx:Script>

<mx:HTTPService
    id="service"
    resultFormat="text"
    url="http://weblogs.macromedia.com/mesh/mashedpotato.json"
    result="onJSONLoad(event)" />

Answer 2

这里你需要一些东西。首先，你需要一个JSON库，因为它不是内置在Flash中，即使使用它们修改过的E4X核心：

https://github.com/mikechambers/as3corelib

这应该为您提供以下代码：

import com.adobe.serialization.json.JSON;

function urlLoader_complete(e:Event):void 
{
   var loader:URLLoader = URLLoader(e.target);
   var some_result:Object = JSON.decode(loader.data);
}

现在......你的PHP代码很乱。创建JSON的最佳方法是使用json_encode函数：

$retVal = array('result_equal'=>20);
echo json_encode($retVal);

Answer 3

PHP代码应如下所示：

$result = array("result_equal" => 20);
return json_encode($result);

Answer 4

所以，这就是我得到的：请说，什么是错的，什么好！ Thanx1

package  
{
    import data.*;
    import flash.errors.IOError;
    import flash.events.Event;
    import flash.events.*;
    import flash.net.*;

    public class UserInfoProxy 
    {
        public static const GET_USER_INFO:DataCallConfigVO = new DataCallConfigVO( "COMMON", 'GET_USER_INFO', true, null, null);

        public function UserInfoProxy() 
        {               
            trace("Start request");
            var request:URLRequest = new URLRequest("http://www.avrora.com.localhost/myservlet.php");
            var loader:URLLoader = new URLLoader();

            loader.addEventListener(Event.COMPLETE, completeHandler);
            loader.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            loader.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            loader.addEventListener(HTTPStatusEvent.HTTP_STATUS, httpStatusHandler);
            loader.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);

            loader.load(request);
        }


        private function completeHandler(event:Event):void 
        {
            var loader:URLLoader = URLLoader(event.target);
            trace("Complete");
            trace("completeHandler: " + loader.data);
        }

        private function progressHandler(event:ProgressEvent):void 
        {
            trace("progressHandler loaded:" + event.bytesLoaded + " total: " + event.bytesTotal);
        }


        private function securityErrorHandler(event:SecurityErrorEvent):void
        {
            trace("securityErrorHandler: " + event);
        }

        private function httpStatusHandler(event:HTTPStatusEvent):void
        {
            trace("httpStatusHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void 
        {
            trace("ioErrorHandler: " + event);
        }
    }

}

这是我的PHP代码，必须返回JSON数据：

 <? 

//here I can process all input GET, POST params, database etc...
    $someJSONresponse = "{'username':'yozhik', 'age':'18'}";

    //here just echo result and it will be automatically downloaded??
    echo $someJSONresponse;

    ?>

使用URL加载器加载JSON数据

4 个答案: